Complete Yocto mirror with license table for TQMa6UL (2038-compliance)
- 264 license table entries with exact download URLs (224/264 resolved) - Complete sources/ directory with all BitBake recipes - Build configuration: tqma6ul-multi-mba6ulx, spaetzle (musl) - Full traceability for Softwarefreigabeantrag - GCC 13.4.0, Linux 6.6.102, U-Boot 2023.04, musl 1.2.4 - License distribution: GPL-2.0 (24), MIT (23), GPL-2.0+ (18), BSD-3 (16)
This commit is contained in:
Siggi (OpenClaw Agent)
156
sources/poky/meta/classes-recipe/uboot-config.bbclass
Normal file
156
sources/poky/meta/classes-recipe/uboot-config.bbclass
Normal file
@@ -0,0 +1,156 @@
|
||||
# Handle U-Boot config for a machine
|
||||
#
|
||||
# The format to specify it, in the machine, is:
|
||||
#
|
||||
# UBOOT_CONFIG ??= <default>
|
||||
# UBOOT_CONFIG[foo] = "config,images,binary"
|
||||
#
|
||||
# or
|
||||
#
|
||||
# UBOOT_MACHINE = "config"
|
||||
#
|
||||
# Copyright 2013, 2014 (C) O.S. Systems Software LTDA.
|
||||
#
|
||||
# SPDX-License-Identifier: MIT
|
||||
|
||||
|
||||
def removesuffix(s, suffix):
|
||||
if suffix and s.endswith(suffix):
|
||||
return s[:-len(suffix)]
|
||||
return s
|
||||
|
||||
UBOOT_ENTRYPOINT ?= "20008000"
|
||||
UBOOT_LOADADDRESS ?= "${UBOOT_ENTRYPOINT}"
|
||||
|
||||
# When naming the files we install/deploy, the package version and revision
|
||||
# are part of the filename. Create a single variable to represent this and
|
||||
# allow it to be customized if desired.
|
||||
UBOOT_VERSION ?= "${PV}-${PR}"
|
||||
|
||||
# Some versions of u-boot use .bin and others use .img. By default use .bin
|
||||
# but enable individual recipes to change this value.
|
||||
UBOOT_SUFFIX ??= "bin"
|
||||
UBOOT_BINARY ?= "u-boot.${UBOOT_SUFFIX}"
|
||||
UBOOT_BINARYNAME ?= "${@os.path.splitext(d.getVar("UBOOT_BINARY"))[0]}"
|
||||
UBOOT_IMAGE ?= "${UBOOT_BINARYNAME}-${MACHINE}-${UBOOT_VERSION}.${UBOOT_SUFFIX}"
|
||||
UBOOT_SYMLINK ?= "${UBOOT_BINARYNAME}-${MACHINE}.${UBOOT_SUFFIX}"
|
||||
UBOOT_MAKE_TARGET ?= "all"
|
||||
|
||||
# Output the ELF generated. Some platforms can use the ELF file and directly
|
||||
# load it (JTAG booting, QEMU) additionally the ELF can be used for debugging
|
||||
# purposes.
|
||||
UBOOT_ELF ?= ""
|
||||
UBOOT_ELF_SUFFIX ?= "elf"
|
||||
UBOOT_ELF_IMAGE ?= "u-boot-${MACHINE}-${UBOOT_VERSION}.${UBOOT_ELF_SUFFIX}"
|
||||
UBOOT_ELF_BINARY ?= "u-boot.${UBOOT_ELF_SUFFIX}"
|
||||
UBOOT_ELF_SYMLINK ?= "u-boot-${MACHINE}.${UBOOT_ELF_SUFFIX}"
|
||||
|
||||
# Some versions of u-boot build an SPL (Second Program Loader) image that
|
||||
# should be packaged along with the u-boot binary as well as placed in the
|
||||
# deploy directory. For those versions they can set the following variables
|
||||
# to allow packaging the SPL.
|
||||
SPL_SUFFIX ?= ""
|
||||
SPL_BINARY ?= ""
|
||||
SPL_DELIMITER ?= "${@'.' if d.getVar("SPL_SUFFIX") else ''}"
|
||||
SPL_BINARYFILE ?= "${@os.path.basename(d.getVar("SPL_BINARY"))}"
|
||||
SPL_BINARYNAME ?= "${@removesuffix(d.getVar("SPL_BINARYFILE"), "." + d.getVar("SPL_SUFFIX"))}"
|
||||
SPL_IMAGE ?= "${SPL_BINARYNAME}-${MACHINE}-${UBOOT_VERSION}${SPL_DELIMITER}${SPL_SUFFIX}"
|
||||
SPL_SYMLINK ?= "${SPL_BINARYNAME}-${MACHINE}${SPL_DELIMITER}${SPL_SUFFIX}"
|
||||
|
||||
# Additional environment variables or a script can be installed alongside
|
||||
# u-boot to be used automatically on boot. This file, typically 'uEnv.txt'
|
||||
# or 'boot.scr', should be packaged along with u-boot as well as placed in the
|
||||
# deploy directory. Machine configurations needing one of these files should
|
||||
# include it in the SRC_URI and set the UBOOT_ENV parameter.
|
||||
UBOOT_ENV_SUFFIX ?= "txt"
|
||||
UBOOT_ENV ?= ""
|
||||
UBOOT_ENV_SRC_SUFFIX ?= "cmd"
|
||||
UBOOT_ENV_SRC ?= "${UBOOT_ENV}.${UBOOT_ENV_SRC_SUFFIX}"
|
||||
UBOOT_ENV_BINARY ?= "${UBOOT_ENV}.${UBOOT_ENV_SUFFIX}"
|
||||
UBOOT_ENV_IMAGE ?= "${UBOOT_ENV}-${MACHINE}-${UBOOT_VERSION}.${UBOOT_ENV_SUFFIX}"
|
||||
UBOOT_ENV_SYMLINK ?= "${UBOOT_ENV}-${MACHINE}.${UBOOT_ENV_SUFFIX}"
|
||||
|
||||
# U-Boot EXTLINUX variables. U-Boot searches for /boot/extlinux/extlinux.conf
|
||||
# to find EXTLINUX conf file.
|
||||
UBOOT_EXTLINUX_INSTALL_DIR ?= "/boot/extlinux"
|
||||
UBOOT_EXTLINUX_CONF_NAME ?= "extlinux.conf"
|
||||
UBOOT_EXTLINUX_SYMLINK ?= "${UBOOT_EXTLINUX_CONF_NAME}-${MACHINE}-${UBOOT_VERSION}"
|
||||
|
||||
# Options for the device tree compiler passed to mkimage '-D' feature:
|
||||
UBOOT_MKIMAGE_DTCOPTS ??= ""
|
||||
SPL_MKIMAGE_DTCOPTS ??= ""
|
||||
|
||||
# mkimage command
|
||||
UBOOT_MKIMAGE ?= "uboot-mkimage"
|
||||
UBOOT_MKIMAGE_SIGN ?= "${UBOOT_MKIMAGE}"
|
||||
|
||||
# Signature activation - this requires KERNEL_IMAGETYPE = "fitImage"
|
||||
UBOOT_SIGN_ENABLE ?= "0"
|
||||
|
||||
# Arguments passed to mkimage for signing
|
||||
UBOOT_MKIMAGE_SIGN_ARGS ?= ""
|
||||
SPL_MKIMAGE_SIGN_ARGS ?= ""
|
||||
|
||||
# Options to deploy the u-boot device tree
|
||||
UBOOT_DTB ?= ""
|
||||
UBOOT_DTB_BINARY ??= ""
|
||||
|
||||
# uboot-fit_check_sign command
|
||||
UBOOT_FIT_CHECK_SIGN ?= "uboot-fit_check_sign"
|
||||
|
||||
python () {
|
||||
ubootmachine = d.getVar("UBOOT_MACHINE")
|
||||
ubootconfigflags = d.getVarFlags('UBOOT_CONFIG')
|
||||
ubootbinary = d.getVar('UBOOT_BINARY')
|
||||
ubootbinaries = d.getVar('UBOOT_BINARIES')
|
||||
# The "doc" varflag is special, we don't want to see it here
|
||||
ubootconfigflags.pop('doc', None)
|
||||
ubootconfig = (d.getVar('UBOOT_CONFIG') or "").split()
|
||||
recipename = d.getVar("PN")
|
||||
|
||||
if not ubootmachine and not ubootconfig:
|
||||
FILE = os.path.basename(d.getVar("FILE"))
|
||||
bb.debug(1, "To build %s, see %s for instructions on \
|
||||
setting up your machine config" % (recipename, FILE))
|
||||
raise bb.parse.SkipRecipe("Either UBOOT_MACHINE or UBOOT_CONFIG must be set in the %s machine configuration." % d.getVar("MACHINE"))
|
||||
|
||||
if ubootmachine and ubootconfig:
|
||||
raise bb.parse.SkipRecipe("You cannot use UBOOT_MACHINE and UBOOT_CONFIG at the same time.")
|
||||
|
||||
if ubootconfigflags and ubootbinaries:
|
||||
raise bb.parse.SkipRecipe("You cannot use UBOOT_BINARIES as it is internal to uboot_config.bbclass.")
|
||||
|
||||
if len(ubootconfig) > 0:
|
||||
for config in ubootconfig:
|
||||
found = False
|
||||
for f, v in ubootconfigflags.items():
|
||||
if config == f:
|
||||
found = True
|
||||
items = v.split(',')
|
||||
if items[0] and len(items) > 3:
|
||||
raise bb.parse.SkipRecipe('Only config,images,binary can be specified!')
|
||||
d.appendVar('UBOOT_MACHINE', ' ' + items[0])
|
||||
# IMAGE_FSTYPES appending
|
||||
if len(items) > 1 and items[1]:
|
||||
bb.debug(1, "Appending '%s' to IMAGE_FSTYPES." % items[1])
|
||||
d.appendVar('IMAGE_FSTYPES', ' ' + items[1])
|
||||
if len(items) > 2 and items[2]:
|
||||
bb.debug(1, "Appending '%s' to UBOOT_BINARIES." % items[2])
|
||||
d.appendVar('UBOOT_BINARIES', ' ' + items[2])
|
||||
else:
|
||||
bb.debug(1, "Appending '%s' to UBOOT_BINARIES." % ubootbinary)
|
||||
d.appendVar('UBOOT_BINARIES', ' ' + ubootbinary)
|
||||
break
|
||||
|
||||
if not found:
|
||||
raise bb.parse.SkipRecipe("The selected UBOOT_CONFIG key %s has no match in %s." % (ubootconfig, ubootconfigflags.keys()))
|
||||
|
||||
# This recipe might be inherited e.g. by the kernel recipe via kernel-fitimage.bbclass
|
||||
# Ensure the uboot specific menuconfig settings do not leak into other recipes
|
||||
if 'u-boot' in recipename:
|
||||
if len(ubootconfig) == 1:
|
||||
d.setVar('KCONFIG_CONFIG_ROOTDIR', os.path.join(d.getVar("B"), d.getVar("UBOOT_MACHINE").strip()))
|
||||
else:
|
||||
# Disable menuconfig for multiple configs
|
||||
d.setVar('KCONFIG_CONFIG_ENABLE_MENUCONFIG', "false")
|
||||
}
|
||||
Reference in New Issue
Block a user