Complete Yocto mirror with license table for TQMa6UL (2038-compliance)

- 264 license table entries with exact download URLs (224/264 resolved)
- Complete sources/ directory with all BitBake recipes
- Build configuration: tqma6ul-multi-mba6ulx, spaetzle (musl)
- Full traceability for Softwarefreigabeantrag
- GCC 13.4.0, Linux 6.6.102, U-Boot 2023.04, musl 1.2.4
- License distribution: GPL-2.0 (24), MIT (23), GPL-2.0+ (18), BSD-3 (16)

sources/meta-freescale/recipes-kernel/linux/linux-fslc-imx_6.6.bb

@@ -0,0 +1,107 @@
+# Released under the MIT license (see COPYING.MIT for the terms)
+#
+# SPDX-License-Identifier: MIT
+#
+
+SUMMARY = "Linux Kernel provided by NXP and supported by Community"
+DESCRIPTION = "Linux Kernel provided by NXP as the part of release distribution. \
+Main focus is set on i.MX Family Reference Boards. \
+It includes support for many NXP Proprietary IPs (GPU, VPU, IPU). \
+Latest stable Kernel patchlevel is applied and maintained by Community."
+
+###############################################################################
+# This recipe (and corresponding kernel repository and branch) receives updates
+# from 3 different sources:
+# 1. Stable [linux-6.6.y] branch updates of korg;
+# 2. NXP-specific updates via branch [lf-6.6.y] shared via GitHub NXP repo;
+# 3. Critical patches, which are not (yet) integrated into either of 2 above
+#    sources, but are required to be applied to the kernel tree.
+#
+# Therefore, there is a need to keep track on the patches which are introduced
+# from every source. This could be achieved in this recipe by filling the
+# below list with the information once the update is performed from any source.
+#
+# Once the critical patch gets merged into the stable branch, or NXP-specific
+# patches would be covered by the tag - individual entries from sections below
+# could be removed.
+#
+# ------------------------------------------------------------------------------
+# 1. Stable (tag or SHA(s))
+# ------------------------------------------------------------------------------
+#    tag: v6.6.74
+#
+# ------------------------------------------------------------------------------
+# 2. NXP-specific (tag or SHA(s))
+# ------------------------------------------------------------------------------
+#    tag: lf-6.6.52-2.2.0
+#
+# ------------------------------------------------------------------------------
+# 3. Critical patches (SHA(s))
+# ------------------------------------------------------------------------------
+# The list includes well-known commits not yet upstreamed. Reverts address merge
+# conflicts, prioritizing NXP BSP source code as the latest vendor updates.
+# Additional commits may exist to better acommodate yocto builds.
+#
+# $ git log --oneline  --no-merges v6.6.101.. ^mainline/linux-6.6.y ^NXP/lf-6.6.y
+# - ff2e4152c6ac Fix merge error on pci/controller/dwc/pci-imx6.c
+# - 0e91a51824ac Fix the merge between 6.6.85 and imx branch
+# - db393a056f28 imx8mp-olimex.dts: CSI GPIO pins
+# - 8981bfbf2cd5 Reapply "LF-12740: mxc: vpu: hantro_v4l2: report performance statistics"
+# - 9a97c180b1c4 Fix spi-nxp-fspi merge error
+# - e587f8fe42f1 firmware: se_fw: remove info_list from ro section
+# - 0f638960dcff media: Kconfig: fix double VIDEO_DEV
+# - 198242c057e0 drivers:clk:imx:clk-imx8mp-audiomix: remove duplicated CLK_GATE_PARENT definition
+# - 4f5936d7391f Revert "usb: gadget: u_serial: Disable ep before setting port to null to fix the crash caused by port being null"
+# - 997b7e13e413 imx8mp-olimex.dts: Olimex iMX8MP-SOM-EVB-IND
+# - b746c990ecba Revert "LF-12740: mxc: vpu: hantro_v4l2: report performance statistics"
+# - e349e6c45a94 arm64: imx_v8_defconfig: Enable CONFIG_GPIO_VF610
+# - 5a015324eddc arm64: dts: imx8qm: add missing imx8-ss-cm40.dtsi include
+# - 8a8245d395d5 arm64: dts: imx8: img: add #address-cells and #size-cells to I2C MIPI CSI nodes
+# - db13648c4be6 fw: imx: seco_mu: change dev_err to dev_err_probe for -EPROBE_DEFER
+# - 0451236fd0ae clk: imx: imx8qm: add more resources to whitelist
+# - 2ee789512d1b drm/imx: lcdifv3: Fix videomode settings
+# - 5cd4c30ec228 i2c: imx: Remove unnecessary clock reconfiguration
+# - 583f2a703c5d tty: vt: conmakehash: remove non-portable code printing comment header
+# - 4ddc4dae8515 tty: vt: conmakehash: cope with abs_srctree no longer in env
+# - 46a05495bce3 drm: of: Fix build without CONFIG_OF
+# - 3d6392b96bf1 Revert "LF-4131 iio: gyro: fxas21002c: Fix raw data is not updated in trigger/buffer"
+# - 93b9fc75becd nvmem: imx-ocotp-fsb-s400: BUG: Fix the word count
+# - 090d101928fc tty: vt: conmakehash: Don't mention the full path of the input in output
+# - d16eb5ced32f arm64: dts: imx8mm-evk-qca-wifi: enable support for bluetooth
+# - d39502c0dea9 imx:dts:imx8mm-evkb: fix the pmic name to avoid duplicated label error
+# - 58181fb0ff67 media: imx8: select v4l2_* for mxc-mipi-csi2_yav
+# - 930431e0d1d5 gpu: drm: cadence: select hdmi helper
+# - da675fd29502 of: enable using OF_DYNAMIC without OF_UNITTEST
+# - 7c5f3cbb180c arm64: dts: imx8mq: drop cpu-idle-states
+# - a9920ce3e197 hwrng: optee: support generic crypto
+#
+# NOTE to upgraders:
+# This recipe should NOT collect individual patches, they should be applied to
+# the linux-fslc kernel tree on the corresponding branch, and tracking
+# information should be properly filled in above.
+###############################################################################
+
+require linux-imx.inc
+
+KBRANCH = "6.6-2.2.x-imx"
+SRC_URI = "git://github.com/Freescale/linux-fslc.git;branch=${KBRANCH};protocol=https"
+SRCREV = "36cee4c51e9a0660f6f07d8f116f0c1fd4d77d30"
+
+# PV is defined in the base in linux-imx.inc file and uses the LINUX_VERSION definition
+# required by kernel-yocto.bbclass.
+#
+# LINUX_VERSION define should match to the kernel version referenced by SRC_URI and
+# should be updated once patchlevel is merged.
+LINUX_VERSION = "6.6.101"
+
+KBUILD_DEFCONFIG:mx6-generic-bsp = "imx_v7_defconfig"
+KBUILD_DEFCONFIG:mx7-generic-bsp = "imx_v7_defconfig"
+KBUILD_DEFCONFIG:mx8-generic-bsp = "imx_v8_defconfig"
+KBUILD_DEFCONFIG:mx9-generic-bsp = "imx_v8_defconfig"
+
+# Local version indicates the branch name in the NXP kernel tree where patches are collected from.
+LOCALVERSION = "-lf-6.6.y"
+
+DEFAULT_PREFERENCE = "1"
+
+COMPATIBLE_MACHINE = "(imx-nxp-bsp)"

sources/meta-freescale/recipes-kernel/linux/linux-fslc-lts_6.1.bb

@@ -0,0 +1,41 @@
+# Copyright (C) 2012-2019 O.S. Systems Software LTDA.
+# Released under the MIT license (see COPYING.MIT for the terms)
+#
+# SPDX-License-Identifier: MIT
+#
+
+SUMMARY = "FSL Community BSP Linux LTS based kernel with backported features and fixes"
+DESCRIPTION = "Linux kernel based on LTS kernel used by FSL Community BSP in order to \
+provide support for some backported features and fixes, or because it was applied in upstream \
+and will not become part of a LTS version, or because it is not applicable for \
+upstreaming in any form."
+
+require linux-imx.inc
+
+KERNEL_DEVICETREE_32BIT_COMPATIBILITY_UPDATE = "1"
+
+SRC_URI = "git://github.com/Freescale/linux-fslc.git;branch=${KBRANCH};protocol=https"
+
+# PV is defined in the base in linux-imx.inc file and uses the LINUX_VERSION definition
+# required by kernel-yocto.bbclass.
+#
+# LINUX_VERSION define should match to the kernel version referenced by SRC_URI and
+# should be updated once patchlevel is merged.
+LINUX_VERSION = "6.1.72"
+
+KBRANCH = "6.1.x+fslc"
+SRCREV = "b80c9dede70132da3ae7feb949fe0803aad3db24"
+
+KBUILD_DEFCONFIG:mx5-generic-bsp = "imx_v6_v7_defconfig"
+KBUILD_DEFCONFIG:mx5-generic-bsp = "imx_v6_v7_defconfig"
+KBUILD_DEFCONFIG:mx5-generic-bsp = "imx_v6_v7_defconfig"
+KBUILD_DEFCONFIG:mx6-generic-bsp = "imx_v6_v7_defconfig"
+KBUILD_DEFCONFIG:mx7-generic-bsp = "imx_v6_v7_defconfig"
+KBUILD_DEFCONFIG:mx8-generic-bsp = "defconfig"
+KBUILD_DEFCONFIG:mx9-generic-bsp = "defconfig"
+KBUILD_DEFCONFIG:mxs-generic-bsp = "mxs_defconfig"
+KBUILD_DEFCONFIG:vf-generic-bsp = "imx_v6_v7_defconfig"
+
+LOCALVERSION = "-fslc"
+
+COMPATIBLE_MACHINE = "(imx-generic-bsp)"

sources/meta-freescale/recipes-kernel/linux/linux-fslc-lts_6.6.bb

@@ -0,0 +1,37 @@
+# Copyright (C) 2012-2024 O.S. Systems Software LTDA.
+# Released under the MIT license (see COPYING.MIT for the terms)
+#
+# SPDX-License-Identifier: MIT
+#
+
+SUMMARY = "FSL Community BSP Linux LTS based kernel with backported features and fixes"
+DESCRIPTION = "Linux kernel based on LTS kernel used by FSL Community BSP in order to \
+provide support for some backported features and fixes, or because it was applied in upstream \
+and will not become part of a LTS version, or because it is not applicable for \
+upstreaming in any form."
+
+require linux-imx.inc
+
+SRC_URI = "git://github.com/Freescale/linux-fslc.git;branch=${KBRANCH};protocol=https"
+
+# PV is defined in the base in linux-imx.inc file and uses the LINUX_VERSION definition
+# required by kernel-yocto.bbclass.
+#
+# LINUX_VERSION define should match to the kernel version referenced by SRC_URI and
+# should be updated once patchlevel is merged.
+LINUX_VERSION = "6.6.50"
+
+KBRANCH = "6.6.x+fslc"
+SRCREV = "2473dfed9007471b503efe1f7de74d63eaf4c699"
+
+KBUILD_DEFCONFIG:mx5-generic-bsp = "imx_v6_v7_defconfig"
+KBUILD_DEFCONFIG:mx6-generic-bsp = "imx_v6_v7_defconfig"
+KBUILD_DEFCONFIG:mx7-generic-bsp = "imx_v6_v7_defconfig"
+KBUILD_DEFCONFIG:mx8-generic-bsp = "defconfig"
+KBUILD_DEFCONFIG:mx9-generic-bsp = "defconfig"
+KBUILD_DEFCONFIG:mxs-generic-bsp = "mxs_defconfig"
+KBUILD_DEFCONFIG:vf-generic-bsp = "imx_v6_v7_defconfig"
+
+LOCALVERSION = "-fslc"
+
+COMPATIBLE_MACHINE = "(imx-generic-bsp)"

sources/meta-freescale/recipes-kernel/linux/linux-fslc-qoriq_5.4.bb

@@ -0,0 +1,17 @@
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+SUMMARY = "Mainline/LTS rebased NXP/QorIQ patches + FSLC patches."
+DESCRIPTION = "Linux kernel based on LTS kernel used by FSL Community BSP in order to \
+provide support for some backported features and fixes, or because it was applied in linux-next \
+and takes some time to become part of a stable version, or because it is not applicable for \
+upstreaming."
+
+require recipes-kernel/linux/linux-qoriq.inc
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=bbea815ee2795b2f4230826c0c6b8814"
+
+LINUX_VERSION = "5.4.92"
+
+SRCBRANCH = "5.4.y+qoriq+fslc"
+SRCREV = "11d4722c637a77c6e1c9a8eeec091f1588f6b3f3"
+SRC_URI := "git://github.com/Freescale/linux-fslc.git;branch=${SRCBRANCH};protocol=https"

sources/meta-freescale/recipes-kernel/linux/linux-fslc_6.12.bb

@@ -0,0 +1,44 @@
+# Copyright (C) 2012-2024 O.S. Systems Software LTDA.
+# Released under the MIT license (see COPYING.MIT for the terms)
+#
+# SPDX-License-Identifier: MIT
+#
+
+SUMMARY = "FSL Community BSP Linux mainline based kernel with backported features and fixes"
+DESCRIPTION = "Linux kernel based on mainline kernel used by FSL Community BSP in order to \
+provide support for some backported features and fixes, or because it was applied in linux-next \
+and takes some time to become part of a stable version, or because it is not applicable for \
+upstreaming."
+
+require linux-imx.inc
+
+SRC_URI = "git://github.com/Freescale/linux-fslc.git;branch=${KBRANCH};protocol=https"
+
+DEPENDS += " \
+    coreutils-native \
+"
+
+# PV is defined in the base in linux-imx.inc file and uses the LINUX_VERSION definition
+# required by kernel-yocto.bbclass.
+#
+# LINUX_VERSION define should match to the kernel version referenced by SRC_URI and
+# should be updated once patchlevel is merged.
+#
+# Linux kernel stable 6.12.20 changelog:
+# https://cdn.kernel.org/pub/linux/kernel/v6.x/ChangeLog-6.12.20
+LINUX_VERSION = "6.12.20"
+
+KBRANCH = "6.12.x+fslc"
+SRCREV = "844aa3471b97053b0a59f68d36dc6f796338b562"
+
+KBUILD_DEFCONFIG:mx5-generic-bsp = "imx_v6_v7_defconfig"
+KBUILD_DEFCONFIG:mx6-generic-bsp = "imx_v6_v7_defconfig"
+KBUILD_DEFCONFIG:mx7-generic-bsp = "imx_v6_v7_defconfig"
+KBUILD_DEFCONFIG:mx8-generic-bsp = "defconfig"
+KBUILD_DEFCONFIG:mx9-generic-bsp = "defconfig"
+KBUILD_DEFCONFIG:mxs-generic-bsp = "mxs_defconfig"
+KBUILD_DEFCONFIG:vf-generic-bsp = "imx_v6_v7_defconfig"
+
+LOCALVERSION = "-fslc"
+
+COMPATIBLE_MACHINE = "(imx-generic-bsp)"

sources/meta-freescale/recipes-kernel/linux/linux-imx-headers_6.6.bb

@@ -0,0 +1,78 @@
+# Copyright 2017-2024 NXP
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+SUMMARY = "Installs i.MX-specific kernel headers"
+DESCRIPTION = "Installs i.MX-specific kernel headers to userspace. \
+New headers are installed in ${includedir}/imx."
+LICENSE = "GPL-2.0-only"
+LIC_FILES_CHKSUM = "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46"
+
+SRC_URI = "git://github.com/nxp-imx/linux-imx.git;protocol=https;branch=${SRCBRANCH}"
+SRCBRANCH = "lf-6.6.y"
+LOCALVERSION = "-6.6.52-2.2.1"
+SRCREV = "90192c5d29cb650fd7f7dd9094af14eefb38837d"
+
+S = "${WORKDIR}/git"
+
+do_configure[noexec] = "1"
+
+do_compile[noexec] = "1"
+
+IMX_UAPI_HEADERS = " \
+    dma-buf.h \
+    hantrodec.h \
+    hx280enc.h \
+    ipu.h \
+    imx_vpu.h \
+    mxc_asrc.h \
+    mxc_dcic.h \
+    mxc_mlb.h \
+    mxc_sim_interface.h \
+    mxc_v4l2.h \
+    mxcfb.h \
+    pxp_device.h \
+    pxp_dma.h \
+    version.h \
+    videodev2.h \
+"
+
+do_install() {
+    # We install all headers inside of B so we can copy only the
+    # i.MX-specific ones, and there is no risk of a new header to be
+    # installed by mistake.
+    oe_runmake headers_install INSTALL_HDR_PATH=${B}${exec_prefix}
+
+    ################################################
+    # BEGIN Copy of exceptional logic from linux-libc-headers
+    # Kernel should not be exporting this header
+    rm -f ${B}${exec_prefix}/include/scsi/scsi.h
+
+    # The ..install.cmd conflicts between various configure runs
+    find ${B}${includedir} -name ..install.cmd | xargs rm -f
+    # END Copy from linux-libc-headers
+    ################################################
+
+    # Install i.MX-specific headers only
+    for h in ${IMX_UAPI_HEADERS}; do
+        install -D -m 0644 ${B}${includedir}/linux/$h \
+                       ${D}${includedir}/imx/linux/$h
+    done
+}
+
+# Allow to build empty main package, this is required in order for -dev package
+# to be propagated into the SDK
+#
+# Without this setting the RDEPENDS in other recipes fails to find this
+# package, therefore causing the -dev package also to be skipped effectively not
+# populating it into SDK
+ALLOW_EMPTY:${PN} = "1"
+
+INHIBIT_DEFAULT_DEPS = "1"
+DEPENDS += "unifdef-native bison-native rsync-native"
+
+PACKAGE_ARCH = "${MACHINE_SOCARCH}"
+
+# Restrict this recipe to NXP BSP only, this recipe is not compatible
+# with mainline BSP
+COMPATIBLE_HOST = '(null)'
+COMPATIBLE_HOST:use-nxp-bsp = '.*'

sources/meta-freescale/recipes-kernel/linux/linux-imx.inc

@@ -0,0 +1,66 @@
+# Copyright (C) 2012, 2015 O.S. Systems Software LTDA.
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+LICENSE = "GPL-2.0-only"
+LIC_FILES_CHKSUM = "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46"
+
+inherit kernel-yocto kernel fsl-kernel-localversion fsl-vivante-kernel-driver-handler
+
+# Put a local version until we have a true SRCREV to point to
+LOCALVERSION ?= ""
+SCMVERSION ?= "y"
+SRCBRANCH ?= ""
+
+# Allow use of kernel as linux-mfgtool provider.
+PROVIDES += "linux-mfgtool"
+
+# Set the PV to the correct kernel version to satisfy the kernel version sanity check
+PV = "${LINUX_VERSION}+git${SRCPV}"
+
+SRC_URI = "git://github.com/nxp-imx/linux-imx;protocol=https;branch=${SRCBRANCH}"
+
+S = "${WORKDIR}/git"
+
+# Tell to kernel class that we would like to use our defconfig to configure the kernel.
+# Otherwise, the --allnoconfig would be used per default which leads to mis-configured
+# kernel.
+#
+# This behavior happens when a defconfig is provided, the kernel-yocto configuration
+# uses the filename as a trigger to use a 'allnoconfig' baseline before merging
+# the defconfig into the build.
+#
+# If the defconfig file was created with make_savedefconfig, not all options are
+# specified, and should be restored with their defaults, not set to 'n'.
+# To properly expand a defconfig like this, we need to specify: KCONFIG_MODE="--alldefconfig"
+# in the kernel recipe include.
+KCONFIG_MODE="--alldefconfig"
+
+# We need to pass it as param since kernel might support more then one
+# machine, with different entry points
+KERNEL_EXTRA_ARGS += "LOADADDR=${UBOOT_ENTRYPOINT}"
+
+# A function to strip the new 32-bit dtb sub-folders in KERNEL_DEVICETREE
+# for older kernel builds.
+# Set KERNEL_DEVICETREE_32BIT_COMPATIBILITY_UPDATE = "1" to enable.
+KERNEL_DEVICETREE_32BIT_COMPATIBILITY_UPDATE ?= "0"
+python kernel_devicetree_32bit_compatibility_update() {
+    import os.path
+    import re
+    if d.getVar('KERNEL_DEVICETREE_32BIT_COMPATIBILITY_UPDATE') != "1" or d.getVar('TUNE_ARCH') != "arm":
+        return
+    input = d.getVar('KERNEL_DEVICETREE').split()
+    output = ""
+    stripped = ""
+    for original in input:
+        if re.match("^.*/", original):
+            stripped = os.path.basename(original)
+            output += stripped + " "
+            bb.debug(1, "Devicetrees are moved to sub-folder, stripping the sub-folder for older kernel: %s -> %s" % (original, stripped))
+        else:
+            output += original + " "
+    if stripped:
+        bb.warn("Updating KERNEL_DEVICETREE, removing sub-folders for older kernel. Use -D for more details. Set KERNEL_DEVICETREE_32BIT_COMPATIBILITY_UPDATE = \"0\" to disable.")
+        d.setVar('KERNEL_DEVICETREE', output)
+}
+addhandler kernel_devicetree_32bit_compatibility_update
+kernel_devicetree_32bit_compatibility_update[eventmask] = "bb.event.RecipeParsed"

sources/meta-freescale/recipes-kernel/linux/linux-imx/0001-tty-vt-conmakehash-Don-t-mention-the-full-path-of-th.patch

@@ -0,0 +1,70 @@
+From 3bd85c6c97b2d232638594bf828de62083fe3389 Mon Sep 17 00:00:00 2001
+From: =?UTF-8?q?Uwe=20Kleine-K=C3=B6nig?= <u.kleine-koenig@pengutronix.de>
+Date: Mon, 11 Mar 2024 12:30:18 +0100
+Subject: [PATCH] tty: vt: conmakehash: Don't mention the full path of the
+ input in output
+MIME-Version: 1.0
+Content-Type: text/plain; charset=UTF-8
+Content-Transfer-Encoding: 8bit
+
+This change strips $abs_srctree of the input file containing the
+character mapping table in the generated output. The motivation for this
+change is Yocto emitting a build warning
+
+        WARNING: linux-lxatac-6.7-r0 do_package_qa: QA Issue: File /usr/src/debug/linux-lxatac/6.7-r0/drivers/tty/vt/consolemap_deftbl.c in package linux-lxatac-src contains reference to TMPDIR
+
+So this change brings us one step closer to make the build result
+reproducible independent of the build path.
+
+Upstream-Status: Backport [https://github.com/torvalds/linux/commit/3bd85c6c97b2d232638594bf828de62083fe3389]
+
+Signed-off-by: Uwe Kleine-König <u.kleine-koenig@pengutronix.de>
+Link: https://lore.kernel.org/r/20240311113017.483101-2-u.kleine-koenig@pengutronix.de
+Signed-off-by: Greg Kroah-Hartman <gregkh@linuxfoundation.org>
+---
+ drivers/tty/vt/conmakehash.c | 15 +++++++++++++--
+ 1 file changed, 13 insertions(+), 2 deletions(-)
+
+diff --git a/drivers/tty/vt/conmakehash.c b/drivers/tty/vt/conmakehash.c
+index cddd789fe46e..dc2177fec715 100644
+--- a/drivers/tty/vt/conmakehash.c
++++ b/drivers/tty/vt/conmakehash.c
+@@ -76,7 +76,8 @@ static void addpair(int fp, int un)
+ int main(int argc, char *argv[])
+ {
+   FILE *ctbl;
+-  char *tblname;
++  const char *tblname, *rel_tblname;
++  const char *abs_srctree;
+   char buffer[65536];
+   int fontlen;
+   int i, nuni, nent;
+@@ -101,6 +102,16 @@ int main(int argc, char *argv[])
+ 	}
+     }
+ 
++  abs_srctree = getenv("abs_srctree");
++  if (abs_srctree && !strncmp(abs_srctree, tblname, strlen(abs_srctree)))
++    {
++      rel_tblname = tblname + strlen(abs_srctree);
++      while (*rel_tblname == '/')
++	++rel_tblname;
++    }
++  else
++    rel_tblname = tblname;
++
+   /* For now we assume the default font is always 256 characters. */
+   fontlen = 256;
+ 
+@@ -253,7 +264,7 @@ int main(int argc, char *argv[])
+ #include <linux/types.h>\n\
+ \n\
+ u8 dfont_unicount[%d] = \n\
+-{\n\t", argv[1], fontlen);
++{\n\t", rel_tblname, fontlen);
+ 
+   for ( i = 0 ; i < fontlen ; i++ )
+     {
+-- 
+2.34.1
+

sources/meta-freescale/recipes-kernel/linux/linux-imx_6.6.bb

@@ -0,0 +1,37 @@
+# Copyright 2013-2016 (C) Freescale Semiconductor
+# Copyright 2017-2024 (C) NXP
+# Copyright 2018 (C) O.S. Systems Software LTDA.
+# Released under the MIT license (see COPYING.MIT for the terms)
+#
+# SPDX-License-Identifier: MIT
+#
+
+SUMMARY = "Linux Kernel provided and supported by NXP"
+DESCRIPTION = "Linux Kernel provided and supported by NXP with focus on \
+i.MX Family Reference Boards. It includes support for many IPs such as GPU, VPU and IPU."
+
+require recipes-kernel/linux/linux-imx.inc
+
+SRCBRANCH = "lf-6.6.y"
+LOCALVERSION = "-6.6.52-2.2.1"
+SRCREV = "90192c5d29cb650fd7f7dd9094af14eefb38837d"
+
+SRC_URI += " \
+    file://0001-tty-vt-conmakehash-Don-t-mention-the-full-path-of-th.patch \
+"
+
+# PV is defined in the base in linux-imx.inc file and uses the LINUX_VERSION definition
+# required by kernel-yocto.bbclass.
+#
+# LINUX_VERSION define should match to the kernel version referenced by SRC_URI and
+# should be updated once patchlevel is merged.
+LINUX_VERSION = "6.6.52"
+
+KBUILD_DEFCONFIG:mx6-generic-bsp = "imx_v7_defconfig"
+KBUILD_DEFCONFIG:mx7-generic-bsp = "imx_v7_defconfig"
+KBUILD_DEFCONFIG:mx8-generic-bsp = "imx_v8_defconfig"
+KBUILD_DEFCONFIG:mx9-generic-bsp = "imx_v8_defconfig"
+
+DEFAULT_PREFERENCE = "1"
+
+COMPATIBLE_MACHINE = "(imx-nxp-bsp)"

sources/meta-freescale/recipes-kernel/linux/linux-qoriq.inc

@@ -0,0 +1,58 @@
+inherit kernel qoriq_build_64bit_kernel siteinfo
+inherit fsl-kernel-localversion
+
+SUMMARY = "Linux Kernel for NXP QorIQ platforms"
+SECTION = "kernel"
+LICENSE = "GPL-2.0-only"
+
+S = "${WORKDIR}/git"
+
+DEPENDS:append = " libgcc"
+# not put Images into /boot of rootfs, install kernel-image if needed
+RRECOMMENDS:${KERNEL_PACKAGE_NAME}-base = ""
+
+KERNEL_CC:append = " ${TOOLCHAIN_OPTIONS}"
+KERNEL_LD:append = " ${TOOLCHAIN_OPTIONS}"
+KERNEL_EXTRA_ARGS += "LOADADDR=${UBOOT_ENTRYPOINT}"
+
+ZIMAGE_BASE_NAME = "zImage-${PKGE}-${PKGV}-${PKGR}-${MACHINE}-${DATETIME}"
+ZIMAGE_BASE_NAME[vardepsexclude] = "DATETIME"
+
+# Set the PV to the correct kernel version to satisfy the kernel version sanity check
+PV = "${LINUX_VERSION}+git${SRCPV}"
+
+SCMVERSION ?= "y"
+LOCALVERSION = ""
+DELTA_KERNEL_DEFCONFIG ?= ""
+DELTA_KERNEL_DEFCONFIG:prepend:qoriq-arm64 = "lsdk.config "
+DELTA_KERNEL_DEFCONFIG:prepend:qoriq-arm = "multi_v7_lpae.config lsdk.config "
+
+do_merge_delta_config[depends] += "virtual/${TARGET_PREFIX}gcc:do_populate_sysroot bison-native:do_populate_sysroot"
+do_merge_delta_config[dirs] = "${B}"
+
+do_merge_delta_config() {
+    # create config with make config
+    oe_runmake  -C ${S} O=${B} ${KERNEL_DEFCONFIG}
+
+    # check if bigendian is enabled
+    if [ "${SITEINFO_ENDIANNESS}" = "be" ]; then
+        echo "CONFIG_CPU_BIG_ENDIAN=y" >> .config
+        echo "CONFIG_MTD_CFI_BE_BYTE_SWAP=y" >> .config
+    fi
+
+    # add config fragments
+    for deltacfg in ${DELTA_KERNEL_DEFCONFIG}; do
+        if [ -f ${S}/arch/${ARCH}/configs/${deltacfg} ]; then
+            oe_runmake  -C ${S} O=${B} ${deltacfg}
+        elif [ -f "${WORKDIR}/${deltacfg}" ]; then
+            ${S}/scripts/kconfig/merge_config.sh -m .config ${WORKDIR}/${deltacfg}
+        elif [ -f "${deltacfg}" ]; then
+            ${S}/scripts/kconfig/merge_config.sh -m .config ${deltacfg}
+        fi
+    done
+    cp .config ${WORKDIR}/defconfig
+}
+addtask merge_delta_config before do_kernel_localversion after do_patch
+
+FILES:${KERNEL_PACKAGE_NAME}-image += "/boot/zImage*"
+COMPATIBLE_MACHINE = "(qoriq)"

sources/meta-freescale/recipes-kernel/linux/linux-qoriq_5.10.bb

@@ -0,0 +1,8 @@
+LIC_FILES_CHKSUM = "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46"
+
+LINUX_VERSION = "5.10.52"
+
+SRC_URI = "git://github.com/nxp-qoriq/linux;protocol=https;nobranch=1"
+SRCREV = "a11753a89ec610768301d4070e10b8bd60fde8cd"
+
+require recipes-kernel/linux/linux-qoriq.inc