16accb6b24
- 264 license table entries with exact download URLs (224/264 resolved) - Complete sources/ directory with all BitBake recipes - Build configuration: tqma6ul-multi-mba6ulx, spaetzle (musl) - Full traceability for Softwarefreigabeantrag - GCC 13.4.0, Linux 6.6.102, U-Boot 2023.04, musl 1.2.4 - License distribution: GPL-2.0 (24), MIT (23), GPL-2.0+ (18), BSD-3 (16)
36 lines
1.2 KiB
BlitzBasic
36 lines
1.2 KiB
BlitzBasic
SUMMARY = "File manager for the Xfce Desktop Environment"
|
|
SECTION = "x11"
|
|
LICENSE = "GPL-2.0-or-later"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
|
|
DEPENDS = "libxml-parser-perl-native exo gdk-pixbuf libxfce4ui libnotify xfce4-panel udev"
|
|
|
|
inherit xfce gobject-introspection features_check mime-xdg perlnative gtk-doc
|
|
|
|
# xfce4 depends on libwnck3, gtk+3 and libepoxy need to be built with x11 PACKAGECONFIG.
|
|
# cairo would at least needed to be built with xlib.
|
|
ANY_OF_DISTRO_FEATURES = "${GTK3DISTROFEATURES}"
|
|
|
|
SRC_URI[sha256sum] = "684f1422c4d92b00db477ecaa2a0ed38ce688e2a567e5d70b7cf66fc6dd6fd18"
|
|
|
|
PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'x11', d)}"
|
|
PACKAGECONFIG[pcre] = "--enable-pcre2,--disable-pcre2,libpcre2"
|
|
PACKAGECONFIG[x11] = ",,libsm startup-notification"
|
|
|
|
FILES:${PN} += " \
|
|
${libdir}/thunarx-3/* \
|
|
${libdir}/xfce4/panel/plugins/* \
|
|
${libdir}/Thunar/[Tt]hunar* \
|
|
${systemd_user_unitdir} \
|
|
${datadir}/dbus-1 \
|
|
${datadir}/metainfo \
|
|
${datadir}/polkit-1 \
|
|
${datadir}/Thunar \
|
|
${datadir}/xfce4/panel/plugins/* \
|
|
"
|
|
|
|
RRECOMMENDS:${PN} = " \
|
|
gvfs \
|
|
gvfsd-trash \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'dbus', 'tumbler', '', d)} \
|
|
"
|