Complete Yocto mirror with license table for TQMa6UL (2038-compliance)

- 264 license table entries with exact download URLs (224/264 resolved)
- Complete sources/ directory with all BitBake recipes
- Build configuration: tqma6ul-multi-mba6ulx, spaetzle (musl)
- Full traceability for Softwarefreigabeantrag
- GCC 13.4.0, Linux 6.6.102, U-Boot 2023.04, musl 1.2.4
- License distribution: GPL-2.0 (24), MIT (23), GPL-2.0+ (18), BSD-3 (16)

sources/meta-openembedded/meta-networking/recipes-support/spice/libcacard_2.8.1.bb

@@ -0,0 +1,17 @@
+SUMMARY = "This library provides emulation of smart cards to a virtual card reader running in a guest virtual machine."
+LICENSE = "LGPL-2.1-or-later"
+LIC_FILES_CHKSUM = "file://COPYING;md5=79ffa0ec772fa86740948cb7327a0cc7"
+
+DEPENDS = "glib-2.0 pcsc-lite nss"
+
+SRCREV = "7b07684ea6698d4885ff2062350ad8798a04de42"
+
+SRC_URI = "git://gitlab.freedesktop.org/spice/libcacard.git;protocol=https;branch=master"
+
+S = "${WORKDIR}/git"
+
+inherit meson pkgconfig
+
+do_configure:prepend() {
+	echo ${PV} > ${S}/.tarball-version
+}

sources/meta-openembedded/meta-networking/recipes-support/spice/phodav_3.0.bb

@@ -0,0 +1,24 @@
+SUMMARY = "phodav is a WebDav server implementation using libsoup (RFC 4918)."
+LICENSE = "LGPL-2.1-only"
+LIC_FILES_CHKSUM = "file://COPYING;md5=4fbd65380cdd255951079008b364516c"
+
+DEPENDS = " \
+    glib-2.0 \
+    libsoup \
+"
+
+GTKDOC_MESON_OPTION = 'gtk_doc'
+GTKDOC_MESON_ENABLE_FLAG = 'enabled'
+GTKDOC_MESON_DISABLE_FLAG = 'disabled'
+
+PACKAGECONFIG ??= "avahi"
+PACKAGECONFIG[avahi] = "-Davahi=enabled,-Davahi=disabled,avahi"
+
+inherit pkgconfig gnomebase gettext gtk-doc
+
+EXTRA_OEMESON += "-Dsystemdsystemunitdir=${systemd_system_unitdir}"
+
+SRC_URI = "https://download.gnome.org/sources/phodav/3.0/phodav-${PV}.tar.xz;name=archive"
+SRC_URI[archive.sha256sum] = "392ec2d06d50300dcff1ef269a2a985304e29bce3520002fca29f2edc1d138d1"
+
+FILES:${PN} += "${libdir} ${systemd_system_unitdir}"

sources/meta-openembedded/meta-networking/recipes-support/spice/spice-gtk_0.42.bb

@@ -0,0 +1,69 @@
+SUMMARY = "A Gtk client and libraries for SPICE remote desktop servers."
+HOMEPAGE = "https://spice-space.org"
+LICENSE = "LGPL-2.1-only & BSD-3-Clause & GPL-2.0-only"
+LIC_FILES_CHKSUM = " \
+	file://COPYING;md5=4fbd65380cdd255951079008b364516c \
+	file://subprojects/spice-common/COPYING;md5=4b54a1fd55a448865a0b32d41598759d \
+	file://subprojects/keycodemapdb/LICENSE.BSD;md5=5ae30ba4123bc4f2fa49aa0b0dce887b \
+	file://subprojects/keycodemapdb/LICENSE.GPL2;md5=751419260aa954499f7abaabaa882bbe \
+"
+
+SRCREV = "f04479c16f0969fb394ebe74b6eff74e560a42f0"
+
+SRC_URI = "gitsm://gitlab.freedesktop.org/spice/spice-gtk.git;protocol=https;branch=master"
+
+S = "${WORKDIR}/git"
+
+DEPENDS = " \
+	${@bb.utils.filter('DISTRO_FEATURES', 'polkit', d)} \
+	${@bb.utils.contains('DISTRO_FEATURES', 'wayland', 'wayland wayland-native wayland-protocols', '', d)} \
+	acl \
+	cyrus-sasl \
+	gstreamer1.0 \
+	gstreamer1.0-plugins-base \
+	gstreamer1.0-vaapi \
+	gtk+3 \
+	jpeg \
+	json-glib \
+	libcap-ng \
+	libepoxy \
+	libopus \
+	libusb1 \
+	lz4 \
+	pixman \
+	python3-pyparsing-native \
+	python3-six-native \
+	spice-protocol \
+	usbredir \
+	usbutils \
+	zlib \
+"
+DEPENDS:append:libc-musl = " libucontext"
+
+RDEPENDS:${PN} = "python3-pyparsing python3-six hwdata"
+
+inherit meson pkgconfig vala gobject-introspection features_check gtk-doc
+
+REQUIRED_DISTRO_FEATURES = "opengl"
+
+GIR_MESON_ENABLE_FLAG = 'enabled'
+GIR_MESON_DISABLE_FLAG = 'disabled'
+GTKDOC_MESON_OPTION = 'gtk_doc'
+GTKDOC_MESON_ENABLE_FLAG = 'enabled'
+GTKDOC_MESON_DISABLE_FLAG = 'disabled'
+
+do_configure:prepend() {
+	echo ${PV} > ${S}/.tarball-version
+}
+
+PACKAGECONFIG ??= "${@bb.utils.contains('GI_DATA_ENABLED', 'True', 'vapi', '', d)} smartcard"
+PACKAGECONFIG[vapi] = "-Dvapi=enabled,-Dvapi=disabled"
+PACKAGECONFIG[smartcard] = "-Dsmartcard=enabled,-Dsmartcard=disabled,libcacard"
+PACKAGECONFIG[webdav] = "-Dwebdav=enabled,-Dwebdav=disabled,phodav libsoup"
+
+EXTRA_OEMESON = "-Dpie=true -Dusb-ids-path=${datadir}/hwdata/usb.ids "
+EXTRA_OEMESON:append:libc-musl = " -Dcoroutine=libucontext"
+
+LDFLAGS += "${@bb.utils.contains('DISTRO_FEATURES', 'ld-is-lld', ' -Wl,--undefined-version', '', d)}"
+
+FILES:${PN} += "${datadir}"

sources/meta-openembedded/meta-networking/recipes-support/spice/spice-guest-vdagent_0.22.1.bb

@@ -0,0 +1,25 @@
+SUMMARY = "Spice agent for Linux"
+HOMEPAGE = "https://spice-space.org"
+LICENSE = "GPL-3.0-only"
+LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
+
+SRCREV = "aa08162f036840d3e33502dc0a836b03b9cec97c"
+
+SRC_URI = "git://gitlab.freedesktop.org/spice/linux/vd_agent.git;protocol=https;branch=master"
+
+S = "${WORKDIR}/git"
+
+ANY_OF_DISTRO_FEATURES = "${GTK3DISTROFEATURES}"
+REQUIRED_DISTRO_FEATURES = "opengl x11"
+
+inherit autotools pkgconfig features_check
+
+DEPENDS = "glib-2.0 alsa-lib gtk4 dbus libdrm spice-protocol libxfixes xrandr xinerama libx11"
+
+EXTRA_OECONF = " \
+	--with-gtk4 \
+	--enable-pie \
+"
+
+FILES:${PN} += "${datadir}"
+

sources/meta-openembedded/meta-networking/recipes-support/spice/spice-protocol_0.14.4.bb

@@ -0,0 +1,21 @@
+#
+# Copyright (C) 2013 Wind River Systems, Inc.
+#
+
+SUMMARY = "Simple Protocol for Independent Computing Environments (protocol definition"
+HOMEPAGE = "https://spice-space.org"
+
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://COPYING;md5=b37311cb5604f3e5cc2fb0fd23527e95"
+
+SRCREV = "6f453a775d87087c6ba59fc180c1a1e466631a47"
+
+SRC_URI = "git://gitlab.freedesktop.org/spice/spice-protocol.git;protocol=https;branch=master"
+
+S = "${WORKDIR}/git"
+
+inherit meson pkgconfig
+
+ALLOW_EMPTY:${PN} = "1"
+
+BBCLASSEXTEND = "native nativesdk"

sources/meta-openembedded/meta-networking/recipes-support/spice/spice_git.bb

@@ -0,0 +1,48 @@
+#
+# Copyright (C) 2013 Wind River Systems, Inc.
+#
+
+SUMMARY = "Simple Protocol for Independent Computing Environments"
+DESCRIPTION = "SPICE (the Simple Protocol for Independent Computing \
+Environments) is a remote-display system built for virtual \
+environments which allows users to view a computing 'desktop' \ 
+environment - not only on its computer-server machine, but also from \
+anywhere on the Internet and using a wide variety of machine \
+architectures."
+
+LICENSE = "LGPL-2.1-or-later"
+LIC_FILES_CHKSUM = "file://COPYING;md5=4fbd65380cdd255951079008b364516c"
+
+PV = "0.15.2"
+
+SRCREV = "0c2c1413a8b387ea597a95b6c867470a7c56c8ab"
+
+SRC_URI = "gitsm://gitlab.freedesktop.org/spice/spice;branch=master;protocol=https"
+
+S = "${WORKDIR}/git"
+
+CVE_STATUS[CVE-2018-10893] = "fixed-version: patched already, caused by inaccurate CPE in the NVD database."
+
+inherit meson gettext python3native python3-dir pkgconfig
+
+DEPENDS = "spice-protocol jpeg pixman alsa-lib glib-2.0 gdk-pixbuf lz4 orc python3-pyparsing-native python3-six-native glib-2.0-native zlib"
+DEPENDS:append:class-nativesdk = " nativesdk-openssl"
+
+export PYTHON="${STAGING_BINDIR_NATIVE}/python3-native/python3"
+
+do_configure:prepend() {
+	echo ${PV} > ${S}/.tarball-version
+}
+
+PACKAGECONFIG:class-native = ""
+PACKAGECONFIG:class-nativesdk = ""
+PACKAGECONFIG ?= "sasl opus smartcard gstreamer"
+
+PACKAGECONFIG[gstreamer] = "-Dgstreamer=1.0,-Dgstreamer=no,gstreamer1.0 gstreamer1.0-plugins-base"
+PACKAGECONFIG[smartcard] = "-Dsmartcard=enabled,-Dsmartcard=disabled,libcacard,libcacard"
+PACKAGECONFIG[sasl] = "-Dsasl=true,-Dsasl=false,cyrus-sasl,"
+PACKAGECONFIG[opus] = "-Dopus=enabled,-Dopus=disabled,libopus,"
+
+COMPATIBLE_HOST = '(x86_64|i.86|aarch64).*-linux'
+
+BBCLASSEXTEND = "native nativesdk"

sources/meta-openembedded/meta-networking/recipes-support/spice/usbredir_0.13.0.bb

@@ -0,0 +1,18 @@
+SUMMARY = "usbredir libraries and utilities"
+
+LICENSE = "GPL-2.0-or-later & LGPL-2.1-or-later"
+LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
+    file://COPYING.LIB;md5=4b54a1fd55a448865a0b32d41598759d \
+"
+
+DEPENDS = "libusb1 glib-2.0"
+
+SRCREV = "5fc0e1c43194d948545941d408f4c10d084eb6ed"
+
+SRC_URI = "git://gitlab.freedesktop.org/spice/usbredir;branch=main;protocol=https"
+
+S = "${WORKDIR}/git"
+
+inherit meson pkgconfig
+
+BBCLASSEXTEND = "native nativesdk"