Complete Yocto mirror with license table for TQMa6UL (2038-compliance)

- 264 license table entries with exact download URLs (224/264 resolved)
- Complete sources/ directory with all BitBake recipes
- Build configuration: tqma6ul-multi-mba6ulx, spaetzle (musl)
- Full traceability for Softwarefreigabeantrag
- GCC 13.4.0, Linux 6.6.102, U-Boot 2023.04, musl 1.2.4
- License distribution: GPL-2.0 (24), MIT (23), GPL-2.0+ (18), BSD-3 (16)

sources/meta-rauc/recipes-support/curl/curl_%.bbappend

@@ -0,0 +1 @@
+require ${@bb.utils.contains('DISTRO_FEATURES', 'rauc', '${BPN}_rauc.inc', '', d)}

sources/meta-rauc/recipes-support/curl/curl_rauc.inc

@@ -0,0 +1,5 @@
+# HTTP/2 allows having multiple parallel (range-) requests in flight on the
+# same connection without requiring multiple TCP and TLS handshakes.
+# This speeds up adaptive updates a lot, since they work by making many
+# range-requests for parts of the update bundle.
+PACKAGECONFIG:append:class-target = " nghttp2"

sources/meta-rauc/recipes-support/rauc-hawkbit-updater/rauc-hawkbit-updater.inc

@@ -0,0 +1,25 @@
+SUMMARY = "The RAUC hawkBit updater operates as an interface between the RAUC D-Bus API and the hawkBit DDI API."
+HOMEPAGE = "https://github.com/rauc/rauc-hawkbit-updater"
+
+LICENSE = "LGPL-2.1-only"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=1a6d268fd218675ffea8be556788b780"
+
+inherit meson pkgconfig systemd useradd
+
+SYSTEMD_SERVICE:${PN} = "${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'rauc-hawkbit-updater.service', '', d)}"
+
+PACKAGECONFIG ??= " \
+    ${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)} \
+"
+PACKAGECONFIG[systemd] = "-Dsystemd=enabled,-Dsystemd=disabled,systemd"
+
+USERADD_PACKAGES = "${PN}"
+USERADD_PARAM:${PN} = "--system --home-dir / --no-create-home --shell /bin/false rauc-hawkbit"
+
+DEPENDS = "curl glib-2.0-native json-glib"
+
+do_install:append () {
+	install -d ${D}${sysconfdir}/${PN}
+	install -m 644 ${S}/config.conf.example ${D}${sysconfdir}/${PN}/config.conf
+}
+

sources/meta-rauc/recipes-support/rauc-hawkbit-updater/rauc-hawkbit-updater_1.3.bb

@@ -0,0 +1,4 @@
+include rauc-hawkbit-updater.inc
+
+SRC_URI = "https://github.com/rauc/${BPN}/releases/download/v${PV}/${BPN}-${PV}.tar.xz"
+SRC_URI[sha256sum] = "42318e96a464e6c716edb45c48bd3ec3b874462973db902fbe099a395e4acb4b"

sources/meta-rauc/recipes-support/rauc-hawkbit-updater/rauc-hawkbit-updater_git.bb

@@ -0,0 +1,8 @@
+include rauc-hawkbit-updater.inc
+
+SRC_URI = "git://github.com/rauc/rauc-hawkbit-updater.git;protocol=https;branch=master"
+SRCREV = "e19bc259a615ea31584c4056f365db46237d70f9"
+S = "${WORKDIR}/git"
+PV = "1.3+git${SRCPV}"
+
+DEFAULT_PREFERENCE = "-1"

sources/meta-rauc/recipes-support/rauc-hawkbit/files/rauc-hawkbit.service

@@ -0,0 +1,9 @@
+[Unit]
+Description=rauc-hawkbit client service
+Requires=rauc.service
+
+[Service]
+ExecStart=@BINDIR@/rauc-hawkbit-client -c @SYSCONFDIR@/rauc-hawkbit/config.cfg
+
+[Install]
+WantedBy=multi-user.target

sources/meta-rauc/recipes-support/rauc-hawkbit/rauc-hawkbit_git.bb

@@ -0,0 +1,41 @@
+LICENSE = "LGPL-2.1-or-later"
+LIC_FILES_CHKSUM = " \
+    file://COPYING;md5=4fbd65380cdd255951079008b364516c \
+    file://README.rst;beginline=114;endline=132;md5=aff2a45fabc5c8d959b72f97ffc77465 \
+    "
+
+SUMMARY = "hawkBit client for RAUC"
+
+DEPENDS = "python3-setuptools-scm-native"
+
+SRC_URI = " \
+    git://github.com/rauc/rauc-hawkbit.git;protocol=https;branch=master \
+    file://rauc-hawkbit.service \
+"
+
+PV = "0.2.0+git${SRCPV}"
+SRCREV = "47bebb4a011768817f13f7796ec1b4e67edaffc5"
+
+S = "${WORKDIR}/git"
+
+inherit setuptools3 systemd
+
+PACKAGES =+ "${PN}-service"
+SYSTEMD_SERVICE:${PN}-service = "rauc-hawkbit.service"
+SYSTEMD_PACKAGES = "${PN}-service"
+
+do_install:append() {
+	install -d ${D}${sysconfdir}/${BPN}/
+	install -m 0644 ${S}/rauc_hawkbit/config.cfg ${D}${sysconfdir}/${BPN}/config.cfg
+	install -d ${D}${systemd_unitdir}/system/
+	install -m 0644 ${WORKDIR}/rauc-hawkbit.service ${D}${systemd_unitdir}/system/
+	sed -i -e 's!@BINDIR@!${bindir}!g' -e 's!@SYSCONFDIR@!${sysconfdir}!g' \
+		${D}${systemd_unitdir}/system/rauc-hawkbit.service
+}
+
+RDEPENDS:${PN} += "python3-aiohttp python3-gbulb"
+FILES:${PN}-service = " \
+    ${bindir}/rauc-hawkbit-client \
+    ${sysconfdir}/${BPN}/config.cfg \
+    ${systemd_unitdir}/system/rauc-hawkbit.service \
+"