16accb6b24
- 264 license table entries with exact download URLs (224/264 resolved) - Complete sources/ directory with all BitBake recipes - Build configuration: tqma6ul-multi-mba6ulx, spaetzle (musl) - Full traceability for Softwarefreigabeantrag - GCC 13.4.0, Linux 6.6.102, U-Boot 2023.04, musl 1.2.4 - License distribution: GPL-2.0 (24), MIT (23), GPL-2.0+ (18), BSD-3 (16)
45 lines
2.0 KiB
PHP
45 lines
2.0 KiB
PHP
DEFAULTTUNE ?= "aarch64"
|
|
|
|
require conf/machine/include/arm/arch-armv7ve.inc
|
|
|
|
TUNEVALID[aarch64] = "Enable instructions for aarch64"
|
|
TUNECONFLICTS[aarch64] = "armv4 armv5 armv6 armv7 armv7a"
|
|
|
|
MACHINEOVERRIDES =. "${@bb.utils.contains('TUNE_FEATURES', 'aarch64', 'aarch64:', '', d)}"
|
|
|
|
# Little Endian base configs
|
|
AVAILTUNES += "aarch64 aarch64_be"
|
|
ARMPKGARCH:tune-aarch64 ?= "aarch64"
|
|
ARMPKGARCH:tune-aarch64_be ?= "aarch64"
|
|
TUNE_FEATURES:tune-aarch64 = "aarch64"
|
|
TUNE_FEATURES:tune-aarch64_be = "${TUNE_FEATURES:tune-aarch64} bigendian"
|
|
TUNE_PKGARCH_64:tune-aarch64 = "aarch64"
|
|
TUNE_PKGARCH_64:tune-aarch64_be = "aarch64_be"
|
|
BASE_LIB:tune-aarch64 = "lib64"
|
|
BASE_LIB:tune-aarch64_be = "lib64"
|
|
|
|
PACKAGE_EXTRA_ARCHS:tune-aarch64 = "aarch64"
|
|
PACKAGE_EXTRA_ARCHS:tune-aarch64_be = "aarch64_be"
|
|
|
|
ARMPKGSFX_ENDIAN_64 = "${@bb.utils.contains('TUNE_FEATURES', 'bigendian', '_be', '', d)}"
|
|
TUNE_ARCH_64 = "aarch64${ARMPKGSFX_ENDIAN_64}"
|
|
TUNE_PKGARCH_64 = "${ARMPKGARCH}${ARMPKGSFX_ENDIAN_64}"
|
|
ABIEXTENSION_64 = ""
|
|
TARGET_FPU_64 = ""
|
|
|
|
# Duplicated from arch-arm.inc
|
|
TUNE_ARCH_32 = "${@bb.utils.contains('TUNE_FEATURES', 'bigendian', 'armeb', 'arm', d)}"
|
|
TUNE_PKGARCH_32 = "${ARMPKGARCH}${ARMPKGSFX_THUMB}${ARMPKGSFX_DSP}${ARMPKGSFX_EABI}${ARMPKGSFX_ENDIAN}${ARMPKGSFX_FPU}"
|
|
ABIEXTENSION_32 = "eabi"
|
|
TARGET_FPU_32 = "${@d.getVar('TUNE_CCARGS_MFLOAT') or 'soft'}"
|
|
|
|
TUNE_ARCH = "${@bb.utils.contains('TUNE_FEATURES', 'aarch64', '${TUNE_ARCH_64}', '${TUNE_ARCH_32}', d)}"
|
|
TUNE_PKGARCH = "${@bb.utils.contains('TUNE_FEATURES', 'aarch64', '${TUNE_PKGARCH_64}', '${TUNE_PKGARCH_32}', d)}"
|
|
ABIEXTENSION = "${@bb.utils.contains('TUNE_FEATURES', 'aarch64', '${ABIEXTENSION_64}', '${ABIEXTENSION_32}', d)}"
|
|
TARGET_FPU = "${@bb.utils.contains('TUNE_FEATURES', 'aarch64', '${TARGET_FPU_64}', '${TARGET_FPU_32}', d)}"
|
|
|
|
# Emit branch protection (PAC/BTI) instructions. On hardware that doesn't
|
|
# support these they're meaningless NOP instructions, so there's very little
|
|
# reason not to.
|
|
TUNE_CCARGS .= "${@bb.utils.contains('TUNE_FEATURES', 'aarch64', ' -mbranch-protection=standard', '', d)}"
|