Complete Yocto mirror with license table for TQMa6UL (2038-compliance)

- 264 license table entries with exact download URLs (224/264 resolved)
- Complete sources/ directory with all BitBake recipes
- Build configuration: tqma6ul-multi-mba6ulx, spaetzle (musl)
- Full traceability for Softwarefreigabeantrag
- GCC 13.4.0, Linux 6.6.102, U-Boot 2023.04, musl 1.2.4
- License distribution: GPL-2.0 (24), MIT (23), GPL-2.0+ (18), BSD-3 (16)

sources/meta-qt6/recipes-python/pyqt6/python3-pyqt-builder-native_1.18.0.bb

@@ -0,0 +1,12 @@
+SUMMARY = "The PEP 517 compliant PyQt build system"
+HOMEPAGE = "https://pypi.org/project/PyQt-builder/"
+LICENSE = "GPL-2.0-or-later"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=ed1d69a33480ebf4ff8a7a760826d84e"
+
+SRC_URI[sha256sum] = "ce9930aafc1ce0af928a6944bcc80ecf78c23ffdcad6ac111306c4c71057848e"
+
+inherit pypi python_setuptools_build_meta native
+
+PYPI_PACKAGE = "pyqt_builder"
+
+DEPENDS += "python3-setuptools-scm-native"

sources/meta-qt6/recipes-python/pyqt6/python3-pyqt6-sip_13.10.0.bb

@@ -0,0 +1,12 @@
+SUMMARY = "The sip module support for PyQt6"
+HOMEPAGE = "https://github.com/Python-SIP/sip"
+LICENSE = "BSD-2-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=bc996f4e03c98eae60de43496026f863"
+
+SRC_URI[sha256sum] = "d6daa95a0bd315d9ec523b549e0ce97455f61ded65d5eafecd83ed2aa4ae5350"
+
+inherit pypi setuptools3
+
+PYPI_PACKAGE = "pyqt6_sip"
+
+BBCLASSEXTEND = "native nativesdk"

sources/meta-qt6/recipes-python/pyqt6/python3-pyqt6/0001-Fix-build-with-Qt-6.8.2.patch

@@ -0,0 +1,32 @@
+From ee6c2c30eca67004e2b05f55ee1d82c3ab44b966 Mon Sep 17 00:00:00 2001
+From: Christophe Marin <christophe@krop.fr>
+Date: Sun, 2 Feb 2025 12:59:19 +0100
+Subject: [PATCH] Fix build with Qt 6.8.2
+MIME-Version: 1.0
+Content-Type: text/plain; charset=UTF-8
+Content-Transfer-Encoding: 8bit
+
+Fixes:
+/home/abuild/rpmbuild/BUILD/python-PyQt6-6.8.0-build/PyQt6-6.8.0/build/QtCore/sipQtCoreQStringConverterBase.cpp:58:52: error: use of deleted function ‘constexpr QStringConverterBase::QStringConverterBase(const QStringConverterBase&)’
+
+Upstream-Status: Pending
+
+---
+ sip/QtCore/qstringconverter_base.sip | 2 +-
+ 1 file changed, 1 insertion(+), 1 deletion(-)
+
+diff --git a/sip/QtCore/qstringconverter_base.sip b/sip/QtCore/qstringconverter_base.sip
+index d0c790f..6f7c301 100644
+--- a/sip/QtCore/qstringconverter_base.sip
++++ b/sip/QtCore/qstringconverter_base.sip
+@@ -22,7 +22,7 @@
+ 
+ %If (Qt_6_4_0 -)
+ 
+-class QStringConverterBase
++class QStringConverterBase /NoDefaultCtors/
+ {
+ %TypeHeaderCode
+ #include <qstringconverter_base.h>
+-- 
+2.48.1

sources/meta-qt6/recipes-python/pyqt6/python3-pyqt6_6.8.0.bb

@@ -0,0 +1,110 @@
+SUMMARY = "Python Qt6 Bindings"
+HOMEPAGE = "https://www.riverbankcomputing.com/software/pyqt"
+SECTION = "devel/python"
+LICENSE = "GPL-3.0-only"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=d32239bcb673463ab874e80d47fae504"
+
+inherit pypi python3targetconfig python3-dir qt6-qmake qt6-paths
+
+PYPI_PACKAGE = "PyQt6"
+
+SRC_URI[sha256sum] = "6d8628de4c2a050f0b74462e4c9cb97f839bf6ffabbca91711722ffb281570d9"
+SRC_URI += "file://0001-Fix-build-with-Qt-6.8.2.patch"
+
+S = "${WORKDIR}/PyQt6-${PV}"
+B = "${S}/build"
+
+DEPENDS += " \
+    qtbase \
+    qtdeclarative \
+    sip (>= 6.7.12) \
+    sip-native (>= 6.7.12) \
+    python3 \
+    python3-pyqt6-sip-native \
+    python3-pyqt6-sip \
+    python3-packaging-native \
+    python3-tomli-native \
+    python3-pyqt-builder-native \
+    python3-ply \
+    python3-ply-native \
+"
+
+RDEPENDS:${PN} += " \
+    qtbase \
+    qtdeclarative \
+    python3-core \
+    python3-pyqt6-sip \
+"
+
+# Disable support of 128bit ints and add path to Python.h
+CXXFLAGS += " -DQT_NO_INT128 -I${PYTHON_INCLUDE_DIR}"
+
+EXTRA_OEMAKE += "INSTALL_ROOT=${D}"
+
+DISABLED_FEATURES = " \
+    PyQt_Desktop_OpenGL \
+    PyQt_Accessibility \
+    PyQt_SessionManager \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'opengl', '', 'PyQt_OpenGL', d)} \
+"
+
+PYQT_MODULES = " \
+    QtCore \
+    QtGui \
+    QtNetwork \
+    QtXml \
+    QtNetwork \
+    QtQml \
+    QtSql \
+"
+
+do_configure() {
+    extra_args=""
+
+    for i in ${DISABLED_FEATURES}; do
+        extra_args="$extra_args --disabled-feature=$i"
+    done
+
+    for i in ${PYQT_MODULES}; do
+        extra_args="$extra_args --enable=$i"
+    done
+
+    cd ${S}
+    sip-build \
+        --verbose \
+        --confirm-license \
+        --scripts-dir="${bindir}" \
+        --build-dir="${B}" \
+        --target-dir="${PYTHON_SITEPACKAGES_DIR}" \
+        --no-make \
+        --qmake=${OE_QMAKE_QMAKE} \
+        --pep484-pyi \
+        --no-dbus-python \
+        $extra_args
+
+    QMAKE_PROFILES=${B}/PyQt6.pro
+
+    # Fixes: cc1plus: error: include location "/usr/include/python3.13"
+    # is unsafe for cross-compilation [-Werror=poison-system-directories]
+    sed -i "s|/usr/include/${PYTHON_DIR}|${PYTHON_INCLUDE_DIR}|g" ${B}/*/*.pro
+}
+
+do_compile:append() {
+    sed -i "s,${STAGING_DIR_TARGET},," ${B}/inventory.txt
+}
+
+do_install:append() {
+    sed -i "s,exec .*nativepython3,exec ${bindir}/python3," ${D}/${bindir}/*
+}
+
+# fix buildpaths warnings in python3-pyqt6-src
+pyqt_fix_sources() {
+    find ${PKGD}/usr/src/debug/${PN} -type f -exec sed -i "s,\(${B}\|${S}\),/usr/src/debug/${PN}/${PV}-${PR},g" {} \;
+}
+PACKAGESPLITFUNCS:prepend = "pyqt_fix_sources"
+
+# Ignore warnings about TMPDIR [buildpaths] in libpyqt6qmlplugin.so
+INSANE_SKIP:${PN} += "buildpaths"
+INSANE_SKIP:${PN}-dbg += "buildpaths"
+
+FILES:${PN} += "${PYTHON_SITEPACKAGES_DIR} ${OE_QMAKE_PATH_PLUGINS}"

sources/meta-qt6/recipes-python/pyside6/python3-pyside6.inc

@@ -0,0 +1,33 @@
+LICENSE = "The-Qt-Company-Commercial | (GPL-3.0-only & Qt-GPL-exception-1.0) & (LGPL-3.0-only | GPL-2.0-only | GPL-3.0-only)"
+LIC_FILES_CHKSUM = " \
+    file://LICENSES/BSD-3-Clause.txt;md5=cb40fa7520502d8c7a3aea47cae1316c \
+    file://LICENSES/GFDL-1.3-no-invariants-only.txt;md5=a22d0be1ce2284b67950a4d1673dd1b0 \
+    file://LICENSES/GPL-2.0-only.txt;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
+    file://LICENSES/GPL-3.0-only.txt;md5=d32239bcb673463ab874e80d47fae504 \
+    file://LICENSES/LGPL-3.0-only.txt;md5=e6a600fd5e1d9cbde2d983680233ad02 \
+    file://LICENSES/LicenseRef-Qt-Commercial.txt;md5=40a1036f91cefc0e3fabad241fb5f187 \
+    file://LICENSES/Qt-GPL-exception-1.0.txt;md5=9a13522cd91a88fba784baf16ea66af8 \
+"
+
+python() {
+    if 'clang-layer' not in d.getVar('BBFILE_COLLECTIONS').split():
+        raise bb.parse.SkipRecipe('Requires meta-clang to be present.')
+}
+
+inherit setuptools3
+inherit qt6-cmake
+
+require recipes-qt/qt6/qt6-git.inc
+
+QT_GIT_PROJECT = "pyside"
+QT_MODULE = "pyside-setup"
+QT_MODULE_BRANCH = "dev"
+
+FILESEXTRAPATHS:prepend := "${THISDIR}/pyside6:"
+
+S = "${WORKDIR}/git"
+
+EXTRA_OECMAKE += "-DBUILD_TESTS=FALSE"
+EXTRA_OECMAKE:append:class-target = " -DQFP_SHIBOKEN_HOST_PATH=${STAGING_EXECPREFIXDIR} -DQFP_PYTHON_HOST_PATH=${PYTHON}"
+
+INSANE_SKIP:${PN} += "already-stripped"

sources/meta-qt6/recipes-python/pyside6/python3-pyside6_git.bb

@@ -0,0 +1,71 @@
+require python3-pyside6.inc
+
+DEPENDS += "\
+    python3-shiboken6 \
+    python3-shiboken6-native \
+    ${PYSIDE_QT_MODULES} \
+"
+PYSIDE_QT_MODULES ?= "\
+    ${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'qt3d', '', d)} \
+    qtbase \
+    qtcharts \
+    qtconnectivity \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'qtdatavis3d', '', d)} \
+    qtdeclarative \
+    qtdeclarative-native \
+    qtgraphs \
+    ${@bb.utils.contains('QT_COMMERCIAL_MODULES', '1', 'qthttpserver', '', d)} \
+    qtlocation \
+    qtmultimedia \
+    qtnetworkauth \
+    qtpositioning \
+    qtquick3d \
+    qtquick3d-native \
+    qtremoteobjects \
+    qtremoteobjects-native \
+    qtscxml \
+    qtscxml-native \
+    qtsensors \
+    qtserialbus \
+    qtserialport \
+    qtspeech \
+    qtsvg \
+    qttools \
+    qtwebchannel \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'webengine', 'qtwebengine', '', d)} \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'webengine', 'qtpdf', '', d)} \
+    qtwebsockets \
+"
+
+OECMAKE_SOURCEPATH = "${S}/sources/pyside6"
+
+export LLVM_INSTALL_DIR = "${STAGING_DIR_NATIVE}${exec_prefix}"
+
+PYSIDE_COMPILER = "${HOST_SYS}-g++"
+PYSIDE_COMPILER:toolchain-clang = "${HOST_SYS}-clang++"
+# Workaround big.LITTLE architecture args not supported by clang
+PYSIDE_COMPILER_FLAGS = "${@d.getVar('HOST_CC_ARCH') \
+    .replace('cortex-a15.cortex','cortex') \
+    .replace('cortex-a17.cortex','cortex') \
+    .replace('cortex-a57.cortex','cortex') \
+    .replace('cortex-a72.cortex','cortex') \
+    .replace('cortex-a73.cortex','cortex') \
+    .replace('cortex-a75.cortex','cortex') \
+    .replace('cortex-a76.cortex','cortex')} \
+"
+
+EXTRA_OECMAKE += "\
+    -DSTANDALONE=ON \
+    -DPYSIDE_TREAT_QT_INCLUDE_DIRS_AS_NON_SYSTEM=ON \
+    -DSHIBOKEN_GENERATOR_EXTRA_FLAGS='\
+        --clang-options=--sysroot=${STAGING_DIR_TARGET},--target=${HOST_SYS},${@d.getVar('PYSIDE_COMPILER_FLAGS').replace(' ',',')} \
+        --compiler-path=${PYSIDE_COMPILER} \
+    ' \
+"
+
+FILES:${PN} += "\
+    ${QT6_INSTALL_PLUGINSDIR}/designer \
+"
+FILES:${PN}-dev += "\
+    ${datadir}/PySide6 \
+"

sources/meta-qt6/recipes-python/pyside6/python3-shiboken6_git.bb

@@ -0,0 +1,16 @@
+require python3-pyside6.inc
+
+DEPENDS += "qtbase clang-native python3-shiboken6-native"
+
+OECMAKE_SOURCEPATH = "${S}/sources/shiboken6"
+
+EXTRA_OECMAKE += "-DSHIBOKEN_BUILD_LIBS=ON"
+
+do_install:append() {
+    # shiboken6.pc in package python3-shiboken6-dev contains reference to TMPDIR [buildpaths]
+    sed -i ${D}${QT6_INSTALL_LIBDIR}/pkgconfig/shiboken6.pc \
+        -e '/^python_/d' \
+        -e 's|${RECIPE_SYSROOT}||'
+}
+
+BBCLASSEXTEND = "native nativesdk"

sources/meta-qt6/recipes-python/pytest-qt/python3-pytest-qt_4.2.0.bb

@@ -0,0 +1,12 @@
+SUMMARY = "pytest support for PyQt and PySide applications"
+HOMEPAGE = "http://github.com/pytest-dev/pytest-qt"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=be0db96616c6ec3cabe975402c4c687f"
+
+SRC_URI[sha256sum] = "00a17b586dd530b6d7a9399923a40489ca4a9a309719011175f55dc6b5dc8f41"
+
+inherit pypi setuptools3
+
+DEPENDS = "python3-setuptools-scm-native"
+
+RDEPENDS:${PN} += "python3-pytest"