Complete Yocto mirror with license table for TQMa6UL (2038-compliance)

- 264 license table entries with exact download URLs (224/264 resolved)
- Complete sources/ directory with all BitBake recipes
- Build configuration: tqma6ul-multi-mba6ulx, spaetzle (musl)
- Full traceability for Softwarefreigabeantrag
- GCC 13.4.0, Linux 6.6.102, U-Boot 2023.04, musl 1.2.4
- License distribution: GPL-2.0 (24), MIT (23), GPL-2.0+ (18), BSD-3 (16)

sources/meta-tq/meta-dumpling/recipes-core/base-files/base-files/handle_issue.sh

@@ -0,0 +1,3 @@
+if [ -n "$SSH_TTY" ]; then
+	cat /etc/issue.net
+fi

sources/meta-tq/meta-dumpling/recipes-core/base-files/base-files_3.0.%.bbappend

@@ -0,0 +1,49 @@
+#
+# this bbappend is intended to be used with example distros defined in this
+# layer. It shows, how to customize the banner files /etc/issue[.net]
+#
+DEPENDS += "figlet-native"
+
+FILESEXTRAPATHS:prepend := "${THISDIR}/${BPN}:"
+
+SRC_URI:append = "\
+    file://handle_issue.sh \
+"
+
+dirs755:append = "\
+    ${sysconfdir}/profile.d \
+"
+
+# this usually comes from our distro
+VENDOR_LONG_NAME ??= "TQ-Systems"
+DISTRO_SHORT_NAME ??= "dumpling"
+
+do_install:append() {
+    install -m 0755 ${WORKDIR}/handle_issue.sh ${D}${sysconfdir}/profile.d/handle_issue.sh
+}
+
+do_install_basefilesissue:append() {
+    # rewrite issue.net to prevent telnetd escape codes in the banner
+    if [ -n "${DISTRO_NAME}" ]; then
+        printf "%s" "${DISTRO_NAME}" > ${D}${sysconfdir}/issue.net
+        if [ -n "${DISTRO_VERSION}" ]; then
+            distro_version_nodate="${@d.getVar('DISTRO_VERSION').replace('snapshot-${DATE}','snapshot').replace('${DATE}','')}"
+            printf " %s" "${distro_version_nodate}" >> ${D}${sysconfdir}/issue.net
+        fi
+        echo >> ${D}${sysconfdir}/issue.net
+    fi
+
+    figlet -c -d ${RECIPE_SYSROOT_NATIVE}/usr/share/figlet -- "${VENDOR_LONG_NAME}" | \
+        sed 's,\\,\\\\,g'  >> ${D}${sysconfdir}/issue
+    echo "\n" >> ${D}${sysconfdir}/issue
+    figlet -c -d ${RECIPE_SYSROOT_NATIVE}/usr/share/figlet -- "${DISTRO_SHORT_NAME}" | \
+        sed 's,\\,\\\\,g'  >> ${D}${sysconfdir}/issue
+    echo "\n" >> ${D}${sysconfdir}/issue
+
+    figlet -c -d ${RECIPE_SYSROOT_NATIVE}/usr/share/figlet -- "${VENDOR_LONG_NAME}" >> \
+        ${D}${sysconfdir}/issue.net
+    echo "\n" >> ${D}${sysconfdir}/issue.net
+    figlet -c -d ${RECIPE_SYSROOT_NATIVE}/usr/share/figlet -- "${DISTRO_SHORT_NAME}" >> \
+        ${D}${sysconfdir}/issue.net
+    echo "\n" >> ${D}${sysconfdir}/issue.net
+}