Complete Yocto mirror with license table for TQMa6UL (2038-compliance)
- 264 license table entries with exact download URLs (224/264 resolved) - Complete sources/ directory with all BitBake recipes - Build configuration: tqma6ul-multi-mba6ulx, spaetzle (musl) - Full traceability for Softwarefreigabeantrag - GCC 13.4.0, Linux 6.6.102, U-Boot 2023.04, musl 1.2.4 - License distribution: GPL-2.0 (24), MIT (23), GPL-2.0+ (18), BSD-3 (16)
This commit is contained in:
Siggi (OpenClaw Agent)
111
sources/poky/meta/recipes-devtools/tcltk/tcl_8.6.13.bb
Normal file
111
sources/poky/meta/recipes-devtools/tcltk/tcl_8.6.13.bb
Normal file
@@ -0,0 +1,111 @@
|
||||
SUMMARY = "Tool Command Language"
|
||||
HOMEPAGE = "http://tcl.sourceforge.net"
|
||||
DESCRIPTION = "Tool Command Language, is an open-source multi-purpose C library which includes a powerful dynamic scripting language. Together they provide ideal cross-platform development environment for any programming project."
|
||||
SECTION = "devel/tcltk"
|
||||
|
||||
# http://www.tcl.tk/software/tcltk/license.html
|
||||
LICENSE = "TCL & BSD-3-Clause"
|
||||
LIC_FILES_CHKSUM = "file://license.terms;md5=058f6229798281bbcac4239c788cfa38 \
|
||||
file://compat/license.terms;md5=058f6229798281bbcac4239c788cfa38 \
|
||||
file://library/license.terms;md5=058f6229798281bbcac4239c788cfa38 \
|
||||
file://macosx/license.terms;md5=058f6229798281bbcac4239c788cfa38 \
|
||||
file://tests/license.terms;md5=058f6229798281bbcac4239c788cfa38 \
|
||||
file://win/license.terms;md5=058f6229798281bbcac4239c788cfa38 \
|
||||
"
|
||||
|
||||
DEPENDS = "tcl-native zlib"
|
||||
|
||||
BASE_SRC_URI = "${SOURCEFORGE_MIRROR}/tcl/tcl-core${PV}-src.tar.gz \
|
||||
file://tcl-add-soname.patch"
|
||||
SRC_URI = "${BASE_SRC_URI} \
|
||||
file://fix_non_native_build_issue.patch \
|
||||
file://fix_issue_with_old_distro_glibc.patch \
|
||||
file://tcl-remove-hardcoded-install-path.patch \
|
||||
file://alter-includedir.patch \
|
||||
file://interp.patch \
|
||||
file://run-ptest \
|
||||
"
|
||||
SRC_URI[sha256sum] = "c61f0d6699e2bc7691f119b41963aaa8dc980f23532c4e937739832a5f4a6642"
|
||||
|
||||
SRC_URI:class-native = "${BASE_SRC_URI}"
|
||||
|
||||
UPSTREAM_CHECK_URI = "https://www.tcl.tk/software/tcltk/download.html"
|
||||
UPSTREAM_CHECK_REGEX = "tcl(?P<pver>\d+(\.\d+)+)-src"
|
||||
|
||||
S = "${WORKDIR}/${BPN}${PV}"
|
||||
|
||||
VER = "${PV}"
|
||||
|
||||
inherit autotools ptest binconfig
|
||||
|
||||
AUTOTOOLS_SCRIPT_PATH = "${S}/unix"
|
||||
EXTRA_OECONF = "--enable-threads --disable-rpath --enable-man-suffix"
|
||||
|
||||
# Prevent installing copy of tzdata based on tzdata installation on the build host
|
||||
# It doesn't install tzdata if one of the following files exist on the host:
|
||||
# /usr/share/zoneinfo/UTC /usr/share/zoneinfo/GMT /usr/share/lib/zoneinfo/UTC /usr/share/lib/zoneinfo/GMT /usr/lib/zoneinfo/UTC /usr/lib/zoneinfo/GMT
|
||||
# otherwise "/usr/lib/tcl8.6/tzdata" is included in tcl package
|
||||
EXTRA_OECONF += "--with-tzdata=no"
|
||||
|
||||
do_install() {
|
||||
autotools_do_install
|
||||
oe_runmake 'DESTDIR=${D}' install-private-headers
|
||||
ln -sf ./tclsh${VER} ${D}${bindir}/tclsh
|
||||
ln -sf tclsh8.6 ${D}${bindir}/tclsh${VER}
|
||||
sed -i "s;-L${B};-L${STAGING_LIBDIR};g" tclConfig.sh
|
||||
sed -i "s;'${WORKDIR};'${STAGING_INCDIR};g" tclConfig.sh
|
||||
install -d ${D}${bindir_crossscripts}
|
||||
install -m 0755 tclConfig.sh ${D}${bindir_crossscripts}
|
||||
install -m 0755 tclConfig.sh ${D}${libdir}
|
||||
for dir in compat generic unix; do
|
||||
install -d ${D}${includedir}/${BPN}${VER}/$dir
|
||||
install -m 0644 ${S}/$dir/*.h ${D}${includedir}/${BPN}${VER}/$dir/
|
||||
done
|
||||
}
|
||||
|
||||
SYSROOT_DIRS += "${bindir_crossscripts}"
|
||||
|
||||
PACKAGES =+ "tcl-lib"
|
||||
FILES:tcl-lib = "${libdir}/libtcl8.6.so.*"
|
||||
FILES:${PN} += "${libdir}/tcl${VER} ${libdir}/tcl8.6 ${libdir}/tcl8"
|
||||
FILES:${PN}-dev += "${libdir}/tclConfig.sh ${libdir}/tclooConfig.sh"
|
||||
|
||||
# isn't getting picked up by shlibs code
|
||||
RDEPENDS:${PN} += "tcl-lib"
|
||||
RDEPENDS:${PN}-ptest += "libgcc"
|
||||
|
||||
BBCLASSEXTEND = "native nativesdk"
|
||||
|
||||
do_compile_ptest() {
|
||||
oe_runmake tcltest
|
||||
}
|
||||
|
||||
do_install_ptest() {
|
||||
cp ${B}/tcltest ${D}${PTEST_PATH}
|
||||
cp -r ${S}/library ${D}${PTEST_PATH}
|
||||
cp -r ${S}/tests ${D}${PTEST_PATH}
|
||||
}
|
||||
|
||||
do_install_ptest:append:libc-musl () {
|
||||
# Assumes locales other than provided by musl-locales
|
||||
sed -i '/SKIP="$SKIP socket.*$/a # unixInit-3* is suppressed due to hardcoded locale assumptions\nSKIP="$SKIP unixInit-3\\\*"' ${D}${PTEST_PATH}/run-ptest
|
||||
}
|
||||
|
||||
# Fix some paths that might be used by Tcl extensions
|
||||
BINCONFIG_GLOB = "*Config.sh"
|
||||
|
||||
# Fix the path in sstate
|
||||
SSTATE_SCAN_FILES += "*Config.sh"
|
||||
|
||||
# Cleanup host path from ${libdir}/tclConfig.sh and remove the
|
||||
# ${bindir_crossscripts}/tclConfig.sh from target
|
||||
PACKAGE_PREPROCESS_FUNCS += "tcl_package_preprocess"
|
||||
tcl_package_preprocess() {
|
||||
sed -i -e "s;${DEBUG_PREFIX_MAP};;g" \
|
||||
-e "s;-L${STAGING_LIBDIR};-L${libdir};g" \
|
||||
-e "s;${STAGING_INCDIR};${includedir};g" \
|
||||
-e "s;--sysroot=${RECIPE_SYSROOT};;g" \
|
||||
${PKGD}${libdir}/tclConfig.sh
|
||||
|
||||
rm -f ${PKGD}${bindir_crossscripts}/tclConfig.sh
|
||||
}
|
||||
Reference in New Issue
Block a user