Complete Yocto mirror with license table for TQMa6UL (2038-compliance)

- 264 license table entries with exact download URLs (224/264 resolved)
- Complete sources/ directory with all BitBake recipes
- Build configuration: tqma6ul-multi-mba6ulx, spaetzle (musl)
- Full traceability for Softwarefreigabeantrag
- GCC 13.4.0, Linux 6.6.102, U-Boot 2023.04, musl 1.2.4
- License distribution: GPL-2.0 (24), MIT (23), GPL-2.0+ (18), BSD-3 (16)

sources/meta-freescale/recipes-extended/odp/odp-counters_git.bb

@@ -0,0 +1,14 @@
+require odp.inc
+
+inherit module
+
+do_compile:prepend () {
+    export KERNEL_PATH="${STAGING_KERNEL_DIR}"
+    export KERNEL_CFG_PATH="${STAGING_KERNEL_BUILDDIR}"
+    cd ${S}/test/debug/perf_counters
+}
+
+do_install () {
+    install -d ${D}${nonarch_base_libdir}/modules/${KERNEL_VERSION}/odp
+    install -m 755 ${S}/test/debug/perf_counters/odpfsl_perfcounters.ko ${D}${nonarch_base_libdir}/modules/${KERNEL_VERSION}/odp
+}

sources/meta-freescale/recipes-extended/odp/odp-module_git.bb

@@ -0,0 +1,16 @@
+require odp.inc
+
+inherit module
+
+do_compile:prepend () {
+    export KERNEL_PATH="${STAGING_KERNEL_DIR}"
+    export KERNEL_CFG_PATH="${STAGING_KERNEL_BUILDDIR}"
+    cd ${S}/kern
+}
+
+do_install () {
+    install -d ${D}${nonarch_base_libdir}/modules/${KERNEL_VERSION}/odp
+    install -m 755 ${S}/kern/odpfsl_kni.ko ${D}${nonarch_base_libdir}/modules/${KERNEL_VERSION}/odp
+}
+
+PKG:${PN} = "kernel-module-${PN}"

sources/meta-freescale/recipes-extended/odp/odp.inc

@@ -0,0 +1,27 @@
+SUMMARY = "Open Data Plane Interface Implementation"
+DESCRIPTION = "OpenDataPlane (ODP) provides a data plane application programming \
+        environment that is easy to use, high performance, and portable between networking SoCs."
+HOMEPAGE = "http://www.opendataplane.org"
+SECTION = "console/network"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=ca6103dc75397fb6bec596187d6b7829"
+
+FILESEXTRAPATHS:prepend := "${THISDIR}/odp:"
+
+SRC_URI = " \
+git://github.com/nxp-qoriq/odp;protocol=https;nobranch=1 \
+git://github.com/nxp-qoriq/qbman_userspace;protocol=https;nobranch=1;name=qbman;destsuffix=git/platform/linux-dpaa2/flib/qbman \
+git://github.com/nxp-qoriq/flib;protocol=https;nobranch=1;name=rta;destsuffix=git/platform/linux-dpaa2/flib/rta \
+"
+
+SRC_URI += "file://0001-Fix-this-build-error.patch"
+
+SRCREV = "0bda2c9736a72ef41a411e193bc31487ecce6731"
+
+SRCREV_qbman = "75ff61a7ca6acdbdbb780161b053cbcbc990f1be"
+SRCREV_rta = "bbab28b03ae21c52ce913f8b052acf53bd24ff5d"
+
+SRCREV_FORMAT = "default_qbman_rta"
+S = "${WORKDIR}/git"
+
+COMPATIBLE_MACHINE = "(ls1043a|ls1046a|ls2088a|ls1088a)"

sources/meta-freescale/recipes-extended/odp/odp/0001-Fix-this-build-error.patch

@@ -0,0 +1,29 @@
+From 9fb1642b38053de6e8098f6b608ad86ff45bf7f7 Mon Sep 17 00:00:00 2001
+From: Chunrong Guo <chunrong.guo@nxp.com>
+Date: Fri, 28 Jul 2017 14:59:22 +0800
+Subject: [PATCH] Fix this build error
+
+fix the below error:
+|error: 'SIGEV_THREAD' undeclared (first use in this function); did you mean 'CLONE_THREAD'?
+
+Upstream-Status: Pending
+Signed-off-by: Chunrong Guo <B40290@freescale.com>
+---
+ example/lpm-ipfwd/app/odp_lpmfwd.c | 1 +
+ 1 file changed, 1 insertion(+)
+
+diff --git a/example/lpm-ipfwd/app/odp_lpmfwd.c b/example/lpm-ipfwd/app/odp_lpmfwd.c
+index 57c5e82..f8507be 100644
+--- a/example/lpm-ipfwd/app/odp_lpmfwd.c
++++ b/example/lpm-ipfwd/app/odp_lpmfwd.c
+@@ -23,6 +23,7 @@
+ #include <errno.h>
+ #include <error.h>
+ #include <mqueue.h>
++#include <signal.h>
+ 
+ #include <example_debug.h>
+ 
+-- 
+1.8.3.2
+

sources/meta-freescale/recipes-extended/odp/odp_git.bb

@@ -0,0 +1,62 @@
+require odp.inc
+
+inherit autotools-brokensep
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+DEPENDS = "openssl cunit libxml2"
+
+RDEPENDS:${PN} = "bash libcrypto libssl odp-module odp-counters"
+
+ODP_SOC ?= ""
+ODP_SOC:ls1043ardb = "LS1043"
+ODP_SOC:ls1046ardb = "LS1046"
+ODP_PLATFORM ?= "linux-dpaa2"
+ODP_BUILD_TYPE ?= "ls2088"
+ODP_BUILD_TYPE:ls1043ardb = "ls1043"
+ODP_BUILD_TYPE:ls1046ardb = "ls1046"
+ODP_BUILD_TYPE:ls1088ardb = "ls1088"
+
+EXTRA_OECONF = "--with-platform=${ODP_PLATFORM} \
+                --enable-test-vald \
+                --enable-test-perf \
+                --enable-test-cpp \
+"
+
+EXTRA_OEMAKE = "CROSS_COMPILE="${TARGET_PREFIX}" \
+                SYSROOT="${STAGING_DIR_TARGET}" \
+"
+
+CFLAGS += "-Wno-format-truncation -Wno-maybe-uninitialized -Wno-implicit-fallthrough -Wno-cpp -Wno-cast-function-type \
+          -Wno-stringop-truncation \
+"
+
+PACKAGECONFIG[perf] = "--enable-test-perf,,,"
+
+do_configure:prepend () {
+    export SOC=${ODP_SOC}
+    ${S}/bootstrap
+}
+
+do_compile:prepend () {
+    export SOC=${ODP_SOC}
+    export ARCH=${TUNE_ARCH}
+}
+
+do_install:append () {
+    install -d ${D}${includedir}/odp/kni
+    install -d ${D}${includedir}/odp/kern
+    install -d ${D}${includedir}/odp/flib/mc
+    install -d ${D}${includedir}/odp/flib/qbman/include/drivers
+
+    cp -rf ${S}/platform/linux-dpaa2/include/* ${D}${includedir}/odp/
+    cp -rf ${S}/platform/linux-dpaa2/kni/*.h ${D}${includedir}/odp/kni/
+    cp -rf ${S}/kern/*.h ${D}${includedir}/odp/kern/
+    cp -rf ${S}/platform/linux-dpaa2/flib/mc/*.h ${D}${includedir}/odp/flib/mc/
+
+    sed -i -e 's#platform/linux-dpaa2/##g' ${D}${includedir}/odp/kern/*.h
+}
+
+FILES:${PN}-staticdev += "${datadir}/opendataplane/*.la"
+FILES:${PN} += "/usr/odp/bin /usr/odp/scripts /usr/odp/debug /usr/odp/test/validation /usr/odp/test/performance /usr/odp/test/miscellaneous /usr/odp/test/api_test"
+FILES:${PN}-dbg += "/usr/odp/bin/.debug /usr/odp/debug/.debug /usr/odp/test/validation/.debug /usr/odp/test/performance/.debug /usr/odp/test/miscellaneous/.debug /usr/odp/test/api_test/.debug"