Complete Yocto mirror with license table for TQMa6UL (2038-compliance)
- 264 license table entries with exact download URLs (224/264 resolved) - Complete sources/ directory with all BitBake recipes - Build configuration: tqma6ul-multi-mba6ulx, spaetzle (musl) - Full traceability for Softwarefreigabeantrag - GCC 13.4.0, Linux 6.6.102, U-Boot 2023.04, musl 1.2.4 - License distribution: GPL-2.0 (24), MIT (23), GPL-2.0+ (18), BSD-3 (16)
This commit is contained in:
Siggi (OpenClaw Agent)
@@ -0,0 +1,7 @@
|
||||
# Disable screen blanking
|
||||
Section "ServerFlags"
|
||||
Option "BlankTime" "0"
|
||||
Option "StandbyTime" "0"
|
||||
Option "SuspendTime" "0"
|
||||
Option "OffTime" "0"
|
||||
EndSection
|
||||
@@ -0,0 +1,27 @@
|
||||
SUMMARY = "X.Org X server configuration file"
|
||||
HOMEPAGE = "http://www.x.org"
|
||||
SECTION = "x11/base"
|
||||
LICENSE = "MIT"
|
||||
LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
|
||||
|
||||
SRC_URI = "file://xorg.conf"
|
||||
SRC_URI:append:qemuall = " file://noblank.conf"
|
||||
|
||||
S = "${WORKDIR}"
|
||||
|
||||
CONFFILES:${PN} = "${sysconfdir}/X11/xorg.conf"
|
||||
|
||||
PACKAGE_ARCH = "${MACHINE_ARCH}"
|
||||
ALLOW_EMPTY:${PN} = "1"
|
||||
|
||||
do_install () {
|
||||
if test -s ${WORKDIR}/xorg.conf; then
|
||||
install -d ${D}/${sysconfdir}/X11
|
||||
install -m 0644 ${WORKDIR}/xorg.conf ${D}/${sysconfdir}/X11/
|
||||
fi
|
||||
|
||||
if test -s ${S}/noblank.conf; then
|
||||
install -d ${D}/${sysconfdir}/X11/xorg.conf.d
|
||||
install -m 0644 ${S}/noblank.conf ${D}/${sysconfdir}/X11/xorg.conf.d/
|
||||
fi
|
||||
}
|
||||
183
sources/poky/meta/recipes-graphics/xorg-xserver/xserver-xorg.inc
Normal file
183
sources/poky/meta/recipes-graphics/xorg-xserver/xserver-xorg.inc
Normal file
@@ -0,0 +1,183 @@
|
||||
SUMMARY = "The X.Org X server"
|
||||
HOMEPAGE = "http://www.x.org"
|
||||
SECTION = "x11/base"
|
||||
LICENSE = "MIT"
|
||||
LIC_FILES_CHKSUM = "file://COPYING;md5=5df87950af51ac2c5822094553ea1880"
|
||||
|
||||
# xf86-*-* packages depend on an X server built with the xfree86 DDX
|
||||
# so we have a virtual to represent that:
|
||||
# deprecated, we should use virtual/xserver instead
|
||||
PROVIDES = "virtual/xserver-xf86"
|
||||
|
||||
# Other packages tend to just care that there is *an* X server:
|
||||
PROVIDES += "virtual/xserver"
|
||||
|
||||
PE = "2"
|
||||
|
||||
XORG_PN = "xorg-server"
|
||||
SRC_URI = "${XORG_MIRROR}/individual/xserver/${XORG_PN}-${PV}.tar.xz"
|
||||
|
||||
UPSTREAM_CHECK_REGEX = "xorg-server-(?P<pver>\d+(\.(?!99)\d+)+)\.tar"
|
||||
|
||||
CVE_PRODUCT = "xorg-server x_server"
|
||||
|
||||
CVE_STATUS[CVE-2011-4613] = "not-applicable-platform: This is specific to Debian's xserver-wrapper.c"
|
||||
CVE_STATUS[CVE-2020-25697] = "upstream-wontfix: \
|
||||
As per upstream, exploiting this flaw is non-trivial and it requires exact \
|
||||
timing on the behalf of the attacker. Many graphical applications exit if their \
|
||||
connection to the X server is lost, so a typical desktop session is either \
|
||||
impossible or difficult to exploit. There is currently no upstream patch \
|
||||
available for this flaw."
|
||||
CVE_STATUS[CVE-2022-3553] = "cpe-incorrect: This is specific to XQuartz, which is the macOS X server port"
|
||||
|
||||
S = "${WORKDIR}/${XORG_PN}-${PV}"
|
||||
|
||||
inherit meson pkgconfig
|
||||
|
||||
inherit features_check
|
||||
REQUIRED_DISTRO_FEATURES = "x11"
|
||||
|
||||
LIB_DEPS = "pixman libxfont2 xtrans libxau libxext libxdmcp libdrm libxkbfile libpciaccess libxcvt libtirpc"
|
||||
DEPENDS = "xorgproto ${LIB_DEPS} font-util"
|
||||
|
||||
# Split out some modules and extensions from the main package
|
||||
# These aren't needed for basic operations and only take up space:
|
||||
# 32.0k libdri.so
|
||||
# 91.0k libexa.so
|
||||
# 336.0k libglx.so
|
||||
# 1360k libint10.so
|
||||
# 180.0k libwfb.so
|
||||
# 320.0k libxaa.so
|
||||
# 124.0k libxf1bpp.so
|
||||
# 84.0k libxf4bpp.so
|
||||
# librecord.so
|
||||
# libextmod.so
|
||||
# libdbe.so
|
||||
|
||||
PACKAGES =+ "${PN}-sdl \
|
||||
${PN}-fbdev \
|
||||
${PN}-xvfb \
|
||||
${PN}-utils \
|
||||
${PN}-xephyr \
|
||||
${PN}-xwayland \
|
||||
${PN}-multimedia-modules \
|
||||
${PN}-extension-dri \
|
||||
${PN}-extension-dri2 \
|
||||
${PN}-extension-glx \
|
||||
${PN}-extension-record \
|
||||
${PN}-extension-extmod \
|
||||
${PN}-extension-dbe \
|
||||
${PN}-module-libint10 \
|
||||
${PN}-module-libafb \
|
||||
${PN}-module-libwfb \
|
||||
${PN}-module-libmfb \
|
||||
${PN}-module-libcfb \
|
||||
${PN}-module-exa \
|
||||
${PN}-module-xaa \
|
||||
${PN}-module-libxf1bpp \
|
||||
${PN}-module-libxf4bpp \
|
||||
xf86-video-modesetting"
|
||||
|
||||
SUMMARY:xf86-video-modesetting = "X.Org X server -- modesetting display driver"
|
||||
INSANE_SKIP:${MLPREFIX}xf86-video-modesetting = "xorg-driver-abi"
|
||||
|
||||
XSERVER_RDEPENDS = "xkeyboard-config rgb xserver-xf86-config xkbcomp xf86-input-libinput"
|
||||
RDEPENDS:${PN} += "${XSERVER_RDEPENDS}"
|
||||
RDEPENDS:${PN}-xwayland += "${XSERVER_RDEPENDS}"
|
||||
RDEPENDS:${PN}-xvfb += "xkeyboard-config"
|
||||
RDEPENDS:${PN}-module-exa = "${PN} (= ${EXTENDPKGV})"
|
||||
|
||||
FILES:${PN} = "${bindir} ${libdir}/X11/Options ${libdir}/X11/Cards ${libdir}/X11/getconfig ${libdir}/X11/etc ${libdir}/modules/*.so ${libdir}/xorg/modules/input/*.so ${libdir}/xorg/modules/*.so /etc/X11 ${libdir}/xorg/protocol.txt ${datadir}/X11/xorg.conf.d"
|
||||
FILES:${PN}-dev += "${libdir}/xorg/modules/*.la ${libdir}/xorg/modules/*/*.la"
|
||||
FILES:${PN}-doc += "${libdir}/X11/doc ${datadir}/X11/xkb/compiled/README.compiled ${localstatedir}/lib/xkb/README.compiled"
|
||||
FILES:${PN}-sdl = "${bindir}/Xsdl"
|
||||
FILES:${PN}-fbdev = "${bindir}/Xfbdev"
|
||||
FILES:${PN}-xvfb = "${bindir}/Xvfb"
|
||||
FILES:${PN}-utils = "${bindir}/scanpci ${bindir}/pcitweak ${bindir}/ioport ${bindir}/in[bwl] ${bindir}/out[bwl] ${bindir}/mmap[rw] ${bindir}/gtf ${bindir}/getconfig ${bindir}/getconfig.pl"
|
||||
FILES:${PN}-xephyr = "${bindir}/Xephyr"
|
||||
FILES:${PN}-xwayland = "${bindir}/Xwayland"
|
||||
FILES:${PN}-multimedia-modules = "${libdir}/xorg/modules/multimedia/*drv*"
|
||||
FILES:${PN}-extension-dri = "${libdir}/xorg/modules/extensions/libdri.so"
|
||||
FILES:${PN}-extension-dri2 = "${libdir}/xorg/modules/extensions/libdri2.so"
|
||||
FILES:${PN}-extension-glx = "${libdir}/xorg/modules/extensions/libglx.so"
|
||||
FILES:${PN}-extension-record = "${libdir}/xorg/modules/extensions/librecord.so"
|
||||
FILES:${PN}-extension-extmod = "${libdir}/xorg/modules/extensions/libextmod.so"
|
||||
FILES:${PN}-extension-dbe = "${libdir}/xorg/modules/extensions/libdbe.so"
|
||||
FILES:${PN}-module-libint10 = "${libdir}/xorg/modules/libint10.so"
|
||||
FILES:${PN}-module-libafb = "${libdir}/xorg/modules/libafb.so"
|
||||
FILES:${PN}-module-libwfb = "${libdir}/xorg/modules/libwfb.so"
|
||||
FILES:${PN}-module-libmfb = "${libdir}/xorg/modules/libmfb.so"
|
||||
FILES:${PN}-module-libcfb = "${libdir}/xorg/modules/libcfb.so"
|
||||
FILES:${PN}-module-exa = "${libdir}/xorg/modules/libexa.so"
|
||||
FILES:${PN}-module-xaa = "${libdir}/xorg/modules/libxaa.so"
|
||||
FILES:${PN}-module-libxf1bpp = "${libdir}/xorg/modules/libxf1bpp.so"
|
||||
FILES:${PN}-module-libxf4bpp = "${libdir}/xorg/modules/libxf4bpp.so"
|
||||
FILES:xf86-video-modesetting = "${libdir}/xorg/modules/drivers/modesetting_drv.so"
|
||||
|
||||
EXTRA_OEMESON += " \
|
||||
-Dxnest=false \
|
||||
-Ddtrace=false \
|
||||
-Dint10=x86emu \
|
||||
-Dxkb_output_dir=/var/lib/xkb \
|
||||
"
|
||||
|
||||
OPENGL_PKGCONFIGS = "dri glx glamor dri3"
|
||||
PACKAGECONFIG ??= "dga dri2 udev ${XORG_CRYPTO} \
|
||||
${@bb.utils.contains('DISTRO_FEATURES', 'opengl', '${OPENGL_PKGCONFIGS}', '', d)} \
|
||||
${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'systemd-logind', '', d)} \
|
||||
"
|
||||
|
||||
PACKAGECONFIG[udev] = "-Dudev=true,-Dudev=false,udev"
|
||||
PACKAGECONFIG[dga] = "-Ddga=true,-Ddga=false"
|
||||
PACKAGECONFIG[dri] = "-Ddri1=true,-Ddri1=false,virtual/mesa"
|
||||
PACKAGECONFIG[dri2] = "-Ddri2=true,-Ddri2=false"
|
||||
PACKAGECONFIG[dri3] = "-Ddri3=true,-Ddri3=false"
|
||||
PACKAGECONFIG[glx] = "-Dglx=true,-Dglx=false,virtual/libgl virtual/libx11"
|
||||
PACKAGECONFIG[glamor] = "-Dglamor=true,-Dglamor=false,libepoxy virtual/libgbm,libegl"
|
||||
PACKAGECONFIG[unwind] = "-Dlibunwind=true,-Dlibunwind=false,libunwind"
|
||||
PACKAGECONFIG[systemd-logind] = "-Dsystemd_logind=true,-Dsystemd_logind=false,dbus,"
|
||||
PACKAGECONFIG[xinerama] = "-Dxinerama=true,-Dxinerama=false"
|
||||
PACKAGECONFIG[xvfb] = "-Dxvfb=true,-Dxvfb=false"
|
||||
|
||||
# Xorg requires a SHA1 implementation, pick one
|
||||
XORG_CRYPTO ??= "openssl"
|
||||
PACKAGECONFIG[openssl] = "-Dsha1=libcrypto,,openssl"
|
||||
PACKAGECONFIG[nettle] = "-Dsha1=libnettle,,nettle"
|
||||
PACKAGECONFIG[gcrypt] = "-Dsha1=libgcrypt,,libgcrypt"
|
||||
|
||||
do_install:append () {
|
||||
sed -i -e 's,${libdir}/xorg/modules,${prefix}/lib*/xorg/modules,' ${D}${mandir}/man5/xorg.conf.5
|
||||
}
|
||||
|
||||
# Add runtime provides for the ABI versions of the video and input subsystems,
|
||||
# so that drivers can depend on the relevant version.
|
||||
python populate_packages:prepend() {
|
||||
import subprocess
|
||||
|
||||
# Set PKG_CONFIG_PATH so pkg-config looks at the .pc files that are going
|
||||
# into the new package, not the staged ones.
|
||||
newenv = dict(os.environ)
|
||||
newenv["PKG_CONFIG_PATH"] = d.expand("${PKGD}${libdir}/pkgconfig/")
|
||||
|
||||
def get_abi(name):
|
||||
abis = {
|
||||
"video": "abi_videodrv",
|
||||
"input": "abi_xinput"
|
||||
}
|
||||
p = subprocess.Popen(args="pkg-config --variable=%s xorg-server" % abis[name],
|
||||
shell=True, env=newenv, stdout=subprocess.PIPE)
|
||||
stdout, stderr = p.communicate()
|
||||
output = stdout.decode("utf-8").split(".")[0]
|
||||
mlprefix = d.getVar('MLPREFIX') or ''
|
||||
return "%sxorg-abi-%s-%s" % (mlprefix, name, output)
|
||||
|
||||
pn = d.getVar("PN")
|
||||
d.appendVar("RPROVIDES:" + pn, " " + get_abi("input"))
|
||||
d.appendVar("RPROVIDES:" + pn, " " + get_abi("video"))
|
||||
}
|
||||
|
||||
CVE_STATUS[CVE-2023-5574] = "${@bb.utils.contains('PACKAGECONFIG', 'xvfb', 'unpatched', 'not-applicable-config: specific to Xvfb', d)}"
|
||||
|
||||
CVE_STATUS_GROUPS = "CVE_STATUS_REDHAT"
|
||||
CVE_STATUS_REDHAT = "CVE-2025-26594 CVE-2025-26595 CVE-2025-26596 CVE-2025-26597 CVE-2025-26598 CVE-2025-26599 CVE-2025-26600 CVE-2025-26601"
|
||||
CVE_STATUS_REDHAT[status] = "fixed-version: these are tracked as versionless redhat CVEs in NVD DB, fixed in 21.1.16"
|
||||
@@ -0,0 +1,28 @@
|
||||
From cedc797e1a0850039a25b7e387b342e54fffcc97 Mon Sep 17 00:00:00 2001
|
||||
From: Khem Raj <raj.khem@gmail.com>
|
||||
Date: Mon, 17 Aug 2020 10:50:51 -0700
|
||||
Subject: [PATCH] Avoid duplicate definitions of IOPortBase
|
||||
|
||||
This fixed build with gcc10/-fno-common
|
||||
|
||||
Fixes
|
||||
compiler.h:528: multiple definition of `IOPortBase';
|
||||
|
||||
Upstream-Status: Pending
|
||||
Signed-off-by: Khem Raj <raj.khem@gmail.com>
|
||||
---
|
||||
hw/xfree86/os-support/linux/lnx_video.c | 1 +
|
||||
1 file changed, 1 insertion(+)
|
||||
|
||||
diff --git a/hw/xfree86/os-support/linux/lnx_video.c b/hw/xfree86/os-support/linux/lnx_video.c
|
||||
index fd83022..1d0d96e 100644
|
||||
--- a/hw/xfree86/os-support/linux/lnx_video.c
|
||||
+++ b/hw/xfree86/os-support/linux/lnx_video.c
|
||||
@@ -78,6 +78,7 @@ xf86OSInitVidMem(VidMemInfoPtr pVidMem)
|
||||
/***************************************************************************/
|
||||
/* I/O Permissions section */
|
||||
/***************************************************************************/
|
||||
+_X_EXPORT unsigned int IOPortBase; /* Memory mapped I/O port area */
|
||||
|
||||
#if defined(__powerpc__)
|
||||
volatile unsigned char *ioBase = NULL;
|
||||
@@ -0,0 +1,50 @@
|
||||
From ad8967de36e6e2a185b71ce1d701448cda4ef3e2 Mon Sep 17 00:00:00 2001
|
||||
From: California Sullivan <california.l.sullivan@intel.com>
|
||||
Date: Fri, 16 Mar 2018 17:23:11 -0700
|
||||
Subject: [PATCH] xf86pciBus.c: use Intel ddx only for pre-gen4 hardware
|
||||
|
||||
Use intel ddx only on pre-gen4 hw, newer ones will fall back to modesetting
|
||||
Author: Timo Aaltonen <tjaalton@debian.org>
|
||||
|
||||
Instead of defaulting to the Intel driver for all Intel hardware, only
|
||||
default it for older hardware for which it has shown to be better for.
|
||||
|
||||
Others fall through to the -modesetting default.
|
||||
|
||||
Upstream-Status: Pending [Debian/Fedora patch
|
||||
https://src.fedoraproject.org/rpms/xorg-x11-server/c/ee515e44b07e37689abf48cf2fffb41578f3bc1d]
|
||||
|
||||
Signed-off-by: California Sullivan <california.l.sullivan@intel.com>
|
||||
---
|
||||
hw/xfree86/common/xf86pciBus.c | 18 +++++++++++++++++-
|
||||
1 file changed, 17 insertions(+), 1 deletion(-)
|
||||
|
||||
diff --git a/hw/xfree86/common/xf86pciBus.c b/hw/xfree86/common/xf86pciBus.c
|
||||
index aeeed8b..db705bf 100644
|
||||
--- a/hw/xfree86/common/xf86pciBus.c
|
||||
+++ b/hw/xfree86/common/xf86pciBus.c
|
||||
@@ -1174,7 +1174,23 @@ xf86VideoPtrToDriverList(struct pci_device *dev, XF86MatchedDrivers *md)
|
||||
case 0x0bef:
|
||||
/* Use fbdev/vesa driver on Oaktrail, Medfield, CDV */
|
||||
break;
|
||||
- default:
|
||||
+ /* Default to intel only on pre-gen4 chips */
|
||||
+ case 0x3577:
|
||||
+ case 0x2562:
|
||||
+ case 0x3582:
|
||||
+ case 0x358e:
|
||||
+ case 0x2572:
|
||||
+ case 0x2582:
|
||||
+ case 0x258a:
|
||||
+ case 0x2592:
|
||||
+ case 0x2772:
|
||||
+ case 0x27a2:
|
||||
+ case 0x27ae:
|
||||
+ case 0x29b2:
|
||||
+ case 0x29c2:
|
||||
+ case 0x29d2:
|
||||
+ case 0xa001:
|
||||
+ case 0xa011:
|
||||
driverList[0] = "intel";
|
||||
break;
|
||||
}
|
||||
@@ -0,0 +1,28 @@
|
||||
require xserver-xorg.inc
|
||||
|
||||
SRC_URI += "file://0001-xf86pciBus.c-use-Intel-ddx-only-for-pre-gen4-hardwar.patch \
|
||||
file://0001-Avoid-duplicate-definitions-of-IOPortBase.patch \
|
||||
"
|
||||
SRC_URI[sha256sum] = "c878d1930d87725d4a5bf498c24f4be8130d5b2646a9fd0f2994deff90116352"
|
||||
|
||||
# These extensions are now integrated into the server, so declare the migration
|
||||
# path for in-place upgrades.
|
||||
|
||||
RREPLACES:${PN} = "${PN}-extension-dri \
|
||||
${PN}-extension-dri2 \
|
||||
${PN}-extension-record \
|
||||
${PN}-extension-extmod \
|
||||
${PN}-extension-dbe \
|
||||
"
|
||||
RPROVIDES:${PN} = "${PN}-extension-dri \
|
||||
${PN}-extension-dri2 \
|
||||
${PN}-extension-record \
|
||||
${PN}-extension-extmod \
|
||||
${PN}-extension-dbe \
|
||||
"
|
||||
RCONFLICTS:${PN} = "${PN}-extension-dri \
|
||||
${PN}-extension-dri2 \
|
||||
${PN}-extension-record \
|
||||
${PN}-extension-extmod \
|
||||
${PN}-extension-dbe \
|
||||
"
|
||||
Reference in New Issue
Block a user