Complete Yocto mirror with license table for TQMa6UL (2038-compliance)

- 264 license table entries with exact download URLs (224/264 resolved)
- Complete sources/ directory with all BitBake recipes
- Build configuration: tqma6ul-multi-mba6ulx, spaetzle (musl)
- Full traceability for Softwarefreigabeantrag
- GCC 13.4.0, Linux 6.6.102, U-Boot 2023.04, musl 1.2.4
- License distribution: GPL-2.0 (24), MIT (23), GPL-2.0+ (18), BSD-3 (16)

sources/meta-tq/meta-dumpling/recipes-core/tq-mount-data/tq-mount-data.bb

@@ -0,0 +1,41 @@
+# SPDX-License-Identifier: MIT
+#
+# Copyright (c) 2024 TQ-Systems GmbH <oss@ew.tq-group.com>, D-82229 Seefeld, Germany.
+# Author: Matthias Schiffer
+
+SUMMARY = "Automatic mount of a data partition for TQ platforms"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/MIT;md5=0835ade698e0bcf8506ecda2f7b4f302"
+
+inherit allarch systemd update-rc.d
+
+SRC_URI = "\
+    file://tq-mount-data.service \
+    file://tq-mount-data.sh \
+"
+TQ_DATA_MOUNT_TARGET ?= "/srv/data"
+
+SYSTEMD_SERVICE:${PN} = "tq-mount-data.service"
+
+INITSCRIPT_NAME = "tq-mount-data.sh"
+INITSCRIPT_PARAMS = "start 05 S ."
+
+RDEPENDS:${PN} += "util-linux-findmnt"
+
+do_install() {
+    install -Dm 755 "${WORKDIR}/tq-mount-data.sh" "${D}${libexecdir}/tq/mount-data.sh"
+    sed -i -e "s,@TQ_DATA_MOUNT_TARGET@,${TQ_DATA_MOUNT_TARGET},g" "${D}${libexecdir}/tq/mount-data.sh"
+
+    if ${@bb.utils.contains('DISTRO_FEATURES', 'sysvinit', 'true', 'false', d)}; then
+	    install -d ${D}${sysconfdir}/init.d/
+        ln -s ${libexecdir}/tq/mount-data.sh ${D}${sysconfdir}/init.d/tq-mount-data.sh
+    fi
+
+    if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
+        install -Dm 0644 "${WORKDIR}/tq-mount-data.service" "${D}${systemd_system_unitdir}/tq-mount-data.service"
+        sed -i -e "s,@LIBEXECDIR@,${libexecdir},g" "${D}${systemd_system_unitdir}/tq-mount-data.service"
+    fi
+
+    install -d "${D}${TQ_DATA_MOUNT_TARGET}"
+}
+FILES:${PN} += "${TQ_DATA_MOUNT_TARGET}"

sources/meta-tq/meta-dumpling/recipes-core/tq-mount-data/tq-mount-data/tq-mount-data.service

@@ -0,0 +1,17 @@
+# SPDX-License-Identifier: MIT
+#
+# Copyright (c) 2024 TQ-Systems GmbH <oss@ew.tq-group.com>, D-82229 Seefeld, Germany.
+# Author: Matthias Schiffer
+
+[Unit]
+Description=Data partition mount
+DefaultDependencies=no
+Before=sysinit.target
+
+[Service]
+ExecStart=@LIBEXECDIR@/tq/mount-data.sh
+Type=oneshot
+RemainAfterExit=yes
+
+[Install]
+WantedBy=sysinit.target

sources/meta-tq/meta-dumpling/recipes-core/tq-mount-data/tq-mount-data/tq-mount-data.sh

@@ -0,0 +1,40 @@
+#!/bin/sh
+
+# SPDX-License-Identifier: MIT
+#
+# Copyright (c) 2024 TQ-Systems GmbH <oss@ew.tq-group.com>, D-82229 Seefeld, Germany.
+# Author: Matthias Schiffer
+
+set -e
+
+TQ_DATA_MOUNT_TARGET='@TQ_DATA_MOUNT_TARGET@'
+
+get_root_dev () {
+	findmnt --evaluate --first-only --noheadings --output SOURCE --mountpoint /
+}
+
+get_data_dev () {
+	local root_dev
+	root_dev=$(get_root_dev)
+	case "${root_dev}" in
+	# 2 and 3 are possible root partitions in our WKS files for RAUC
+	/dev/*2|/dev/*3)
+		# Data is partition 4
+		echo "${root_dev}" | sed -e 's/.$/4/'
+		;;
+	esac
+}
+
+main () {
+	local data_dev
+
+	data_dev=$(get_data_dev)
+
+	if [ -z "${data_dev}" ]; then
+		return 0
+	fi
+
+	mount "${data_dev}" "${TQ_DATA_MOUNT_TARGET}"
+}
+
+main "$@"