16accb6b24
- 264 license table entries with exact download URLs (224/264 resolved) - Complete sources/ directory with all BitBake recipes - Build configuration: tqma6ul-multi-mba6ulx, spaetzle (musl) - Full traceability for Softwarefreigabeantrag - GCC 13.4.0, Linux 6.6.102, U-Boot 2023.04, musl 1.2.4 - License distribution: GPL-2.0 (24), MIT (23), GPL-2.0+ (18), BSD-3 (16)
34 lines
1.2 KiB
BlitzBasic
34 lines
1.2 KiB
BlitzBasic
SUMMARY = "Transport-Independent RPC library"
|
|
DESCRIPTION = "Libtirpc is a port of Suns Transport-Independent RPC library to Linux"
|
|
SECTION = "libs/network"
|
|
HOMEPAGE = "http://sourceforge.net/projects/libtirpc/"
|
|
BUGTRACKER = "http://sourceforge.net/tracker/?group_id=183075&atid=903784"
|
|
LICENSE = "BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=f835cce8852481e4b2bbbdd23b5e47f3 \
|
|
file://src/netname.c;beginline=1;endline=27;md5=f8a8cd2cb25ac5aa16767364fb0e3c24"
|
|
|
|
PROVIDES = "virtual/librpc"
|
|
|
|
SRC_URI = "${SOURCEFORGE_MIRROR}/${BPN}/${BP}.tar.bz2 \
|
|
file://ipv6.patch \
|
|
"
|
|
UPSTREAM_CHECK_URI = "https://sourceforge.net/projects/libtirpc/files/libtirpc/"
|
|
UPSTREAM_CHECK_REGEX = "(?P<pver>\d+(\.\d+)+)/"
|
|
SRC_URI[sha256sum] = "1e0b0c7231c5fa122e06c0609a76723664d068b0dba3b8219b63e6340b347860"
|
|
|
|
CVE_STATUS[CVE-2021-46828] = "fixed-version: fixed in 1.3.3rc1 so not present in 1.3.3"
|
|
|
|
inherit autotools pkgconfig
|
|
|
|
PACKAGECONFIG ??= "\
|
|
${@bb.utils.filter('DISTRO_FEATURES', 'ipv6', d)} \
|
|
"
|
|
PACKAGECONFIG[ipv6] = "--enable-ipv6,--disable-ipv6"
|
|
PACKAGECONFIG[gssapi] = "--enable-gssapi,--disable-gssapi,krb5"
|
|
|
|
do_install:append() {
|
|
test -e ${D}${sysconfdir}/netconfig && chown root:root ${D}${sysconfdir}/netconfig
|
|
}
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|