Complete Yocto mirror with license table for TQMa6UL (2038-compliance)

- 264 license table entries with exact download URLs (224/264 resolved)
- Complete sources/ directory with all BitBake recipes
- Build configuration: tqma6ul-multi-mba6ulx, spaetzle (musl)
- Full traceability for Softwarefreigabeantrag
- GCC 13.4.0, Linux 6.6.102, U-Boot 2023.04, musl 1.2.4
- License distribution: GPL-2.0 (24), MIT (23), GPL-2.0+ (18), BSD-3 (16)

sources/poky/meta/recipes-graphics/xorg-font/xorg-font-common.inc

@@ -0,0 +1,42 @@
+HOMEPAGE = "http://www.x.org"
+BUGTRACKER = "https://bugs.freedesktop.org/enter_bug.cgi?product=xorg"
+
+SECTION = "x11/fonts"
+LICENSE = "MIT"
+
+DEPENDS = " encodings font-alias font-util-native"
+RDEPENDS:${PN} = "encodings font-util font-alias"
+
+XORG_PN = "${BPN}"
+
+SRC_URI_EXT = "bz2"
+SRC_URI = "${XORG_MIRROR}/individual/font/${XORG_PN}-${PV}.tar.${SRC_URI_EXT}"
+S = "${WORKDIR}/${XORG_PN}-${PV}"
+
+inherit autotools pkgconfig features_check
+
+# The mkfontscale-native requires x11 in DISTRO_FEATURES
+REQUIRED_DISTRO_FEATURES = "x11"
+
+EXTRA_OEMAKE += "FCCACHE=/bin/true UTIL_DIR=${STAGING_DIR_TARGET}\$\(MAPFILES_PATH\)"
+
+do_install:append() {
+	find ${D}${libdir}/X11/fonts -type f -name fonts.dir | xargs rm -f
+	find ${D}${libdir}/X11/fonts -type f -name fonts.scale | xargs rm -f
+	find ${D}${datadir}/fonts/X11 -type f -name fonts.dir | xargs rm -f
+	find ${D}${datadir}/fonts/X11 -type f -name fonts.scale | xargs rm -f	
+}
+
+FILES:${PN} += " ${libdir}/X11/fonts ${datadir}"
+
+PACKAGE_WRITE_DEPS += "mkfontdir-native mkfontscale-native"
+pkg_postinst:${PN} () {
+        for fontdir in `find $D/usr/lib/X11/fonts -type d`; do
+                mkfontdir $fontdir
+                mkfontscale $fontdir
+        done
+        for fontdir in `find $D/usr/share/fonts/X11 -type d`; do
+                mkfontdir $fontdir
+                mkfontscale $fontdir
+        done
+}