Complete Yocto mirror with license table for TQMa6UL (2038-compliance)

- 264 license table entries with exact download URLs (224/264 resolved)
- Complete sources/ directory with all BitBake recipes
- Build configuration: tqma6ul-multi-mba6ulx, spaetzle (musl)
- Full traceability for Softwarefreigabeantrag
- GCC 13.4.0, Linux 6.6.102, U-Boot 2023.04, musl 1.2.4
- License distribution: GPL-2.0 (24), MIT (23), GPL-2.0+ (18), BSD-3 (16)

sources/meta-rauc/recipes-core/bundles/core-bundle-minimal.bb

@@ -0,0 +1,24 @@
+# A minimal demo bundle
+#
+# Note: The created bundle will not contain RAUC itself yet!
+# To add this, properly configure it for your specific system and add it to
+# your image recipe you intend to build a bundle from:
+#
+# IMAGE_INSTALL:append = " rauc"
+#
+# Also note that you need to configure RAUC_KEY_FILE and RAUC_CERT_FILE to
+# point to contain the full path to your key and cert.
+# Depending on you requirements you can either set them via global
+# configuration or from a bundle recipe bbappend.
+#
+# For testing purpose, you may use the scripts/openssl-ca.sh to create some.
+
+inherit bundle
+
+RAUC_BUNDLE_FORMAT = "verity"
+
+RAUC_BUNDLE_COMPATIBLE ?= "Demo Board"
+
+RAUC_BUNDLE_SLOTS ?= "rootfs"
+
+RAUC_SLOT_rootfs ?= "core-image-minimal"

sources/meta-rauc/recipes-core/busybox/busybox_%.bbappend

@@ -0,0 +1 @@
+require ${@bb.utils.contains('DISTRO_FEATURES', 'rauc', '${BPN}_rauc.inc', '', d)}

sources/meta-rauc/recipes-core/busybox/busybox_rauc.inc

@@ -0,0 +1,3 @@
+FILESEXTRAPATHS:prepend := "${THISDIR}/files:"
+
+SRC_URI += "file://rauc.cfg"

sources/meta-rauc/recipes-core/busybox/files/rauc.cfg

@@ -0,0 +1,2 @@
+CONFIG_FEATURE_TAR_LONG_OPTIONS=y
+CONFIG_FEATURE_TAR_AUTODETECT=y

sources/meta-rauc/recipes-core/packagegroups/packagegroup-base.bbappend

@@ -0,0 +1 @@
+require ${@bb.utils.contains('DISTRO_FEATURES', 'rauc', '${BPN}_rauc.inc', '', d)}

sources/meta-rauc/recipes-core/packagegroups/packagegroup-base_rauc.inc

@@ -0,0 +1,6 @@
+PACKAGES += "packagegroup-base-rauc"
+RDEPENDS:packagegroup-base += "packagegroup-base-rauc"
+
+SUMMARY:packagegroup-base-rauc = "RAUC update framework support"
+RDEPENDS:packagegroup-base-rauc = "\
+    rauc"

sources/meta-rauc/recipes-core/rauc/files/ca.cert.pem

@@ -0,0 +1,6 @@
+# This is a dummy keyring file. Please overwrite this with one that matches
+# your X509 infrastructure if you intend to use RAUC for secure updates!
+#
+# If you really do not intend to actively use the security features or for
+# testing you may create a self-signed development certificate by executing the
+# script `openssl-ca.sh` from the `scripts` folder.

sources/meta-rauc/recipes-core/rauc/files/rauc-mark-good.init

@@ -0,0 +1,23 @@
+#!/bin/sh
+### BEGIN INIT INFO
+# Provides:          rauc-mark-good
+# Required-Start:    
+# Required-Stop:     
+# Default-Start:     2 3 4 5
+# Default-Stop:      0 1 6
+# Short-Description: Rauc Good-marking Service
+### END INIT INFO
+# Author: <ejo@pengutronix.de>
+
+# Aktionen
+case "$1" in
+    start)
+        rauc status mark-good
+        ;;
+    stop)
+        ;;
+    restart)
+        ;;
+esac
+
+exit 0

sources/meta-rauc/recipes-core/rauc/files/rauc-mark-good.service

@@ -0,0 +1,15 @@
+[Unit]
+Description=RAUC Good-marking Service
+ConditionKernelCommandLine=|bootchooser.active
+ConditionKernelCommandLine=|rauc.slot
+After=boot-complete.target
+Requires=boot-complete.target
+DefaultDependencies=no
+
+[Service]
+Type=oneshot
+RemainAfterExit=yes
+ExecStart=@BINDIR@/rauc status mark-good
+
+[Install]
+WantedBy=multi-user.target

sources/meta-rauc/recipes-core/rauc/files/system.conf

@@ -0,0 +1,36 @@
+## This is an example RAUC system configuration. This file will be installed
+## into /etc/rauc/system.conf on your target and describes your system from the
+## perspective of the RAUC update service.
+##
+## Adapt and extend the below configuration to your needs and place it in the
+## BSP layer of you project. Create a rauc .bbappend file that adds this file
+## to your build:
+## 
+##   FILESEXTRAPATHS:prepend := "${THISDIR}/files:"
+##   
+## ---
+##
+# [system]
+# compatible=My Example System
+# bootloader=<barebox|uboot|grub>
+# bundle-formats=-plain
+# 
+# [slot.rootfs.0]
+# device=/dev/mmcblkXp1
+# type=ext4
+# bootname=system0
+# 
+# [slot.rootfs.1]
+# device=/dev/mmcblkXp2
+# type=ext4
+# bootname=system1
+#
+# [slot.appfs.0]
+# device=/dev/mmcblkXp3
+# type=ext4
+# parent=rootfs.0
+#
+# [slot.appfs.1]
+# device=/dev/mmcblkXp4
+# type=ext4
+# parent=rootfs.1

sources/meta-rauc/recipes-core/rauc/nativesdk-rauc.inc

@@ -0,0 +1,5 @@
+do_install:append() {
+	rm -rf ${D}${datadir}
+}
+
+inherit nativesdk

sources/meta-rauc/recipes-core/rauc/nativesdk-rauc_1.14.bb

@@ -0,0 +1,3 @@
+require rauc.inc
+require rauc-1.14.inc
+require nativesdk-rauc.inc

sources/meta-rauc/recipes-core/rauc/nativesdk-rauc_git.bb

@@ -0,0 +1,3 @@
+require rauc.inc
+require rauc-git.inc
+require nativesdk-rauc.inc

sources/meta-rauc/recipes-core/rauc/rauc-1.14.inc

@@ -0,0 +1,5 @@
+SRC_URI = "https://github.com/rauc/rauc/releases/download/v${PV}/rauc-${PV}.tar.xz"
+
+SRC_URI[sha256sum] = "f48c85573d82bf9378e907f6eba0cbe4f2021839a1e9fe3f8431f61dd54ef42c"
+
+UPSTREAM_CHECK_URI = "https://github.com/${BPN}/${BPN}/releases"

sources/meta-rauc/recipes-core/rauc/rauc-conf.bb

@@ -0,0 +1,33 @@
+SUMMARY = "RAUC system configuration & verification keyring"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
+
+RAUC_KEYRING_FILE ??= "ca.cert.pem"
+RAUC_KEYRING_URI ??= "file://${RAUC_KEYRING_FILE}"
+
+RPROVIDES:${PN} += "virtual-rauc-conf"
+
+INHIBIT_DEFAULT_DEPS = "1"
+do_compile[noexec] = "1"
+
+SRC_URI = " \
+  file://system.conf \
+  ${RAUC_KEYRING_URI} \
+  "
+
+do_install () {
+        # Create rauc config dir
+        # Warn if system configuration was not overwritten
+        if ! grep -q "^[^#]" ${WORKDIR}/system.conf; then
+                bbwarn "Please overwrite example system.conf with a project specific one!"
+        fi
+        install -d ${D}${sysconfdir}/rauc
+        install -m 0644 ${WORKDIR}/system.conf ${D}${sysconfdir}/rauc/
+
+        # Warn if CA file was not overwritten
+        if ! grep -q "^[^#]" ${WORKDIR}/${RAUC_KEYRING_FILE}; then
+                bbwarn "Please overwrite example ca.cert.pem with a project specific one, or set the RAUC_KEYRING_FILE variable with your file!"
+        fi
+        install -d ${D}${sysconfdir}/rauc
+        install -m 0644 ${WORKDIR}/${RAUC_KEYRING_FILE} ${D}${sysconfdir}/rauc/
+}

sources/meta-rauc/recipes-core/rauc/rauc-git.inc

@@ -0,0 +1,12 @@
+SRC_URI = " \ 
+  git://github.com/rauc/rauc.git;protocol=https;branch=master \
+  "
+
+PV = "1.14+git${SRCPV}"
+S = "${WORKDIR}/git"
+
+SRCREV = "2c455f87b96400779b77a3f87ac3d655a4c80bcf"
+
+RAUC_USE_DEVEL_VERSION[doc] = "Global switch to enable RAUC development (git) version."
+RAUC_USE_DEVEL_VERSION ??= "-1"
+DEFAULT_PREFERENCE ??= "${RAUC_USE_DEVEL_VERSION}"

sources/meta-rauc/recipes-core/rauc/rauc-native.inc

@@ -0,0 +1,4 @@
+inherit native
+
+DEPENDS = "openssl-native glib-2.0-native"
+RRECOMMENDS:${PN} = "squashfs-tools-native"

sources/meta-rauc/recipes-core/rauc/rauc-native_1.14.bb

@@ -0,0 +1,3 @@
+require rauc.inc
+require rauc-native.inc
+require rauc-1.14.inc

sources/meta-rauc/recipes-core/rauc/rauc-native_git.bb

@@ -0,0 +1,3 @@
+require rauc.inc
+require rauc-native.inc
+require rauc-git.inc

sources/meta-rauc/recipes-core/rauc/rauc-target.inc

@@ -0,0 +1,69 @@
+RAUC_KEYRING_FILE ??= "ca.cert.pem"
+RAUC_KEYRING_URI ??= "file://${RAUC_KEYRING_FILE}"
+
+RRECOMMENDS:${PN} += "virtual-rauc-conf"
+RRECOMMENDS:${PN} += "squashfs-tools"
+
+SRC_URI:append = " \
+  file://rauc-mark-good.service \
+  file://rauc-mark-good.init \
+  "
+
+SYSTEMD_PACKAGES += "${PN}-mark-good"
+SYSTEMD_SERVICE:${PN}-mark-good = "rauc-mark-good.service"
+
+INITSCRIPT_PACKAGES = "${PN}-mark-good"
+INITSCRIPT_NAME:${PN}-mark-good = "rauc-mark-good"
+INITSCRIPT_PARAMS:${PN}-mark-good = "start 99 5 2 . stop 20 0 1 6 ."
+
+inherit systemd update-rc.d
+
+do_install () {
+	meson_do_install
+
+        install -d ${D}${systemd_unitdir}/system/
+        install -m 0644 ${WORKDIR}/rauc-mark-good.service ${D}${systemd_unitdir}/system/
+        sed -i -e 's!@BINDIR@!${bindir}!g' ${D}${systemd_unitdir}/system/*.service
+
+        install -d "${D}${sysconfdir}/init.d"
+        install -m 755 "${WORKDIR}/rauc-mark-good.init" "${D}${sysconfdir}/init.d/rauc-mark-good"
+}
+
+PACKAGES =+ "${PN}-mark-good"
+
+# some magic to get the tool to interact with bootloader storage
+python __anonymous () {
+    bootloader = d.getVar("PREFERRED_PROVIDER_virtual/bootloader")
+
+    if not bootloader:
+        return
+
+    if "barebox" in bootloader:
+        boothelper = " dt-utils-barebox-state"
+    elif "u-boot" in bootloader:
+        boothelper = " u-boot-fw-utils"
+    elif "grub" in bootloader:
+        boothelper = " grub-editenv"
+    else:
+        return
+
+    d.appendVar("RDEPENDS:%s" % d.getVar('PN'), boothelper)
+}
+
+RRECOMMENDS:${PN}:append = " ${PN}-mark-good"
+
+FILES:${PN}-mark-good = "${systemd_unitdir}/system/rauc-mark-good.service ${sysconfdir}/init.d/rauc-mark-good"
+
+PACKAGES =+ "${PN}-service"
+SYSTEMD_SERVICE:${PN}-service = "${@bb.utils.contains('PACKAGECONFIG', 'service', 'rauc.service', '', d)}"
+SYSTEMD_PACKAGES += "${PN}-service"
+RDEPENDS:${PN}-service += "dbus"
+
+FILES:${PN}-service = "\
+  ${systemd_unitdir}/system/rauc.service \
+  ${datadir}/dbus-1/system.d/de.pengutronix.rauc.conf \
+  ${datadir}/dbus-1/system-services/de.pengutronix.rauc.service \
+  ${nonarch_libdir}/systemd/catalog \
+  "
+
+PACKAGECONFIG ??= "service network streaming json nocreate gpt"

sources/meta-rauc/recipes-core/rauc/rauc.inc

@@ -0,0 +1,26 @@
+DESCRIPTION = "RAUC update controller for host and target"
+HOMEPAGE = "https://github.com/rauc/rauc"
+LICENSE = "LGPL-2.1-or-later"
+LIC_FILES_CHKSUM = "file://COPYING;md5=4fbd65380cdd255951079008b364516c"
+DEPENDS = "openssl glib-2.0 glib-2.0-native"
+
+inherit meson pkgconfig gettext
+
+EXTRA_OEMESON += "\
+        -Dtests=false \
+        -Dsystemdunitdir=${systemd_system_unitdir} \
+        -Ddbuspolicydir=${datadir}/dbus-1/system.d \
+        -Ddbussystemservicedir=${datadir}/dbus-1/system-services \
+        -Ddbusinterfacesdir=${datadir}/dbus-1/interfaces \
+        "
+
+PACKAGECONFIG[nocreate]  = "-Dcreate=false,-Dcreate=true,"
+PACKAGECONFIG[service] = "-Dservice=true,-Dservice=false,dbus,${PN}-service"
+PACKAGECONFIG[streaming] = "-Dstreaming=true,-Dstreaming=false,libnl"
+PACKAGECONFIG[network] = "-Dnetwork=true,-Dnetwork=false,curl"
+PACKAGECONFIG[json]    = "-Djson=enabled,-Djson=disabled,json-glib"
+PACKAGECONFIG[gpt]     = "-Dgpt=enabled,-Dgpt=disabled,util-linux"
+
+FILES:${PN}-dev += "\
+  ${datadir}/dbus-1/interfaces/de.pengutronix.rauc.Installer.xml \
+  "

sources/meta-rauc/recipes-core/rauc/rauc_1.14.bb

@@ -0,0 +1,3 @@
+require rauc.inc
+require rauc-target.inc
+require rauc-1.14.inc

sources/meta-rauc/recipes-core/rauc/rauc_git.bb

@@ -0,0 +1,3 @@
+require rauc.inc
+require rauc-target.inc
+require rauc-git.inc