16accb6b24
- 264 license table entries with exact download URLs (224/264 resolved) - Complete sources/ directory with all BitBake recipes - Build configuration: tqma6ul-multi-mba6ulx, spaetzle (musl) - Full traceability for Softwarefreigabeantrag - GCC 13.4.0, Linux 6.6.102, U-Boot 2023.04, musl 1.2.4 - License distribution: GPL-2.0 (24), MIT (23), GPL-2.0+ (18), BSD-3 (16)
55 lines
2.0 KiB
BlitzBasic
55 lines
2.0 KiB
BlitzBasic
# PowerVR Graphics require several patches that have not made their way
|
|
# upstream yet. This allows us to build the shims we need without completely
|
|
# clobbering mesa.
|
|
|
|
require recipes-graphics/mesa/mesa.inc
|
|
|
|
SUMMARY += " (with PowerVR support for TI platforms)"
|
|
|
|
LIC_FILES_CHKSUM = "file://docs/license.rst;md5=63779ec98d78d823a9dc533a0735ef10"
|
|
|
|
BRANCH = "powervr/${PV}"
|
|
|
|
SRC_URI = " \
|
|
git://gitlab.freedesktop.org/StaticRocket/mesa.git;protocol=https;branch=${BRANCH} \
|
|
file://0001-meson.build-check-for-all-linux-host_os-combinations.patch \
|
|
file://0001-meson-misdetects-64bit-atomics-on-mips-clang.patch \
|
|
file://0001-gallium-Fix-build-with-llvm-17.patch \
|
|
file://0001-drisw-fix-build-without-dri3.patch \
|
|
file://0002-glxext-don-t-try-zink-if-not-enabled-in-mesa.patch \
|
|
file://0001-gallivm-Call-StringMapIterator-from-llvm-scope.patch \
|
|
file://0001-Update-lp_bld_misc.cpp-to-support-llvm-19.patch \
|
|
"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
PACKAGECONFIG:append = " \
|
|
${@bb.utils.contains('PREFERRED_PROVIDER_virtual/gpudriver', 'ti-img-rogue-driver', 'pvr', '', d)} \
|
|
${@bb.utils.contains('PREFERRED_PROVIDER_virtual/gpudriver', 'ti-sgx-ddk-km', 'sgx', '', d)} \
|
|
"
|
|
|
|
SRCREV = "82e6a9293c476267417c5b6b906b01fb73a34e38"
|
|
PV = "24.0.1"
|
|
|
|
PVR_DISPLAY_CONTROLLER_ALIAS ??= "tidss"
|
|
PACKAGECONFIG[pvr] = "-Dgallium-pvr-alias=${PVR_DISPLAY_CONTROLLER_ALIAS},"
|
|
PACKAGECONFIG[sgx] = "-Dgallium-sgx-alias=${PVR_DISPLAY_CONTROLLER_ALIAS},"
|
|
|
|
|
|
PACKAGE_ARCH = "${MACHINE_ARCH}"
|
|
|
|
GALLIUMDRIVERS:append = "${@bb.utils.contains('PACKAGECONFIG', 'pvr', ',pvr', '', d)}"
|
|
GALLIUMDRIVERS:append = "${@bb.utils.contains('PACKAGECONFIG', 'sgx', ',sgx', '', d)}"
|
|
|
|
VULKAN_DRIVERS:append = "${@bb.utils.contains('PACKAGECONFIG', 'pvr', ',pvr', '', d)}"
|
|
|
|
do_install:append () {
|
|
# remove pvr custom pkgconfig
|
|
rm -rf ${D}${datadir}/pkgconfig
|
|
}
|
|
|
|
FILES:${PN}-dev += "${datadir}/mesa/wayland-drm.xml"
|
|
FILES:mesa-vulkan-drivers += "${libdir}/libpvr_mesa_wsi.so"
|
|
|
|
RRECOMMENDS:mesa-megadriver:append:class-target = " ${@d.getVar('PREFERRED_PROVIDER_virtual/gpudriver')}"
|