16accb6b24
- 264 license table entries with exact download URLs (224/264 resolved) - Complete sources/ directory with all BitBake recipes - Build configuration: tqma6ul-multi-mba6ulx, spaetzle (musl) - Full traceability for Softwarefreigabeantrag - GCC 13.4.0, Linux 6.6.102, U-Boot 2023.04, musl 1.2.4 - License distribution: GPL-2.0 (24), MIT (23), GPL-2.0+ (18), BSD-3 (16)
57 lines
1.8 KiB
BlitzBasic
57 lines
1.8 KiB
BlitzBasic
SUMMARY = "H.264/MPEG-4 AVC video encoder"
|
|
DESCRIPTION = "A free software library and application for encoding video streams into the H.264/MPEG-4 AVC format."
|
|
HOMEPAGE = "http://www.videolan.org/developers/x264.html"
|
|
|
|
LICENSE = "GPL-2.0-only"
|
|
LICENSE_FLAGS = "commercial"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f"
|
|
|
|
DEPENDS = "nasm-native"
|
|
|
|
SRC_URI = "git://github.com/mirror/x264;branch=stable;protocol=https \
|
|
file://don-t-default-to-cortex-a9-with-neon.patch \
|
|
file://Fix-X32-build-by-disabling-asm.patch \
|
|
"
|
|
UPSTREAM_CHECK_COMMITS = "1"
|
|
|
|
SRCREV = "baee400fa9ced6f5481a728138fed6e867b0ff7f"
|
|
|
|
PV = "r3039+git"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit lib_package pkgconfig
|
|
|
|
X264_DISABLE_ASM = ""
|
|
X264_DISABLE_ASM:x86 = "--disable-asm"
|
|
X264_DISABLE_ASM:armv4 = "--disable-asm"
|
|
X264_DISABLE_ASM:armv5 = "--disable-asm"
|
|
X264_DISABLE_ASM:powerpc = "${@bb.utils.contains("TUNE_FEATURES", "spe", "--disable-asm", "", d)}"
|
|
X264_DISABLE_ASM:mipsarch = "${@bb.utils.contains("TUNE_FEATURES", "r6", "", "--disable-asm", d)}"
|
|
|
|
EXTRA_OECONF = '--prefix=${prefix} \
|
|
--host=${HOST_SYS} \
|
|
--libdir=${libdir} \
|
|
--cross-prefix=${TARGET_PREFIX} \
|
|
--sysroot=${STAGING_DIR_TARGET} \
|
|
--enable-shared \
|
|
--enable-static \
|
|
--disable-lavf \
|
|
--disable-swscale \
|
|
--disable-opencl \
|
|
--enable-pic \
|
|
${X264_DISABLE_ASM} \
|
|
'
|
|
|
|
do_configure() {
|
|
install -m 0755 ${STAGING_DATADIR_NATIVE}/gnu-config/config.guess ${S}
|
|
install -m 0755 ${STAGING_DATADIR_NATIVE}/gnu-config/config.sub ${S}
|
|
./configure ${EXTRA_OECONF}
|
|
}
|
|
|
|
do_install() {
|
|
oe_runmake install DESTDIR=${D}
|
|
}
|
|
|
|
AS[unexport] = "1"
|