Complete Yocto mirror with license table for TQMa6UL (2038-compliance)

- 264 license table entries with exact download URLs (224/264 resolved)
- Complete sources/ directory with all BitBake recipes
- Build configuration: tqma6ul-multi-mba6ulx, spaetzle (musl)
- Full traceability for Softwarefreigabeantrag
- GCC 13.4.0, Linux 6.6.102, U-Boot 2023.04, musl 1.2.4
- License distribution: GPL-2.0 (24), MIT (23), GPL-2.0+ (18), BSD-3 (16)

sources/meta-freescale/recipes-graphics/imx-g2d/imx-dpu-g2d_2.2.2.bb

@@ -0,0 +1,47 @@
+# Copyright (C) 2016 Freescale Semiconductor
+# Copyright 2017-2024 NXP
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+DESCRIPTION = "G2D library using i.MX DPU"
+LICENSE = "Proprietary"
+LIC_FILES_CHKSUM = "file://COPYING;md5=ca53281cc0caa7e320d4945a896fb837" 
+
+DEPENDS = "libdrm ${LIBGAL_IMX}"
+LIBGAL_IMX        = ""
+LIBGAL_IMX:imxviv = "libgal-imx"
+
+PROVIDES += "virtual/libg2d"
+
+SRC_URI = "${FSL_MIRROR}/${IMX_BIN_NAME}.bin;fsl-eula=true;name=${IMX_SRC_URI_NAME}"
+IMX_BIN_NAME = "${BPN}-${IMX_SRC_URI_NAME}-${PV}-${IMX_SRCREV_ABBREV}"
+
+IMX_SRCREV_ABBREV = "e2dce80"
+IMX_SRC_URI_NAME = "v1"
+SRC_URI[v1.sha256sum] = "d43b5d4b8e6015a029c6e8854982aa5d57de25bc0e3ff8209d4aab7679c2d240"
+
+IMX_SRCREV_ABBREV:imxmali = "e2dce80"
+IMX_SRC_URI_NAME:imxmali = "v2"
+SRC_URI[v2.sha256sum] = "d9845356e0c9c959b1d57ebb3ee668ba6aa2b864999263a8c33cb053b83584e6"
+
+S = "${WORKDIR}/${IMX_BIN_NAME}"
+
+inherit fsl-eula-unpack
+
+do_install () {
+    install -d ${D}${libdir}
+    install -d ${D}${includedir}
+    cp -d ${S}/g2d/usr/lib/*.so* ${D}${libdir}
+    cp -Pr ${S}/g2d/usr/include/* ${D}${includedir}
+}
+
+INSANE_SKIP:append:libc-musl = " file-rdeps"
+RDEPENDS:${PN}:append:libc-musl = " gcompat"
+
+# The packaged binaries have been stripped of debug info, so disable
+# operations accordingly.
+INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
+INHIBIT_PACKAGE_STRIP = "1"
+INHIBIT_SYSROOT_STRIP = "1"
+
+PACKAGE_ARCH = "${MACHINE_SOCARCH}"
+COMPATIBLE_MACHINE = "(imxdpu)"

sources/meta-freescale/recipes-graphics/imx-g2d/imx-g2d-samples_git.bb

@@ -0,0 +1,76 @@
+SUMMARY = "i.MX G2D Samples"
+DESCRIPTION = "Set of sample applications for i.MX G2D"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=0858ec9c7a80c4a2cf16e4f825a2cc91"
+
+DEPENDS = "cairo"
+
+PV = "2.2+git${SRCPV}"
+
+SRC_URI = "${GPU_G2D_SAMPLES_SRC};branch=${SRCBRANCH}"
+GPU_G2D_SAMPLES_SRC ?= "git://github.com/nxp-imx/g2d-samples.git;protocol=https"
+SRCBRANCH = "imx_2.2"
+SRCREV = "431f311a41ca052902ea0d6445e74defe0a4df2d"
+
+S = "${WORKDIR}/git"
+
+inherit pkgconfig
+
+PACKAGECONFIG ??= "${PACKAGECONFIG_IMPLEMENTATION}"
+PACKAGECONFIG_IMPLEMENTATION                   = ""
+PACKAGECONFIG_IMPLEMENTATION:imxgpu2d:imxdpu   = "dpu"
+PACKAGECONFIG_IMPLEMENTATION:mx95-nxp-bsp      = "dpu95"
+PACKAGECONFIG_IMPLEMENTATION:imxgpu2d          = "gpu-drm"
+PACKAGECONFIG_IMPLEMENTATION:imxgpu2d:imxfbdev = "gpu-fbdev"
+PACKAGECONFIG_IMPLEMENTATION:mx93-nxp-bsp      = "pxp"
+
+PACKAGECONFIG[dpu] = " \
+    BUILD_IMPLEMENTATION=dpu, \
+    , \
+    imx-dpu-g2d wayland-native wayland wayland-protocols, \
+    , \
+    , \
+    dpu95 gpu-drm gpu-fbdev pxp"
+PACKAGECONFIG[dpu95] = " \
+    BUILD_IMPLEMENTATION=dpu95, \
+    , \
+    imx-dpu-g2d wayland-native wayland wayland-protocols, \
+    , \
+    , \
+    dpu gpu-drm gpu-fbdev pxp"
+PACKAGECONFIG[gpu-drm] = " \
+    BUILD_IMPLEMENTATION=gpu-drm, \
+    , \
+    imx-gpu-g2d wayland-native wayland wayland-protocols, \
+    , \
+    , \
+    dpu dpu95 gpu-fbdev pxp"
+PACKAGECONFIG[gpu-fbdev] = " \
+    BUILD_IMPLEMENTATION=gpu-fbdev, \
+    , \
+    imx-gpu-g2d, \
+    , \
+    , \
+    dpu dpu95 gpu-drm pxp"
+PACKAGECONFIG[pxp] = " \
+    BUILD_IMPLEMENTATION=pxp, \
+    , \
+    imx-pxp-g2d wayland-native wayland wayland-protocols, \
+    , \
+    , \
+    dpu dpu95 gpu-drm gpu-fbdev"
+
+EXTRA_OEMAKE += " \
+    SDKTARGETSYSROOT=${STAGING_DIR_HOST} \
+    ${PACKAGECONFIG_CONFARGS} \
+"
+
+do_install() {
+    oe_runmake install DESTDIR=${D}
+}
+
+FILES:${PN} += "/opt"
+
+PACKAGE_ARCH = "${MACHINE_SOCARCH}"
+
+COMPATIBLE_MACHINE = "(imxgpu2d|mx93-nxp-bsp|mx95-nxp-bsp)"

sources/meta-freescale/recipes-graphics/imx-g2d/imx-gpu-g2d_6.4.11.p2.12.bb

@@ -0,0 +1,42 @@
+# Copyright (C) 2016 Freescale Semiconductor
+# Copyright 2017-2022 NXP
+# Copyright 2018 (C) O.S. Systems Software LTDA.
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+DESCRIPTION = "G2D library using i.MX GPU"
+LICENSE = "Proprietary"
+LIC_FILES_CHKSUM = "file://COPYING;md5=bc649096ad3928ec06a8713b8d787eac"
+DEPENDS = "libgal-imx"
+PROVIDES = "virtual/libg2d"
+
+SRC_URI = "${FSL_MIRROR}/${IMX_BIN_NAME}.bin;name=${TARGET_ARCH};fsl-eula=true"
+IMX_BIN_NAME = "${BP}-${TARGET_ARCH}-${IMX_SRCREV_ABBREV}"
+IMX_SRCREV_ABBREV = "4402ac2"
+SRC_URI[aarch64.sha256sum] = "f82208abc84453c94fdc737ed6267cd689e68c23af9e4154bee6ce0651c075b1"
+SRC_URI[arm.sha256sum] = "bdfe4d48da0239d264b766ad46b89982f78af04ca4d5051aaf7615473b4de86a"
+
+S = "${WORKDIR}/${IMX_BIN_NAME}"
+
+inherit fsl-eula-unpack
+
+SOC_INSTALL_DIR               = "SOC_INSTALL_DIR_NOT_SET"
+SOC_INSTALL_DIR:mx8mm-nxp-bsp = "mx8mm"
+
+do_install () {
+    install -d ${D}${libdir}
+    install -d ${D}${includedir}
+    cp -d ${S}/g2d/usr/lib/*.so* ${D}${libdir}
+    if [ -d ${S}/g2d/usr/lib/${SOC_INSTALL_DIR} ]; then
+        cp -d ${S}/g2d/usr/lib/${SOC_INSTALL_DIR}/*.so* ${D}${libdir}
+    fi
+    cp -Pr ${S}/g2d/usr/include/* ${D}${includedir}
+}
+
+# The packaged binaries have been stripped of debug info, so disable
+# operations accordingly.
+INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
+INHIBIT_PACKAGE_STRIP = "1"
+INHIBIT_SYSROOT_STRIP = "1"
+
+PACKAGE_ARCH = "${MACHINE_SOCARCH}"
+COMPATIBLE_MACHINE = "(imxgpu2d)"

sources/meta-freescale/recipes-graphics/imx-g2d/imx-pxp-g2d_git.bb

@@ -0,0 +1,29 @@
+# Copyright (C) 2016 Freescale Semiconductor
+# Copyright 2017-2024 NXP
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+DESCRIPTION = "G2D library using i.MX PXP"
+LICENSE = "Proprietary"
+LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=ca53281cc0caa7e320d4945a896fb837"
+
+PROVIDES += "virtual/libg2d"
+
+PV = "2.2+git${SRCPV}"
+
+SRC_URI = "${IMX_PXP_G2D_SRC};branch=${SRCBRANCH}"
+IMX_PXP_G2D_SRC ?= "git://github.com/nxp-imx/imx-g2d-pxp.git;protocol=https"
+SRCBRANCH = "imx_2.2"
+SRCREV = "5e633f895a84cec809ca98d77c879af3591b3b20"
+
+S = "${WORKDIR}/git"
+
+inherit use-imx-headers
+
+EXTRA_OEMAKE = "PLATFORM=IMX93 INCLUDE='-I${STAGING_INCDIR_IMX}' DEST_DIR=${D}"
+
+do_install() {
+    oe_runmake install
+}
+
+PACKAGE_ARCH = "${MACHINE_SOCARCH}"
+COMPATIBLE_MACHINE = "(mx93-nxp-bsp)"