Complete Yocto mirror with license table for TQMa6UL (2038-compliance)

- 264 license table entries with exact download URLs (224/264 resolved)
- Complete sources/ directory with all BitBake recipes
- Build configuration: tqma6ul-multi-mba6ulx, spaetzle (musl)
- Full traceability for Softwarefreigabeantrag
- GCC 13.4.0, Linux 6.6.102, U-Boot 2023.04, musl 1.2.4
- License distribution: GPL-2.0 (24), MIT (23), GPL-2.0+ (18), BSD-3 (16)

sources/meta-freescale/recipes-devtools/qoriq-cst/qoriq-cst_git.bb

@@ -0,0 +1,43 @@
+SUMMARY = "utility for security boot"
+SECTION = "cst"
+LICENSE = "BSD-3-Clause"
+
+LIC_FILES_CHKSUM = "file://LICENSE;md5=e959d5d617e33779d0e90ce1d9043eff"
+
+DEPENDS += "openssl qoriq-cst-native"
+RDEPENDS:${PN} = "bash"
+
+GENKEYS ?= "${STAGING_BINDIR_NATIVE}/cst/gen_keys"
+GENKEYS:class-native = "./gen_keys"
+
+inherit kernel-arch
+
+# specify the non default keys pair for secure boot if needed
+#SECURE_PRI_KEY = "/path/srk.pri"
+#SECURE_PUB_KEY = "/path/srk.pub"
+
+SRC_URI = "git://github.com/nxp-qoriq/cst;protocol=https;nobranch=1 \
+           file://0001-tools-Mark-struct-input_field-file_field-extern.patch \
+"
+SRCREV = "e96dead3c339f6addb1600249be67e1884cdbcc5"
+
+S = "${WORKDIR}/git"
+
+EXTRA_OEMAKE = 'CC="${CC}" LD="${CC}"'
+CFLAGS:append = ' -Wno-deprecated-declarations'
+
+PARALLEL_MAKE = ""
+
+do_install () {
+    oe_runmake install DESTDIR=${D} BIN_DEST_DIR=${bindir}
+
+    if [ -n "${SECURE_PRI_KEY}" ]; then
+       cp -f ${SECURE_PRI_KEY} ${D}/${bindir}/cst/srk.pri
+       cp -f ${SECURE_PUB_KEY} ${D}/${bindir}/cst/srk.pub
+    elif [ ! -f ${D}/${bindir}/cst/srk.pri -o ! ${D}/${bindir}/cst/srk.pub ]; then
+       cd ${D}/${bindir}/cst  && ${GENKEYS} 1024
+    fi
+}
+
+FILES:${PN}-dbg += "${bindir}/cst/.debug"
+BBCLASSEXTEND = "native nativesdk"