16accb6b24
- 264 license table entries with exact download URLs (224/264 resolved) - Complete sources/ directory with all BitBake recipes - Build configuration: tqma6ul-multi-mba6ulx, spaetzle (musl) - Full traceability for Softwarefreigabeantrag - GCC 13.4.0, Linux 6.6.102, U-Boot 2023.04, musl 1.2.4 - License distribution: GPL-2.0 (24), MIT (23), GPL-2.0+ (18), BSD-3 (16)
47 lines
1.8 KiB
BlitzBasic
47 lines
1.8 KiB
BlitzBasic
# Copyright (C) 2012-2018 O.S. Systems Software LTDA.
|
|
# Copyright (C) 2012-2016 Freescale Semiconductor
|
|
# Copyright (C) 2017-2023 NXP
|
|
# Released under the MIT license (see COPYING.MIT for the terms)
|
|
DESCRIPTION = "Freescale Multimedia parser libs"
|
|
LICENSE = "Proprietary"
|
|
SECTION = "multimedia"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=ca53281cc0caa7e320d4945a896fb837"
|
|
|
|
# For backwards compatibility
|
|
PROVIDES += "libfslparser"
|
|
RREPLACES:${PN} = "libfslparser"
|
|
RPROVIDES:${PN} = "libfslparser"
|
|
RCONFLICTS:${PN} = "libfslparser"
|
|
|
|
SRC_URI = "${FSL_MIRROR}/${BP}-${IMX_SRCREV_ABBREV}.bin;fsl-eula=true"
|
|
IMX_SRCREV_ABBREV = "828fcb7"
|
|
S = "${WORKDIR}/${BP}-${IMX_SRCREV_ABBREV}"
|
|
|
|
SRC_URI[sha256sum] = "7414db9e2cce2cb2d6fe63ac7d193a0ea65ad8a184e6a2e2ce2785e43acbb339"
|
|
|
|
inherit fsl-eula-unpack autotools pkgconfig
|
|
|
|
# Choose between 32-bit and 64-bit binaries and between Soft Float-Point and Hard Float-Point
|
|
EXTRA_OECONF = "${@bb.utils.contains('TUNE_FEATURES', 'aarch64', '--enable-armv8', \
|
|
bb.utils.contains('TUNE_FEATURES', 'callconvention-hard', '--enable-fhw', '--enable-fsw', d), d)}"
|
|
|
|
INHIBIT_PACKAGE_STRIP = "1"
|
|
INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
|
|
|
|
python __set_insane_skip() {
|
|
# FIXME: All binaries lack GNU_HASH in elf binary but as we don't have
|
|
# the source we cannot fix it. Disable the insane check for now.
|
|
# FIXME: gst-fsl-plugin looks for the .so files so we need to deploy those
|
|
for p in d.getVar('PACKAGES').split():
|
|
d.setVar("INSANE_SKIP:%s" % p, "ldflags dev-so textrel")
|
|
}
|
|
|
|
do_package_qa[prefuncs] += "__set_insane_skip"
|
|
|
|
# FIXME: gst-fsl-plugin looks for the .so files so we need to deploy those
|
|
FILES:${PN} += "${libdir}/imx-mm/*/*${SOLIBS} ${libdir}/imx-mm/*/*${SOLIBSDEV}"
|
|
|
|
INHIBIT_SYSROOT_STRIP = "1"
|
|
|
|
COMPATIBLE_MACHINE = "(imx-nxp-bsp)"
|