Complete Yocto mirror with license table for TQMa6UL (2038-compliance)

- 264 license table entries with exact download URLs (224/264 resolved)
- Complete sources/ directory with all BitBake recipes
- Build configuration: tqma6ul-multi-mba6ulx, spaetzle (musl)
- Full traceability for Softwarefreigabeantrag
- GCC 13.4.0, Linux 6.6.102, U-Boot 2023.04, musl 1.2.4
- License distribution: GPL-2.0 (24), MIT (23), GPL-2.0+ (18), BSD-3 (16)

sources/meta-freescale/dynamic-layers/openembedded-layer/recipes-benchmark/glmark2/glmark2_%.bbappend

@@ -0,0 +1,5 @@
+# 6 and 7 Vivante do not provide virtual/libgbm required for any drm* flavour
+DRM-REMOVE                    = ""
+DRM-REMOVE:imxgpu:mx6-nxp-bsp = "drm-gl drm-gles2"
+DRM-REMOVE:imxgpu:mx7-nxp-bsp = "drm-gl drm-gles2"
+PACKAGECONFIG:remove = "${DRM-REMOVE}"

sources/meta-freescale/dynamic-layers/openembedded-layer/recipes-devtools/cst/imx-cst_3.4.0.bb

@@ -0,0 +1,40 @@
+SUMMARY = "i.MX code signing tool"
+DESCRIPTION = "Provides software code signing support designed that integrate the HABv4 and AHAB library"
+SECTION = "cst"
+LICENSE = "BSD-3-Clause & Apache-2.0"
+
+LIC_FILES_CHKSUM = "\
+    file://LICENSE.bsd3;md5=14aba05f9fa6c25527297c8aac95fcf6 \
+    file://LICENSE.hidapi;md5=e0ea014f523f64f0adb13409055ee59e \
+    file://LICENSE.openssl;md5=3441526b1df5cc01d812c7dfc218cea6 \
+"
+
+DEPENDS = "byacc-native flex-native openssl"
+
+# debian: 3.4.0+dfsg-2
+DEBIAN_PGK_NAME = "imx-code-signing-tool"
+DEBIAN_PGK_VERSION = "${PV}+dfsg"
+
+SRC_URI = "\
+    ${DEBIAN_MIRROR}/main/i/${DEBIAN_PGK_NAME}/${DEBIAN_PGK_NAME}_${DEBIAN_PGK_VERSION}.orig.tar.xz \
+"
+
+SRC_URI[sha256sum] = "52ee3cee3bc500a42095f73c4584e223b4b9d2dfc1cd3e5df965c5952eba8c8d"
+
+S = "${WORKDIR}/${DEBIAN_PGK_NAME}-${DEBIAN_PGK_VERSION}"
+
+EXTRA_OEMAKE = 'CC="${CC}" LD="${CC}" AR="${AR}" OBJCOPY="${OBJCOPY}"'
+
+do_compile() {
+    oe_runmake -C code/obj.linux64 OSTYPE=linux64 ENCRYPTION=yes COPTIONS="${CFLAGS} ${CPPFLAGS}" LDOPTIONS="${LDFLAGS}"
+    oe_runmake -C add-ons/hab_csf_parser COPTS="${CFLAGS} ${CPPFLAGS} ${LDFLAGS}"
+}
+
+do_install () {
+    install -d ${D}${bindir}
+    install -m 755 ${S}/code/obj.linux64/cst ${D}${bindir}/
+    install -m 755 ${S}/code/obj.linux64/srktool ${D}${bindir}
+    install -m 755 ${S}/add-ons/hab_csf_parser/csf_parser ${D}${bindir}
+}
+
+BBCLASSEXTEND = "native nativesdk"

sources/meta-freescale/dynamic-layers/openembedded-layer/recipes-dpaa/fmc/fmc_git.bb

@@ -0,0 +1,55 @@
+SUMMARY = "Frame Manager Configuration tool"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=a504ab5a8ff235e67c7301214749346c"
+
+PR = "r2"
+
+DEPENDS = "libxml2 fmlib tclap"
+
+SRC_URI = "git://github.com/nxp-qoriq/fmc;protocol=https;nobranch=1"
+SRCREV = "5b9f4b16a864e9dfa58cdcc860be278a7f66ac18"
+
+S = "${WORKDIR}/git"
+
+EXTRA_OEMAKE = 'FMD_USPACE_HEADER_PATH="${STAGING_INCDIR}/fmd" \
+    FMD_USPACE_LIB_PATH="${STAGING_LIBDIR}" LIBXML2_HEADER_PATH="${STAGING_INCDIR}/libxml2" \
+    TCLAP_HEADER_PATH="${STAGING_INCDIR}" '
+EXTRA_OEMAKE:class-native = 'FMCHOSTMODE=1 FMD_USPACE_HEADER_PATH="${STAGING_INCDIR}/fmd" \
+    FMD_USPACE_LIB_PATH="${STAGING_LIBDIR}" LIBXML2_HEADER_PATH="${STAGING_INCDIR}/libxml2" \
+    TCLAP_HEADER_PATH="${STAGING_INCDIR}" '
+
+EXTRA_OEMAKE_PLATFORM ?= ""
+EXTRA_OEMAKE_PLATFORM:ls1043a = "ls1043"
+EXTRA_OEMAKE_PLATFORM:ls1046a = "ls1046"
+EXTRA_OEMAKE_PLATFORM:ls1088a = "ls1088"
+EXTRA_OEMAKE_PLATFORM:p1020 = "p4080ds"
+EXTRA_OEMAKE_PLATFORM:p2020 = "p4080ds"
+EXTRA_OEMAKE_PLATFORM:p2041 = "p4080ds"
+EXTRA_OEMAKE_PLATFORM:p3041 = "p4080ds"
+EXTRA_OEMAKE_PLATFORM:p4080 = "p4080ds"
+EXTRA_OEMAKE_PLATFORM:p5040 = "p4080ds"
+
+
+do_compile () {
+    oe_runmake MACHINE=${EXTRA_OEMAKE_PLATFORM} -C source
+}
+
+do_install () {
+    install -d ${D}/${bindir}
+    install -m 755 ${S}/source/fmc ${D}/${bindir}
+
+    install -d ${D}${sysconfdir}/fmc/config
+    install -m 644 ${S}${sysconfdir}/fmc/config/* ${D}${sysconfdir}/fmc/config
+
+    install -d ${D}/${includedir}/fmc
+    install ${S}/source/fmc.h ${D}/${includedir}/fmc
+
+    install -d ${D}/${libdir}
+    install ${S}/source/libfmc.a ${D}/${libdir}
+}
+
+PARALLEL_MAKE = ""
+
+PACKAGE_ARCH = "${MACHINE_SOCARCH}"
+
+COMPATIBLE_MACHINE = "(qoriq)"

sources/meta-freescale/dynamic-layers/openembedded-layer/recipes-multimedia/mpv/mpv_%.bbappend

@@ -0,0 +1,2 @@
+# testbuild/../test.c:10: undefined reference to `glXCreateContext' 
+PACKAGECONFIG:remove:imxgpu = "x11"

sources/meta-freescale/dynamic-layers/openembedded-layer/recipes-support/sg3-utils/sg3-utils_%.bbappend

@@ -0,0 +1 @@
+BBCLASSEXTEND = "native nativesdk"