Complete Yocto mirror with license table for TQMa6UL (2038-compliance)

- 264 license table entries with exact download URLs (224/264 resolved)
- Complete sources/ directory with all BitBake recipes
- Build configuration: tqma6ul-multi-mba6ulx, spaetzle (musl)
- Full traceability for Softwarefreigabeantrag
- GCC 13.4.0, Linux 6.6.102, U-Boot 2023.04, musl 1.2.4
- License distribution: GPL-2.0 (24), MIT (23), GPL-2.0+ (18), BSD-3 (16)

sources/meta-tq/meta-dumpling/recipes-images/images/tq-image-base.inc

@@ -0,0 +1,17 @@
+LICENSE = "MIT"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+IMAGE_INSTALL:append = "\
+    packagegroup-base \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', ' packagegroup-systemd', '', d)} \
+    packagegroup-hwutils-base \
+    packagegroup-fsutils \
+    packagegroup-netutils \
+    packagegroup-sysutils \
+    ${@bb.utils.contains('MACHINE_FEATURES', 'can', 'packagegroup-can', '', d)} \
+    ${@bb.utils.contains('MACHINE_FEATURES', 'lte', 'packagegroup-lte', '', d)} \
+    ${@bb.utils.contains('COMBINED_FEATURES', 'alsa', 'packagegroup-audio', '', d)} \
+    ${@bb.utils.contains('COMBINED_FEATURES', 'npu', 'packagegroup-npu', '',d)} \
+    ${@bb.utils.contains('COMBINED_FEATURES', 'wifi', 'packagegroup-wifi', '',d)} \
+"

sources/meta-tq/meta-dumpling/recipes-images/images/tq-image-debug.inc

@@ -0,0 +1,34 @@
+# For modifying /etc/issue during rootfs postbuild steps
+DEPENDS += "figlet-native"
+
+# plenty of tools for test / development
+IMAGE_INSTALL:append = "\
+    packagegroup-testutils \
+"
+
+# enable root login w/o password and passwordless ssh login
+IMAGE_FEATURES:append = " debug-tweaks"
+# poky defined collection of debug tools
+# tools-testapps is not appended here since it increases images size
+# without having a global benefit due to ltp and complex dependencies
+IMAGE_FEATURES:append = " tools-debug"
+
+#
+# Add a postprocess command to add a note and a message in the issue banner files
+# if debug setting can be found in IMAGE_FEATURES
+#
+ISSUE_WARN = "WARNING: your rootfs has debug settings enabled and is not secure."
+
+do_issue_warning () {
+    figlet -c -d ${RECIPE_SYSROOT_NATIVE}/usr/share/figlet -- "development" | \
+            sed 's,\\,\\\\,g'  >> "${IMAGE_ROOTFS}/${sysconfdir}/issue"
+    echo "${ISSUE_WARN}" >> "${IMAGE_ROOTFS}/${sysconfdir}/issue"
+
+    figlet -c -d ${RECIPE_SYSROOT_NATIVE}/usr/share/figlet -- "development" >> \
+            "${IMAGE_ROOTFS}/${sysconfdir}/issue.net"
+    echo "${ISSUE_WARN}" >> "${IMAGE_ROOTFS}/${sysconfdir}/issue.net"
+}
+
+ROOTFS_POSTPROCESS_COMMAND += '${@bb.utils.contains_any("IMAGE_FEATURES", \
+    [ 'debug-tweaks', 'empty-root-password', 'allow-root-login' ], \
+    "do_issue_warning; ", "",d)}'

sources/meta-tq/meta-dumpling/recipes-images/images/tq-image-generic-debug.bb

@@ -0,0 +1,9 @@
+require tq-image-generic.bb
+require tq-image-debug.inc
+
+SUMMARY =  "This is a generic image for TQ SOM with test and debug features."
+
+DESCRIPTION = "Demo image based on tq-image-generic and selection of packages \
+and IMAGE_FEATURES usually needed for development, debugging and testing. \
+This creates a medium sized image, that must not be used for production - \
+especially from the aspect of security."

sources/meta-tq/meta-dumpling/recipes-images/images/tq-image-generic-rt-debug.bb

@@ -0,0 +1,10 @@
+require tq-image-generic-rt.bb
+require tq-image-debug.inc
+
+SUMMARY =  "This is a generic image for TQ SOM running PREEMPT_RT kernel with test and debug features."
+
+DESCRIPTION = "Demo image based on core-image-generic and essential packages \
+for the machine. This creates a larger image and includes real-time test suite \
+and tools appropriate for real-time use. \
+This creates a medium sized image, that must not be used for production - \
+especially from the aspect of security."

sources/meta-tq/meta-dumpling/recipes-images/images/tq-image-generic-rt.bb

@@ -0,0 +1,22 @@
+require recipes-core/images/core-image-minimal.bb
+
+# Skip processing of this recipe if linux-rt-tq is not explicitly specified as the
+# PREFERRED_PROVIDER for virtual/kernel. This avoids errors when trying
+# to build multiple virtual/kernel providers.
+python () {
+    if d.getVar("PREFERRED_PROVIDER_virtual/kernel") != "linux-rt-tq":
+        raise bb.parse.SkipRecipe("Set PREFERRED_PROVIDER_virtual/kernel to linux-rt-tq to enable it")
+}
+
+SUMMARY =  "This is an RT image for TQ SOM with some RT test / debug tools."
+DESCRIPTION = "Demo image based on core-image-minimal and essential packages \
+for the machine. This creates a larger image and includes real-time test suite \
+and tools appropriate for real-time use."
+DEPENDS += "linux-rt-tq"
+
+IMAGE_INSTALL += "\
+    rt-tests \
+    hwlatdetect \
+"
+
+require tq-image.inc

sources/meta-tq/meta-dumpling/recipes-images/images/tq-image-generic.bb

@@ -0,0 +1,11 @@
+require recipes-core/images/core-image-minimal.bb
+require tq-image.inc
+
+SUMMARY =  "This is a generic image for TQ SOM with some test features."
+
+DESCRIPTION = "Demo image based on core-image-minimal, the base for a \
+booting system and essential packages for the machine. This creates a medium sized image \
+and includes also test tools, not directly suitable for production - \
+also from the aspect of security."
+
+LICENSE = "MIT"

sources/meta-tq/meta-dumpling/recipes-images/images/tq-image-small-debug.bb

@@ -0,0 +1,11 @@
+require tq-image-small.bb
+
+SUMMARY =  "This is a small image for TQ SOM with some test and debug features."
+
+DESCRIPTION = "Demo image based on tq-image-generic and minimal selection of packages \
+and IMAGE_FEATURES usually needed for development, debugging and testing. \
+This creates a small image, that must not be used for production - \
+especially from the aspect of security."
+
+# enable root login w/o password and passwordless ssh login
+IMAGE_FEATURES:append = " debug-tweaks"

sources/meta-tq/meta-dumpling/recipes-images/images/tq-image-small.bb

@@ -0,0 +1,12 @@
+require recipes-core/images/core-image-minimal.bb
+require tq-image-base.inc
+
+SUMMARY =  "This is a small image for TQ SOM with some test / debug features."
+
+DESCRIPTION = "Demo image based on core-image-minimal and essential packages \
+for the machine. This creates a large image and includes also debug tools, not \
+directly suitable for production - also from the aspect of security."
+
+# force dropbear
+IMAGE_FEATURES:append = " ssh-server-dropbear"
+IMAGE_FEATURES:remove = "ssh-server-openssh"

sources/meta-tq/meta-dumpling/recipes-images/images/tq-image-weston-debug.bb

@@ -0,0 +1,9 @@
+require tq-image-weston.bb
+require tq-image-debug.inc
+
+SUMMARY =  "This is a weston image for TQ SOM with test and debug features."
+
+DESCRIPTION = "Demo image based on tq-image-weston and selection of packages \
+and IMAGE_FEATURES usually needed for development, debugging and testing. \
+This creates a medium sized image, that must not be used for production - \
+especially from the aspect of security."

sources/meta-tq/meta-dumpling/recipes-images/images/tq-image-weston.bb

@@ -0,0 +1,31 @@
+# for now: use poky weston image as a base
+require recipes-graphics/images/core-image-weston.bb
+
+# add our default stuff
+require tq-image.inc
+
+SUMMARY =  "This is a weston image for TQ SOM with some test features."
+
+DESCRIPTION = "Demo image based on core-image-weston and essential packages \
+for the machine. This creates a large image and includes also test tools, not \
+directly suitable for production - also from the aspect of security."
+
+LICENSE = "MIT"
+
+IMAGE_FEATURES:remove = "package-management"
+IMAGE_FEATURES:append = " splash"
+
+###
+# this may be a little bit overkill
+###
+THISIMAGE_GSTREAMER_PLUGINS = "\
+    gstreamer1.0-plugins-base-meta \
+    gstreamer1.0-plugins-good-meta \
+    gstreamer1.0-plugins-bad-meta \
+"
+
+IMAGE_INSTALL:append = "\
+    weston-examples \
+    ${THISIMAGE_GSTREAMER_PLUGINS} \
+    packagegroup-dumpling-gstreamer \
+"

sources/meta-tq/meta-dumpling/recipes-images/images/tq-image.inc

@@ -0,0 +1,13 @@
+LICENSE = "MIT"
+
+require tq-image-base.inc
+
+IMAGE_INSTALL:append = "\
+    coreutils \
+    ${@bb.utils.contains('MACHINE_FEATURES', 'camera', ' packagegroup-v4l2', '', d)} \
+    ${@bb.utils.contains('MACHINE_FEATURES', 'vpu', ' packagegroup-v4l2', '', d)} \
+"
+
+# force openssh to prevent conflict with dropbear
+IMAGE_FEATURES:append = " ssh-server-openssh"
+IMAGE_FEATURES:remove = "ssh-server-dropbear"

sources/meta-tq/meta-dumpling/recipes-images/packagegroups/packagegroup-audio.bb

@@ -0,0 +1,14 @@
+DESCRIPTION = "tools needed for basic audio support / testing"
+LICENSE = "MIT"
+
+# prevent warning related to dynamic package renaming
+PACKAGE_ARCH = "${TUNE_PKGARCH}"
+
+inherit packagegroup
+
+RDEPENDS:${PN} = "\
+    alsa-lib \
+    alsa-utils \
+    alsa-tools \
+    alsa-state \
+"

sources/meta-tq/meta-dumpling/recipes-images/packagegroups/packagegroup-can.bb

@@ -0,0 +1,10 @@
+DESCRIPTION = "tools needed for CAN support / testing"
+LICENSE = "MIT"
+
+inherit packagegroup
+
+RDEPENDS:${PN} = "\
+    can-utils \
+    can-utils-cantest \
+    iproute2 \
+"

sources/meta-tq/meta-dumpling/recipes-images/packagegroups/packagegroup-dumpling-gstreamer.bb

@@ -0,0 +1,117 @@
+DESCRIPTION = "Package group to provide audio, video, networking and debug \
+GStreamer plugins with the required hardware acceleration (if supported by the SoC)."
+
+SUMMARY = "set of commonly used GStreamer 1.0 plugins"
+
+LICENSE = "MIT"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+inherit packagegroup
+
+PACKAGES += "\
+    ${PN}-base \
+    ${PN}-audio \
+    ${PN}-video \
+    ${PN}-video-bad \
+    ${PN}-debug \
+    ${PN}-network-base \
+    ${PN}-network \
+"
+
+RDEPENDS:${PN} = "\
+    ${PN}-audio \
+    ${PN}-video \
+    ${PN}-network-base \
+    ${PN}-debug \
+"
+
+# List of X11 specific plugins
+GST_X11_PACKAGES = "\
+    gstreamer1.0-plugins-base-ximagesink \
+    gstreamer1.0-plugins-base-xvimagesink \
+"
+
+# List of Wayland specific plugins
+GST_WAYLAND_PACKAGES = "\
+    gstreamer1.0-plugins-bad-waylandsink \
+"
+
+# basic plugins required in virtually every pipeline
+RDEPENDS:${PN}-base = "\
+    gstreamer1.0 \
+    gstreamer1.0-plugins-base-playback \
+    ${@bb.utils.contains('COMBINED_FEATURES', 'alsa', 'gstreamer1.0-plugins-base-alsa', '', d)} \
+    gstreamer1.0-plugins-base-audioconvert \
+    gstreamer1.0-plugins-base-audioresample \
+    gstreamer1.0-plugins-base-gio \
+    gstreamer1.0-plugins-base-typefindfunctions \
+    gstreamer1.0-plugins-base-videoconvertscale \
+    gstreamer1.0-plugins-base-volume \
+    gstreamer1.0-plugins-good-autodetect \
+"
+
+RRECOMMENDS:${PN}-base = "\
+    ${@bb.utils.contains('DISTRO_FEATURES', 'x11', '${GST_X11_PACKAGES}', \
+                          bb.utils.contains('DISTRO_FEATURES', 'wayland', \
+                                            '${GST_WAYLAND_PACKAGES}', '', d), d)} \
+"
+
+# Basic audio plugins: parsers, demuxers, decoders
+RDEPENDS:${PN}-audio = "\
+    ${PN}-base \
+    gstreamer1.0-plugins-base-ogg \
+    gstreamer1.0-plugins-good-audioparsers \
+    gstreamer1.0-plugins-good-flac \
+    gstreamer1.0-plugins-good-icydemux \
+    gstreamer1.0-plugins-good-id3demux \
+    gstreamer1.0-plugins-good-speex \
+    gstreamer1.0-plugins-good-wavparse \
+"
+
+# Basic video plugins: parsers, demuxers
+RDEPENDS:${PN}-video = "\
+    ${PN}-base \
+    gstreamer1.0-plugins-base-subparse \
+    gstreamer1.0-plugins-base-theora \
+    gstreamer1.0-plugins-good-avi \
+    gstreamer1.0-plugins-good-flv \
+    gstreamer1.0-plugins-good-isomp4 \
+    gstreamer1.0-plugins-good-matroska \
+"
+
+RRECOMMENDS:${PN}-video = "\
+    ${PN}-audio \
+"
+
+# Additional video plugins from the -bad collection
+RDEPENDS:${PN}-video-bad = "\
+    ${PN}-video \
+    gstreamer1.0-plugins-bad-mpegpsdemux \
+    gstreamer1.0-plugins-bad-mpegtsdemux \
+    gstreamer1.0-plugins-bad-videoparsersbad \
+"
+
+# Plugins used for diagnostics and debugging of pipelines
+RDEPENDS:${PN}-debug = "\
+    ${PN}-base \
+    gstreamer1.0-plugins-base-audiotestsrc \
+    gstreamer1.0-plugins-base-videotestsrc \
+    gstreamer1.0-plugins-good-debug \
+    gstreamer1.0-plugins-good-navigationtest \
+"
+
+# Basic networking plugins required by most pipelines that receive and/or send data
+RDEPENDS:${PN}-network-base = "\
+    gstreamer1.0-plugins-base-tcp \
+    gstreamer1.0-plugins-good-soup \
+    gstreamer1.0-plugins-good-udp \
+"
+
+# Additional networking plugins
+RDEPENDS:${PN}-network = "\
+    ${PN}-network-base \
+    gstreamer1.0-plugins-good-rtp \
+    gstreamer1.0-plugins-good-rtpmanager \
+    gstreamer1.0-plugins-good-rtsp \
+"

sources/meta-tq/meta-dumpling/recipes-images/packagegroups/packagegroup-fsutils.bb

@@ -0,0 +1,22 @@
+DESCRIPTION = "tools needed to support different types of file systems and storage"
+LICENSE = "MIT"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+inherit packagegroup
+
+
+# needed for Rootfs on [Q]SPI
+MTD_UTILS_PACKAGES = "\
+    mtd-utils \
+    mtd-utils-misc \
+    mtd-utils-jffs2 \
+    mtd-utils-ubifs \
+"
+
+RDEPENDS:${PN} = "\
+    parted \
+    e2fsprogs \
+    ${@bb.utils.contains('BBFILE_COLLECTIONS', 'filesystems-layer', ' f2fs-tools', '', d)} \
+    ${@bb.utils.contains('MACHINE_FEATURES', 'ubi', ' ${MTD_UTILS_PACKAGES}', '', d)} \
+"

sources/meta-tq/meta-dumpling/recipes-images/packagegroups/packagegroup-hwutils.bb

@@ -0,0 +1,51 @@
+DESCRIPTION = "tools needed to test basic hw support"
+LICENSE = "MIT"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+inherit packagegroup
+
+PACKAGES = "\
+    ${PN}-base \
+    ${PN}-extended \
+"
+
+USB_BASE_DEPENDS = "\
+    uhubctl \
+    usbutils \
+"
+
+####################################
+# If we ever need to use USB devices that initially enumerate as mass
+# storage device for the purpose of bringing Windows (TM) drivers and software
+# and switching after an amount of time to their primary function we could
+# install usb-modeswitch and usb-modeswitch-data. This will enable directly
+# switching to the primary function of the device based on udev / systemd
+# Since usb-modeswitch depends on TCL we leave this out here per default
+####################################
+USB_EXT_DEPENDS = "\
+    usb-modeswitch \
+    usb-modeswitch-data \
+"
+
+RDEPENDS:${PN}-base = "\
+    mmc-utils \
+    i2c-tools \
+    libgpiod \
+    libgpiod-tools \
+    lmsensors-libsensors \
+    lmsensors-sensors \
+    minicom \
+    ${@bb.utils.contains('MACHINE_FEATURES', 'pci', ' pciutils', '', d)} \
+    screen \
+    spitools \
+    ${@bb.utils.contains('MACHINE_FEATURES', 'usbhost', ' ${USB_BASE_DEPENDS}', '', d)} \
+"
+
+# allows to use this package in image recipes without having USB host support
+# for the machine.
+ALLOW_EMPTY:${PN}-extended = "1"
+
+RDEPENDS:${PN}-extended = "\
+    ${@bb.utils.contains('MACHINE_FEATURES', 'usbhost', ' ${USB_EXT_DEPENDS}', '', d)} \
+"

sources/meta-tq/meta-dumpling/recipes-images/packagegroups/packagegroup-lte.bb

@@ -0,0 +1,9 @@
+DESCRIPTION = "tools needed for LTE support with Quectel EC21-E module"
+LICENSE = "MIT"
+
+inherit packagegroup
+
+RDEPENDS:${PN} = "\
+    ppp \
+    quectel-ppp \
+"

sources/meta-tq/meta-dumpling/recipes-images/packagegroups/packagegroup-netutils.bb

@@ -0,0 +1,11 @@
+DESCRIPTION = "tools needed for network support / testing"
+LICENSE = "MIT"
+
+inherit packagegroup
+
+RDEPENDS:${PN} = "\
+    ethtool \
+    iperf2 \
+    iperf3 \
+    iproute2 \
+"

sources/meta-tq/meta-dumpling/recipes-images/packagegroups/packagegroup-npu.bb

@@ -0,0 +1,11 @@
+DESCRIPTION = "tools needed for NPU support"
+LICENSE = "MIT"
+
+# allow depend on machine specific packages
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+inherit packagegroup
+
+# Default dependencies
+RDEPENDS:${PN} = "\
+"

sources/meta-tq/meta-dumpling/recipes-images/packagegroups/packagegroup-npu.bbappend

@@ -0,0 +1,12 @@
+# Add runtime dependencies for i.MX8M Plus tensorflow delegate
+RDEPENDS:${PN}:append:mx8mp-nxp-bsp  = " tensorflow-lite-vx-delegate"
+
+MX93_PKGS_LIST = " \
+    ethos-u-firmware \
+    ethos-u-vela \
+    ethos-u-driver-stack \
+    tensorflow-lite \
+    tensorflow-lite-ethosu-delegate \
+"
+
+RDEPENDS:${PN}:append:mx93-nxp-bsp  = " ${MX93_PKGS_LIST}"

sources/meta-tq/meta-dumpling/recipes-images/packagegroups/packagegroup-systemd.bb

@@ -0,0 +1,10 @@
+DESCRIPTION = "systemd packages"
+LICENSE = "MIT"
+
+inherit packagegroup
+
+RDEPENDS:${PN} = "\
+    systemd \
+    systemd-machine-units \
+    systemd-serialgetty \
+"

sources/meta-tq/meta-dumpling/recipes-images/packagegroups/packagegroup-sysutils.bb

@@ -0,0 +1,16 @@
+DESCRIPTION = "tools needed to test basic hw support"
+LICENSE = "MIT"
+
+# allow depend on machine specific packages
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+inherit packagegroup
+
+RDEPENDS:${PN} = "\
+    cpufrequtils \
+    cpupower \
+    ${@oe.utils.ifelse(d.getVar('PREFERRED_PROVIDER_virtual/bootloader').startswith('u-boot'), 'libubootenv-bin', '')} \
+    linuxptp \
+    procps-sysctl \
+    rng-tools \
+"

sources/meta-tq/meta-dumpling/recipes-images/packagegroups/packagegroup-testutils.bb

@@ -0,0 +1,78 @@
+DESCRIPTION = "test and debugging tools"
+LICENSE = "MIT"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+inherit packagegroup
+
+#the following builds cross gdb and gdbserver
+#DEPENDS += "gdb-cross-${TARGET_ARCH}"
+
+# note: we could also use packagegroup-core-tools-debug
+# but this would install a full fledged gbd on target
+# maybe perl comes also in as a dependency for mtrace
+# and that's not what we want
+
+ALSA_RDEPENDS = "\
+    alsa-utils-alsabat \
+    alsa-utils-speakertest \
+"
+
+RDEPENDS:${PN} = "\
+    ${@bb.utils.contains('COMBINED_FEATURES', 'alsa', ' ${ALSA_RDEPENDS}', '', d)} \
+    atop \
+    dool \
+    evtest \
+    gdbserver \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'opengl', ' glmark2', '', d)} \
+    htop \
+    iotop \
+    libiio-tests \
+    mc \
+    memtester \
+    nano \
+    strace \
+    stressapptest \
+    stress-ng \
+"
+
+#
+# although we should use openssh, prepare to use the packagegroup with dropbear
+# sftp is needed for IDE like QtCreator
+# lscpu is also good to have for testing
+#
+RRECOMMENDS:${PN} = "\
+    openssh-sftp-server \
+    ${VIRTUAL-RUNTIME_base-utils-lscpu} \
+"
+
+DISPLAY_RRECOMMENDS = "\
+    fb-test \
+    libdrm-tests \
+"
+
+RRECOMMENDS:${PN} += "\
+    ${@bb.utils.contains('MACHINE_FEATURES', 'screen', '${DISPLAY_RRECOMMENDS}', '', d)} \
+"
+
+# Note: kmscube is only available if we have opengl and if virtual/libgbm
+# is built. Since this is at least not the case for TQMa6x with vendor graphic
+# stack we need this ugly construct
+# Currently only kmscube needs to be handled
+python () {
+    opengl_rrecommends = ''
+
+    if bb.utils.contains('DISTRO_FEATURES', 'opengl', True, False, d):
+        provider_libgbm = d.getVar('PREFERRED_PROVIDER_virtual/libgbm') or None
+        if provider_libgbm:
+             bb.note("opengl and libgbm provided: adding kmscube")
+             opengl_rrecommends += 'kmscube'
+        else:
+             bb.note("opengl but no libgbm provider")
+    else:
+        bb.note("no opengl and no libgbm")
+
+    d.setVar('OPENGL_RRECOMMENDS', opengl_rrecommends)
+}
+
+RRECOMMENDS:${PN} += "${OPENGL_RRECOMMENDS}"

sources/meta-tq/meta-dumpling/recipes-images/packagegroups/packagegroup-v4l2.bb

@@ -0,0 +1,38 @@
+DESCRIPTION = "camera and video codec testing tools"
+LICENSE = "MIT"
+
+# prevent warning related to dynamic package renaming
+PACKAGE_ARCH = "${TUNE_PKGARCH}"
+
+inherit packagegroup
+
+GST_PKGS = "\
+    gstreamer1.0 \
+    gstreamer1.0-plugins-bad-autoconvert \
+    gstreamer1.0-plugins-bad-fbdevsink \
+    gstreamer1.0-plugins-bad-gdp \
+    gstreamer1.0-plugins-bad-pnm \
+    gstreamer1.0-plugins-bad-kms \
+    gstreamer1.0-plugins-base-tcp \
+    gstreamer1.0-plugins-base-typefindfunctions \
+    gstreamer1.0-plugins-base-videoconvertscale \
+    gstreamer1.0-plugins-base-videotestsrc \
+    gstreamer1.0-plugins-good-meta \
+    gstreamer1.0-plugins-good-multifile \
+    gstreamer1.0-plugins-good-rtp \
+    gstreamer1.0-plugins-good-rtsp \
+    gstreamer1.0-plugins-good-udp \
+    gstreamer1.0-plugins-good-video4linux2 \
+    gstreamer1.0-plugins-good-videocrop \
+    gstreamer1.0-plugins-good-videofilter \
+\
+    gstreamer1.0-plugin-bayer2rgb-neon \
+"
+
+RDEPENDS:${PN} = "\
+    ${GST_PKGS} \
+    bayer2rgb-neon-bin \
+    media-ctl \
+    v4l-utils \
+    yavta \
+"

sources/meta-tq/meta-dumpling/recipes-images/packagegroups/packagegroup-wifi.bb

@@ -0,0 +1,12 @@
+DESCRIPTION = "tools for wifi support"
+LICENSE = "MIT"
+
+inherit packagegroup
+
+RDEPENDS:${PN} = "\
+    wpa-supplicant \
+    hostapd \
+    iw \
+    wireless-regdb-static \
+"
+