Complete Yocto mirror with license table for TQMa6UL (2038-compliance)

- 264 license table entries with exact download URLs (224/264 resolved)
- Complete sources/ directory with all BitBake recipes
- Build configuration: tqma6ul-multi-mba6ulx, spaetzle (musl)
- Full traceability for Softwarefreigabeantrag
- GCC 13.4.0, Linux 6.6.102, U-Boot 2023.04, musl 1.2.4
- License distribution: GPL-2.0 (24), MIT (23), GPL-2.0+ (18), BSD-3 (16)

sources/meta-freescale/classes/fsl-kernel-localversion.bbclass

@@ -0,0 +1,47 @@
+# Freescale Kernel LOCALVERSION extension
+#
+# This allow to easy reuse of code between different kernel recipes
+#
+# The following options are supported:
+#
+#  SCMVERSION        Puts the Git hash in kernel local version
+#  LOCALVERSION      Value used in LOCALVERSION (default to '+fslc')
+#
+# Copyright 2014, 2015 (C) O.S. Systems Software LTDA.
+
+SCMVERSION ??= "y"
+LOCALVERSION ??= "+fslc"
+
+# LINUX_VERSION_EXTENSION is used as CONFIG_LOCALVERSION by kernel-yocto class
+LINUX_VERSION_EXTENSION ?= "${LOCALVERSION}"
+
+do_kernel_localversion[dirs] += "${S} ${B}"
+do_kernel_localversion() {
+
+	# Fallback for recipes not able to use LINUX_VERSION_EXTENSION
+	if [ "${@bb.data.inherits_class('kernel-yocto', d)}" = "False" ]; then
+		echo 'CONFIG_LOCALVERSION="${LOCALVERSION}"' >> ${B}/.config
+	fi
+
+	if [ "${SCMVERSION}" = "y" ]; then
+		# Add GIT revision to the local version
+		if [ "${SRCREV}" = "INVALID" ]; then
+			hash=${SRCREV_machine}
+		else
+			hash=${SRCREV}
+		fi
+		if [ "$hash" = "AUTOINC" ]; then
+			branch=`git --git-dir=${S}/.git  symbolic-ref --short -q HEAD`
+			head=`git --git-dir=${S}/.git rev-parse --verify --short origin/${branch} 2> /dev/null`
+		else
+			head=`git --git-dir=${S}/.git rev-parse --verify --short $hash 2> /dev/null`
+		fi
+		patches=`git --git-dir=${S}/.git rev-list --count $head..HEAD 2> /dev/null`
+		printf "%s%s%s%s" +g $head +p $patches > ${S}/.scmversion
+
+		sed -i -e "/CONFIG_LOCALVERSION_AUTO[ =]/d" ${B}/.config
+		echo "CONFIG_LOCALVERSION_AUTO=y" >> ${B}/.config
+	fi
+}
+
+addtask kernel_localversion before do_configure after do_patch do_kernel_configme