16accb6b24
- 264 license table entries with exact download URLs (224/264 resolved) - Complete sources/ directory with all BitBake recipes - Build configuration: tqma6ul-multi-mba6ulx, spaetzle (musl) - Full traceability for Softwarefreigabeantrag - GCC 13.4.0, Linux 6.6.102, U-Boot 2023.04, musl 1.2.4 - License distribution: GPL-2.0 (24), MIT (23), GPL-2.0+ (18), BSD-3 (16)
29 lines
1.3 KiB
BlitzBasic
29 lines
1.3 KiB
BlitzBasic
SUMMARY = "Portable Hardware Locality (hwloc) software package"
|
|
DESCRIPTION = "The Portable Hardware Locality (hwloc) software package \
|
|
provides a portable abstraction of the hierarchical topology of modern \
|
|
architectures."
|
|
HOMEPAGE = "https://www.open-mpi.org/software/hwloc/"
|
|
SECTION = "base"
|
|
LICENSE = "BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=79179bb373cd55cbd834463a514fb714"
|
|
|
|
SRC_URI = "https://www.open-mpi.org/software/${BPN}/v2.9/downloads/${BP}.tar.bz2"
|
|
SRC_URI[sha256sum] = "5c4062ce556f6d3451fc177ffb8673a2120f81df6835dea6a21a90fbdfff0dec"
|
|
UPSTREAM_CHECK_URI = "https://www.open-mpi.org/software/hwloc/v2.9/"
|
|
|
|
inherit autotools bash-completion pkgconfig
|
|
|
|
DEPENDS += "ncurses udev zlib"
|
|
DEPENDS += "${@bb.utils.contains('DISTRO_FEATURES', 'selinux', 'libselinux', '', d)}"
|
|
|
|
PACKAGECONFIG ?= "pci libxml2 ${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'x11', '', d)}"
|
|
|
|
PACKAGECONFIG[libxml2] = "--enable-libxml2,--disable-libxml2,libxml2,libxml2"
|
|
PACKAGECONFIG[x11] = "--with-x,--without-x,virtual/libx11 cairo,cairo"
|
|
PACKAGECONFIG[pci] = "--enable-pci,--disable-pci,libpciaccess,libpciaccess"
|
|
|
|
# Split hwloc library into separate subpackage
|
|
PACKAGES:prepend = " libhwloc "
|
|
FILES:libhwloc += "${libdir}/libhwloc.so.*"
|
|
RDEPENDS:${PN} += "libhwloc (= ${EXTENDPKGV})"
|