16accb6b24
- 264 license table entries with exact download URLs (224/264 resolved) - Complete sources/ directory with all BitBake recipes - Build configuration: tqma6ul-multi-mba6ulx, spaetzle (musl) - Full traceability for Softwarefreigabeantrag - GCC 13.4.0, Linux 6.6.102, U-Boot 2023.04, musl 1.2.4 - License distribution: GPL-2.0 (24), MIT (23), GPL-2.0+ (18), BSD-3 (16)
109 lines
4.3 KiB
PHP
109 lines
4.3 KiB
PHP
SUMMARY = "GRUB2 is the next-generation GRand Unified Bootloader"
|
|
|
|
DESCRIPTION = "GRUB2 is the next generaion of a GPLed bootloader \
|
|
intended to unify bootloading across x86 operating systems. In \
|
|
addition to loading the Linux kernel, it implements the Multiboot \
|
|
standard, which allows for flexible loading of multiple boot images."
|
|
|
|
HOMEPAGE = "http://www.gnu.org/software/grub/"
|
|
SECTION = "bootloaders"
|
|
|
|
LICENSE = "GPL-3.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
|
|
|
|
CVE_PRODUCT = "grub2"
|
|
|
|
SRC_URI = "${GNU_MIRROR}/grub/grub-${PV}.tar.gz \
|
|
file://0001-Disable-mfpmath-sse-as-well-when-SSE-is-disabled.patch \
|
|
file://autogen.sh-exclude-pc.patch \
|
|
file://grub-module-explicitly-keeps-symbole-.module_license.patch \
|
|
file://0001-grub.d-10_linux.in-add-oe-s-kernel-name.patch \
|
|
file://0001-RISC-V-Restore-the-typcast-to-long.patch \
|
|
file://0001-misc-Implement-grub_strlcpy.patch \
|
|
file://CVE-2024-45781.patch \
|
|
file://CVE-2024-45782_CVE-2024-56737.patch \
|
|
file://CVE-2024-45780.patch \
|
|
file://CVE-2024-45783.patch \
|
|
file://CVE-2025-0624.patch \
|
|
file://CVE-2024-45774.patch \
|
|
file://CVE-2024-45775.patch \
|
|
file://CVE-2025-0622-01.patch \
|
|
file://CVE-2025-0622-02.patch \
|
|
file://CVE-2025-0622-03.patch \
|
|
file://CVE-2024-45776.patch \
|
|
file://CVE-2024-45777.patch \
|
|
file://CVE-2025-0690.patch \
|
|
file://CVE-2025-1118.patch \
|
|
file://CVE-2024-45778_CVE-2024-45779.patch \
|
|
file://CVE-2025-0677_CVE-2025-0684_CVE-2025-0685_CVE-2025-0686_CVE-2025-0689.patch \
|
|
file://CVE-2025-0678_CVE-2025-1125.patch \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "b30919fa5be280417c17ac561bb1650f60cfb80cc6237fa1e2b6f56154cb9c91"
|
|
|
|
CVE_STATUS[CVE-2019-14865] = "not-applicable-platform: applies only to RHEL"
|
|
CVE_STATUS[CVE-2023-4001] = "not-applicable-platform: Applies only to RHEL/Fedora"
|
|
CVE_STATUS[CVE-2024-1048] = "not-applicable-platform: Applies only to RHEL/Fedora"
|
|
|
|
DEPENDS = "flex-native bison-native gettext-native"
|
|
|
|
GRUB_COMPATIBLE_HOST = '(x86_64.*|i.86.*|arm.*|aarch64.*|riscv.*)-(linux.*|freebsd.*)'
|
|
COMPATIBLE_HOST = "${GRUB_COMPATIBLE_HOST}"
|
|
# Grub doesn't support hard float toolchain and won't be able to forcefully
|
|
# disable it on some of the target CPUs. See 'configure.ac' for
|
|
# supported/unsupported CPUs in hardfp.
|
|
COMPATIBLE_HOST:armv7a = "${@'null' if bb.utils.contains('TUNE_CCARGS_MFLOAT', 'hard', True, False, d) else d.getVar('GRUB_COMPATIBLE_HOST')}"
|
|
COMPATIBLE_HOST:armv7ve = "${@'null' if bb.utils.contains('TUNE_CCARGS_MFLOAT', 'hard', True, False, d) else d.getVar('GRUB_COMPATIBLE_HOST')}"
|
|
|
|
# configure.ac has code to set this automagically from the target tuple
|
|
# but the OE freeform one (core2-foo-bar-linux) don't work with that.
|
|
|
|
GRUBPLATFORM:arm = "efi"
|
|
GRUBPLATFORM:aarch64 = "efi"
|
|
GRUBPLATFORM:riscv32 = "efi"
|
|
GRUBPLATFORM:riscv64 = "efi"
|
|
GRUBPLATFORM ??= "pc"
|
|
|
|
inherit autotools gettext texinfo pkgconfig
|
|
|
|
CFLAGS:remove = "-O2"
|
|
# It doesn't support sse, its make.defaults sets:
|
|
# CFLAGS += -mno-mmx -mno-sse
|
|
# So also remove -mfpmath=sse from TUNE_CCARGS
|
|
TUNE_CCARGS:remove = "-mfpmath=sse"
|
|
|
|
EXTRA_OECONF = "--with-platform=${GRUBPLATFORM} \
|
|
--disable-grub-mkfont \
|
|
--program-prefix="" \
|
|
--enable-liblzma=no \
|
|
--enable-libzfs=no \
|
|
--enable-largefile \
|
|
--disable-werror \
|
|
"
|
|
|
|
PACKAGECONFIG ??= ""
|
|
PACKAGECONFIG[grub-mount] = "--enable-grub-mount,--disable-grub-mount,fuse"
|
|
PACKAGECONFIG[device-mapper] = "--enable-device-mapper,--disable-device-mapper,libdevmapper"
|
|
|
|
# grub2 creates its own set of -nostdinc / -isystem / -ffreestanding CFLAGS and
|
|
# OE's default BUILD_CFLAGS (assigned to CFLAGS for native builds) etc, conflict
|
|
# with that. Note that since BUILD_CFLAGS etc are not used by grub2 target
|
|
# builds, it's safe to clear them unconditionally for both target and native.
|
|
BUILD_CPPFLAGS = ""
|
|
BUILD_CFLAGS = ""
|
|
BUILD_CXXFLAGS = ""
|
|
BUILD_LDFLAGS = ""
|
|
|
|
export PYTHON = "python3"
|
|
|
|
do_configure:prepend() {
|
|
cd ${S}
|
|
|
|
# Remove in next version.
|
|
# See: https://git.savannah.gnu.org/cgit/grub.git/commit/?id=b835601c7639ed1890f2d3db91900a8506011a8e
|
|
echo "depends bli part_gpt" > ${S}/grub-core/extra_deps.lst
|
|
|
|
FROM_BOOTSTRAP=1 ${S}/autogen.sh
|
|
cd ${B}
|
|
}
|